S3C2440定時器

/*
名稱：S3C2440定時器
說明：對於S3C2440來說，其定時器的部件完全一樣，共有5個16位定時器。和STM32比較，那就顯得較少了（STM32細算起來有10個定時器呢）。就功能來說，S3C2440的定時器比起STM32也簡單不少（STM32定時器有定時、捕獲輸入等等），它只有定時和PWM功能（或者還有其他的，但我現在還不清楚）。

對於具體的程序來說，採用的是韋東山老師嵌入式linux開發裏timer一節的實驗：定時器中斷控制LED燈循環點亮和熄滅。但是做了點小改動。原實驗的思路是：一上電，由硬件部分把NandFlash中的代碼拷貝至內部RAM，然後在從內部RAM中把代碼拷貝到外部SDRAM。通過配置MPLL來控制PCLK的時鐘，進而控制定時器。但我想，這不是有點麻煩嗎？直接配置MPLL控制HCLK，然後直接在內部RAM中運行程序不是一樣嗎（省去了初始化SDRAM和把代碼拷貝至SDRAM的環節）？ 經過長時間的分析代碼，最終是被我弄出來了。其實改動的地方也不大，就是啓動文件的一些部分。去掉了初始化SDRAM的部分和把內部SRAM代碼拷貝至外部SDRAM的部分。哦，還有makefile文件，連接時的地址改爲0就可以了。

*/

這是改動後的啓動文件

@******************************************************************************
@ File：head.S
@ 功能：初始化，設置中斷模式、管理模式的棧，設置好中斷處理函數
@******************************************************************************       

.extern     main
.text 
.global _start 
_start:
@******************************************************************************       
@ 中斷向量，本程序中，除Reset和HandleIRQ外，其它異常都沒有使用
@******************************************************************************       
    b   Reset

@ 0x04: 未定義指令中止模式的向量地址
HandleUndef:
    b   HandleUndef 

@ 0x08: 管理模式的向量地址，通過SWI指令進入此模式
HandleSWI:
    b   HandleSWI

@ 0x0c: 指令預取終止導致的異常的向量地址
HandlePrefetchAbort:
    b   HandlePrefetchAbort

@ 0x10: 數據訪問終止導致的異常的向量地址
HandleDataAbort:
    b   HandleDataAbort

@ 0x14: 保留
HandleNotUsed:
    b   HandleNotUsed

@ 0x18: 中斷模式的向量地址
    b   HandleIRQ

@ 0x1c: 快中斷模式的向量地址
HandleFIQ:
    b   HandleFIQ

Reset:                  
    ldr sp, =4096           @ 設置棧指針，以下都是C函數，調用前需要設好棧
    bl  disable_watch_dog   @ 關閉WATCHDOG，否則CPU會不斷重啓

    bl  clock_init

    msr cpsr_c, #0xd2       @ 進入中斷模式
    ldr sp, =3072           @ 設置中斷模式棧指針

    msr cpsr_c, #0xd3       @ 進入管理模式
    ldr sp, =4096           @ 設置管理模式棧指針，
                            @ 其實復位之後，CPU就處於管理模式，
                            @ 前面的“ldr sp, =4096”完成同樣的功能，此句可省略

    bl  init_led            @ 初始化LED的GPIO管腳

    bl  timer0_init

    bl  init_irq            @ 調用中斷初始化函數，在init.c中
    msr cpsr_c, #0x53       @ 設置I-bit=0，開IRQ中斷

    ldr lr, =halt_loop      @ 設置返回地址
    ldr pc, =main           @ 調用main函數
halt_loop:
    b   halt_loop

HandleIRQ:
    sub lr, lr, #4                  @ 計算返回地址
    stmdb   sp!,    { r0-r12,lr }   @ 保存使用到的寄存器
                                    @ 注意，此時的sp是中斷模式的sp
                                    @ 初始值是上面設置的3072

    ldr lr, =int_return             @ 設置調用ISR即EINT_Handle函數後的返回地址  
    ldr pc, =Timer0_Handle            @ 調用中斷服務函數，在interrupt.c中
int_return:
    ldmia   sp!,    { r0-r12,pc }^  @ 中斷返回, ^表示將spsr的值複製到cpsr

這是修改後的makefile

objs := head.o init.o interrupt.o main.o

timer.bin: $(objs)
    arm-linux-ld -Ttext 0x00000000 -o timer_linux $^
    arm-linux-objcopy -O binary -S timer_linux $@
    arm-linux-objdump -D -m arm timer_linux > timer.dis

%.o:%.c
    arm-linux-gcc -Wall -O2 -c -o $@ $<

%.o:%.S
    arm-linux-gcc -Wall -O2 -c -o $@ $<

clean:
    rm -f timer.bin timer_linux timer.dis *.o