echo 命令
打開回顯或關閉請求回顯功能，或顯示消息。如果沒有任何參數，echo
命令將顯示當前回顯設置。
語法
echo [{on|off}] [message]
Sample：@echo off / echo hello world
在實際應用中我們會把這條命令和重定向符號（也稱爲管道符號，一般用> >> ^）結合來實現輸入一
些命令到特定的文件中。
rem 命令
註釋命令，類似於在C語言中的/*--------*/，它並不會被執行，只是起一個註釋的作用，便於別人閱讀
和你自己日後修改。
:: 也具有rem的功能
但::和rem還是有區別的，當關閉回顯時，rem和::後的內容都不會顯示。
但是當打開回顯時，rem和rem
後的內容會顯示出來，然而::後的內容仍然不會顯示。
Rem Message
Sample：@Rem Here is the description.
pause 命令
暫停命令。運行 Pause 命令時，將顯示下面的消息：
Press any key to continue. . .(或：請按任意鍵繼續. . .)
Sample：
@echo off
:begin
copy G:*.* d：/back
echo 請插入另一張光盤...
pause
goto begin
在這個例子中，驅動器 G 中磁盤上的所有文件均複製到d:/back中。顯示的註釋提示您將另一張光盤
盤放入驅動器 G 時，pause 命令會使程序掛起，以便您更換光盤，然後按任意鍵繼續處理。
call 命令
從一個批處理程序調用另一個批處理程序，並且不終止父批處理程序。call
命令接受用作調用目標的
標籤。如果在腳本或批處理文件外使用 Call，它將不會在命令行起作用。
語法
call [[Drive:][Path] FileName ] [:label [arguments]]
參數
[Drive:}[Path] FileName
指定要調用的批處理程序的位置和名稱。
start 命令
調用外部程序，所有的DOS命令和命令行程序都可以由start命令來調用。
如：start calc.exe 即可打開Windows的計算器。
常用參數：
MIN 開始時窗口最小化
SEPARATE 在分開的空間內開始 16 位 Windows 程序
HIGH 在 HIGH 優先級類別開始應用程序
REALTIME 在 REALTIME 優先級類別開始應用程序
WAIT 啓動應用程序並等候它結束
parameters 這些爲傳送到命令/程序的參數
執行的應用程序是 32-位 GUI 應用程序時，CMD.EXE 不等應用程序
終止就返回命令提示。如果在命令
腳本內執行，該新行爲則不會發生。
goto 命令
跳轉命令。程序指針跳轉到指定的標籤，從標籤後的第一條命令開始繼續執行批處理程序。
語法：goto label （label是參數，指定所要轉向的批處理程序中的行。）
Sample：
if {%1}=={} goto noparms
if {%2}=={} goto noparms（如果這裏的if、%1、%2你不明白的話，先跳過去，後面會有詳細的解釋
。）
@Rem check parameters if null show usage
:noparms
echo Usage: monitor.bat ServerIP PortNumber
goto end
標籤的名字可以隨便起，但是最好是有意義的字母啦，字母前加個：
用來表示這個字母是標籤，goto
命令就是根據這個：來尋找下一步跳到到那裏。最好有一些說明這樣你別人看起來纔會理解你的意圖啊。
set 命令
顯示、設置或刪除變量。
顯示變量：set 或 set s 前者顯示批處理當前已定義的所有變量及其值，後者顯示所有以s開頭的變量及值。
設置變量：set aa=abcd 此句命令便可向變量aa賦值abcd。如果變量aa已被定義，則aa的值被修改爲abcd；若aa尚未定義，則此句命令即可定義新的變量aa，同時爲變量aa賦予初始值abcd。
刪除變量：set aa= 此句命令即可刪除變量aa。若變量aa已被定義，則刪除變量aa；若aa尚未定義，則此句命令無實質意義。
需要說明的是，批處理中的變量是不區分類型的，不需要像C語言中的變量那樣還要區分int、float、char等。比如執行set aa=345後，變量aa的值既可以被視爲數字345，也可以被視爲字符串345。
set命令具有擴展功能，如用作交互輸入、字符串處理、數值計算等，屬於高級命令範疇。
編輯本段批處理符號簡介
回顯屏蔽 @
表示不顯示@後面的命令，在入侵過程中（例如使用批處理來格式化敵人
的硬盤）自然不能讓對方看到你使用的命令啦。
@用法舉例：通過運行批處理文件對比pause和@pause命令即可明瞭@的效果。
重定向1 >與>>
將輸出信息重定向到指定的設備或文件。系統默認輸出到顯示器。
如：echo aaaaa>a.txt 即可將本在顯示器上顯示的信息aaaaa輸出到文件a.txt中，屏幕上沒有任何顯示。如果文件a.txt本來已經存在，該命令將首先擦除a.txt中的所有信息，然後寫入信息aaaaa；若a.txt本來就不存在，該命令即可新建一個a.txt文件，並寫入信息aaaaa。
echo aaaaa>>a.txt 類似於echo aaaaa>a.txt。區別在於：如果a.txt本已存在，>a.txt會擦除a.txt中的原有內容，而>>a.txt並不擦除原有內容，僅在a.txt文件的末尾添加信息aaaaa。a.txt不存在時，二者沒有差別。
重定向2 <
將輸入信息來源重定向爲指定的設備或文件。系統默認從顯示器讀取輸入信息。
重定向使用舉例：
=========================================
@echo off
echo abcdefg——這是文件a.txt中的信息>a.txt
echo 請任意輸入字符，以回車結束：
set /p ifo=
cls
echo 【 從屏幕獲得的輸入信息 】
echo %ifo%
set /p ifo=<a.txt
echo 【 從文件a.txt獲得的輸入信息 】
echo %ifo%
pause>nul
=========================================
讀者觀察命令與輸出即可體會到重定向的功能和效果。
管道符號 |
將管道符號前面命令的輸出結果重定向輸出到管道符號後面的命令中去，作爲後面命令的輸入。使用格式爲：command_1|command_2
管道符號使用舉例：
=========================================
@echo off
echo aaaa>a.txt
del /p a.txt
pause
=========================================
@echo off
echo aaaa>a.txt
echo y|del /p a.txt
pause
=========================================
對比以上兩個批處理執行結果，讀者即可明白管道符的用法和效果。
需要說明的是，上面del命令添加開關/p只是爲了讓讀者明白管道符號的使用方法，實際刪除文件時不加/p開關即可實現無提示直接刪除。
轉義符 ^
將特殊符號轉化爲一般符號，即剝離特殊符號的特殊地位。特殊符號指：| & > <
比如，如果我們想輸出符號“>”，直接用命令 echo > 是不行的，必須修改爲 echo ^> 。其餘幾個特殊符號類似需要有同樣的處理。
轉義字符使用舉例：
=========================================
@echo off
echo aaaa>a.txt
echo 第一句echo執行完畢
echo aaaa^>a.txt
echo 第二句echo執行完畢
pause
=========================================
比較上面的兩句echo，第一句echo將信息aaaa輸出到了文件a.txt，而第二句echo則在直接屏幕上顯示出aaaa>a.txt
邏輯命令符
邏輯命令符包括：&、&&、||
&-它的作用是用來連接n個DOS命令，並把這些命令按順序執行，而不管是否有命令執行失敗；
&&-當&&前面的命令成功執行時，執行&&後面的命令，否則不執行；
||-當||前面的命令失敗時，執行||後面的命令，否則不執行。
=========================================
@echo off
echo ^|^|
reg add HKCU /v try /f||echo **成功**
reg add HKCU1 /v try /f||echo **失敗**
echo ^&^&
reg delete HKCU /v try /f&&echo **成功**
reg delete HKCU /v try /f&&echo **失敗**
echo ^&
reg delete HKCU /v try /f&echo **成功**
reg delete HKCU /v try /f&echo **失敗**
pause
=========================================
執行reg add或reg delete後，系統會給出執行結果；我們通過echo命令也給出了“執行結果”。對比系統和我們自己給出的結果，既可以驗證邏輯命令的判斷機理。
編輯本段常用DOS命令釋義
文件夾管理
cd 顯示當前目錄名或改變當前目錄。
md 創建目錄。
rd 刪除一個目錄。
dir 顯示目錄中的文件和子目錄列表。
tree 以圖形顯示驅動器或路徑的文件夾結構。
path 爲可執行文件顯示或設置一個搜索路徑。
copy 複製文件和目錄樹。
文件管理
type 顯示文本文件的內容。
copy 將一份或多份文件複製到另一個位置。
del 刪除一個或數個文件。
move 移動文件並重命名文件和目錄。(Windows XP Home Edition中沒有)
ren 重命名文件。
replace 替換文件。
attrib 顯示或更改文件屬性。
find 搜索字符串。
fc 比較兩個文件或兩個文件集並顯示它們之間的不同
網絡命令
ping 進行網絡連接測試、名稱解析
ftp 文件傳輸
net 網絡命令集及用戶管理
telnet 遠程登陸
ipconfig顯示、修改TCP/IP設置
msg 給用戶發送消息
arp 顯示、修改局域網的IP地址-物理地址映射列表
系統管理
at 安排在特定日期和時間運行命令和程序
shutdown立即或定時關機或重啓
tskill 結束進程
taskkill結束進程(比tskill高級，但WinXPHome版中無該命令)
tasklist顯示進程列表(Windows XP Home Edition中沒有)
sc 系統服務設置與控制
reg 註冊表控制檯工具
powercfg控制系統上的電源設置
對於以上列出的所有命令，在cmd中輸入命令+/?即可查看該命令的幫助信息。如find /?
編輯本段語句結構釋義
類似於C語言，批處理也有它的語句結構。批處理的語句結構主要有選擇結構(if語句)、循環結構(for語句)等。
if語句(選擇結構)
if語句實現條件判斷，包括字符串比較、存在判斷、定義判斷等。通過條件判斷，if語句即可以實現選擇功能。
1、字符串比較
if語句僅能夠對兩個字符(串)是否相同、先後順序進行判斷等。其命令格式爲：
IF [not] string1 compare-op string2 command1 [else command2]
其中，比較操作符compare-op有以下幾類：
== - 等於
EQU - 等於
NEQ - 不等於
LSS - 小於
LEQ - 小於或等於
GTR - 大於
GEQ - 大於或等於
選擇開關/i則不區分字符串大小寫；選擇not項，則對判斷結果進行邏輯非。
字符串比較示例：
===============================================
@echo off
set str1=abcd1233
set str2=ABCD1234
if %str1%==%str2% (echo 字符串相同！) else (echo 字符串不相同！)
if /i %str1% LSS %str2% (echo str1^<str2) else (echo str1^>=str2)
echo.
set /p choice=是否顯示當前時間？(y/n)
if /i not %choice% EQU n echo 當前時間是：%date% %time%
pause>nul
===============================================
對於最後一個if判斷，當我們輸入n或N時的效果是一樣的，都不會顯示時間。如果我們取消開關/i，則輸入N時，依舊會顯示時間。
另外請注意一下幾個細節：1-echo str1^<str2和echo str1^>=str2；2-echo.。
2、存在判斷
存在判斷的功能是判斷文件或文件夾是否存在。其命令格式爲：
IF [NOT] EXIST filename command1 [else command2]
===============================================
@echo off
if exist %0 echo 文件%0是存在的！
if not exist %~df0 (
echo 文件夾%~df0不存在！
) else echo 文件夾%~df0存在！
pause>nul
===============================================
這裏注意幾個地方：
1-存在判斷既可以判斷文件也可以判斷文件夾；
2-%0即代表該批處理的全稱(包括驅動器盤符、路徑、文件名和擴展類型)；
3-%~df0是對%0的修正，只保留了其驅動器盤符和路徑，詳情請參考for /?，屬高級批處理範疇；
4-注意if語句的多行書寫，多行書寫要求command1的左括號必須和if在同一行、else必須和command1的右括號同行、command2的左括號必須與else同行、command1和command2都可以有任意多行，即command可以是命令集。
3、定義判斷
定義判斷的功能是判斷變量是否存在，即是否已被定義。其命令格式爲：
IF [not] DEFINED variable command1 [else command2]
存在判斷舉例：
===============================================
@echo off
set var=111
if defined var (echo var=%var%) else echo var尚未定義！
set var=
if defined var (echo var=%var%) else echo var尚未定義！
pause>nul
===============================================
對比可知，"set var="可以取消變量，收回變量所佔據的內存空間。
4、結果判斷
masm %1.asm
if errorlevel 1 pause & edit %1.asm
link %1.obj
先對源代碼進行彙編，如果失敗則暫停顯示錯誤信息，並在按任意鍵後自動進入編輯界面；否則用link程序連接生成的obj文件，這種用法是先判斷前一個命令執行後的返回碼（也叫錯誤碼，DOS程序在運行完後都有返回碼），如果和定義的錯誤碼符合（這裏定義的錯誤碼爲1），則執行相應的操作（這裏相應的操作爲pause & edit %1.asm部分）。
另外，和其他兩種用法一樣，這種用法也可以表示否定。用否定的形式仍表達上面三句的意思，代碼變爲：
masm %1.asm
if not errorlevel 1 link %1.obj
pause & edit %1.asm
for語句(循環結構)
for語句可以實現類似於C語言裏面的循環結構，當然for語句的功能要更強大一點，通過不同的開關可以實現更多的功能。for語句有多個開關，不同開關將會實現不同的功能。
1、無開關
無開關的for語句能夠對設定的範圍內進行循環，是最基本的for循環語句。其命令格式爲：
FOR %%variable IN (set) DO command
其中，%%variable是批處理程序裏面的書寫格式，在DOS中書寫爲%variable，即只有一個百分號(%)；set就是需要我們設定的循環範圍，類似於C語言裏面的循環變量；do後面的command就是循環所執行的命令，即循環體。
無開關for語句舉例：
===============================================
@echo off
for %%i in (a,"b c",d) do echo %%i
pause>nul
===============================================
2、開關/L
含開關/L的for語句，可以根據set裏面的設置進行循環，從而實現對循環次數的直接控制。其命令格式爲：
FOR /L %%variable IN (start,step,end) DO command
其中，start爲開始計數的初始值，step爲每次遞增的值，end爲結束值。當end小於start時，step需要設置爲負數。
含開關/L的for語句舉例(創建5個文件夾)：
===============================================
@echo off
for /l %%i in (1,2,10) do md %%i
pause
===============================================
上例將新建5個文件夾，文件夾名稱依次爲1、3、5、7、9。可以發現，%%i的結束值並非end的值10，而是不大於end的一個數。
3、開關/F
含開關/F的for語句具有最強大的功能，它能夠對字符串進行操作，也能夠對命令的返回值進行操作，還可以訪問硬盤上的ASCII碼文件，比如txt文檔等。其命令格式爲：
FOR /F ["options"] %%variable IN (set) DO command
其中，set爲("string"、'command'、file-set)中的一個；options是(eol=c、skip=n、delims=xxx、tokens=x,y,m-n、usebackq)中的一個或多個的組合。各選項的意義參見for /f。一般情況下，使用較多的是skip、tokens、delims三個選項。
含開關/F的for語句舉例：
===============================================
@echo off
echo **No Options:
for /f %%a in ("1,2,10") do echo a=%%a
echo **Options tokens ^& delims:
for /f "tokens=1-3 delims=," %%a in ("1,2,10") do echo a=%%a b=%%b c=%%c
pause
===============================================
@echo off
echo 本文件夾裏面的文件有：
for /f "skip=5 tokens=3* delims= " %%a in ('dir') do (
if not "%%a"=="<DIR>" if not "%%b"=="字節" if not "%%b"=="可用字節" echo %%b
)
pause
===============================================
@echo off
echo 本文件夾裏面的文件有：
dir>c:/file.txt
for /f "skip=5 tokens=3* delims= " %%a in (c:/file.txt) do (
if not "%%a"=="<DIR>" if not "%%b"=="字節" if not "%%b"=="可用字節" echo %%b
)
del c:/file.txt
pause
===============================================
對於後面的兩個例子，其中options裏面的delims= 是可以刪除的，因爲只要添加了/F開關係統就將delims的值默認爲空格。
符號字符串中的最後一個字符星號， 那麼額外的變量將在最後一個符號解析之後 分配並接受行的保留文本。本例中也可以改爲4，不過文件名中有空格的文件，只能顯示空格以前部分 同時我們也看到了，for語句的do後面的command也是可以分行的，只需要保證command的左括號和do在同一行就可以了。
4、開關/D或/R
含開關/D或/R的for語句是與目錄或文件有關的命令，一般情況下很少使用。含開關/R的命令有時候被用於通過遍歷文件夾來查找某一個文件或文件夾，故而列舉此例。
含開關/R的for語句舉例(文件夾遍歷)：
===============================================
@echo off
setlocal enabledelayedexpansion
FOR /R d: %%i IN (.) DO (
set dd=%%i
set "dd=!dd:~0,-1!"
echo !dd!
)
pause
exit
===============================================
上例即可以羅列出D盤下的所有文件夾，其速度要比命令"tree d:"慢多了，不過其返回結果的實用性則遠遠超過了tree命令。
一般情況下我們不推薦通過遍歷文件夾來查找文件，特別是在查找某些程序(比如QQ.exe)的位置時。推薦通過reg命令查找註冊表來查找QQ的路徑，以保證查找效率。
上例中也出現了幾個新面孔，如setlocal、感嘆號等。其中，感嘆號其實就是變量百分號(%)的強化版。之所以要用!而不用%，是因爲在for循環中，當一個變量被多次賦值時，%dd%所獲取的僅僅是dd第一次被賦予的值；要想刷新dd的值，就必須首先通過命令"setlocal enabledelayedexpansion"來開啓延遲變量開關，然後用!dd!來獲取dd的值。
for語句是批處理裏面功能最強大、使用最普遍卻又最難掌握的一套命令，這也是批處理菜鳥和批處理高手最明顯的一個分水嶺，一旦掌握了這套命令，那麼你就離批處理達人不遠了！
編輯本段字符串處理釋義
批處理有着具有非常強大的字符串處理能力，其功能絕不低於C語言裏面的字符串函數集。批處理中可實現的字符串處理功能有：截取字符串內容、替換字符串特定字段、合併字符串、擴充字符串等功能。下面對這些功能一一進行講解。
1、截取字符串
截取字符串可以說是字符串處理功能中最常用的一個子功能了，能夠實現截取字符串中的特定位置的一個或多個字符。舉例說明其基本功能：
=========================================
@echo off
set ifo=abcdefghijklmnopqrstuvwxyz0 12 3456789
echo 原字符串（第二行爲各字符的序號）：
echo %ifo%
echo 1234567890 123 45678901234567890123456
echo 截取前5個字符：
echo %ifo:~0,5%
echo 截取最後5個字符：
echo %ifo:~-5%
echo 截取第一個到倒數第6個字符：
echo %ifo:~0,-5%
echo 從第4個字符開始，截取5個字符：
echo %ifo:~3,5%
echo 從倒數第14個字符開始，截取5個字符：
echo %ifo:~-14,5%
pause
=========================================
當然，上面的例子只是將字符串處理的基本功能展示出來了，還看不出字符串處理具體有什麼用處。下面這個例子是對時間進行處理。
=========================================
@echo off
echo 當前時間是：%time% 即 %time:~0,2%點%time:~3,2%分%time:~6,2%秒%time:~9,2%釐秒
pause
=========================================
2、替換字符串
替換字符串，即將某一字符串中的特定字符或字符串替換爲給定的字符串。舉例說明其功能：
=========================================
@echo off
set aa=偉大的中國！我爲你自豪！
echo 替換前：%aa%
echo 替換後：%aa:中國=中華人民共和國%
echo aa = %aa%
set "aa=%aa:中國=中華人民共和國%"
echo aa = %aa%
pause
=========================================
對於上面的例子有一點說明，對比兩個echo aa = %aa%可以發現，如果要修改變量aa的內容的話，就需要將修改結果“%aa:中國=中華人民共和國%”賦值給變量aa。上面的字符串截取也有着同樣的特點。
3、字符串合併
其實，合併字符串就是將兩個字符串放在一起就可以了。舉例說明：
=========================================
@echo off
set aa=偉大的中國！
set bb=我爲你自豪！
echo %aa%%bb%
echo aa=%aa%
echo bb=%bb%
set "aa=%aa%%bb%"
echo aa=%aa%
pause
=========================================
同樣，如果要改變變量aa的內容的話，就需要將合併結果“%aa%%bb%”賦值給變量aa。
4、擴充字符串
“擴充”這個詞彙來自於微軟自己的翻譯，意思就是對錶示文件路徑的字符串進行特殊的處理，具體功能羅列如下：
=========================================
~I - 刪除任何引號(")，擴充 %I
%~fI - 將 %I 擴充到一個完全合格的路徑名
%~dI - 僅將 %I 擴充到一個驅動器號
%~pI - 僅將 %I 擴充到一個路徑
%~nI - 僅將 %I 擴充到一個文件名
%~xI - 僅將 %I 擴充到一個文件擴展名
%~sI - 擴充的路徑只含有短名
%~aI - 將 %I 擴充到文件的文件屬性
%~tI - 將 %I 擴充到文件的日期/時間
%~zI - 將 %I 擴充到文件的大小
%~$PATH:I - 查找列在路徑環境變量的目錄，並將 %I 擴充
到找到的第一個完全合格的名稱。如果環境變量名
未被定義，或者沒有找到文件，此組合鍵會擴充到
空字符串
可以組合修飾符來得到多重結果:
%~dpI - 僅將 %I 擴充到一個驅動器號和路徑
%~nxI - 僅將 %I 擴充到一個文件名和擴展名
%~fsI - 僅將 %I 擴充到一個帶有短名的完整路徑名
%~dp$PATH:i - 查找列在路徑環境變量的目錄，並將 %I 擴充
到找到的第一個驅動器號和路徑。
%~ftzaI - 將 %I 擴充到類似輸出線路的 DIR
=========================================
以上內容引用於for /?幫助信息。其中的I代表變量I，不過需要說明的是，不是所有的變量都能夠進行擴充的，有兩個條件：1、該字符串代表一個文件路徑；2、變量要用%x來表示，x可取a-z A-Z 0-9共62個字符中的任意一個。舉例說明：
=========================================
@echo off
echo 正在運行的這個批處理：
echo 完全路徑：%0
echo 去掉引號：%~0
echo 所在分區：%~d0
echo 所處路徑：%~p0
echo 文件名：%~n0
echo 擴展名：%~x0
echo 文件屬性：%~a0
echo 修改時間：%~t0
echo 文件大小：%~z0
pause
=========================================
其中的%0是批處理裏面的參數，代表當前運行的批處理的完全路徑。類似的還有%1-%9，分別代表傳遞來的第1-9個參數。例子如下：
===============================================
@echo off
set aa=C:/Windows/PPP/a.btx
call :deal aaa %aa% "c c" ddd eee
pause>nul
exit
:deal
echo %%0 = %0
echo %%1 = %1
echo %%2 = %2
echo %%3 = %3
echo %%4 = %4
echo %%5 = %5
===============================================
其中，變量aa在之前是不可以擴充的，通過call命令並將aa作爲參數傳遞給子函數:deal，將aa變量轉換成了變量%1，即符合%x格式，從而可以進行字符串擴充。
至於%x中x取a-z A-Z的形式，可以複習一下for語句，for語句裏面的變量就是用%x來表示的，因而可以直接進行擴充。
編輯本段數值計算簡介
批處理裏面的數值計算功能較弱，只能夠進行整型計算，忽略浮點數的小數部分；同時數值計算的範圍也受限於系統位數，對於目前較爲常見的32位機來說，數值計算能處理的數值範圍爲0x80000000h~0x7FFFFFFFh，即-2147483648~+2147483647。
數值計算需要使用set命令，具體格式爲“set /a expression”。其中，expression代表計算表達式，計算表達式跟C語言裏面的表達式基本上完全一致。set支持的運算符也跟C語言裏面的一樣，只是沒有了増一減一。set支持的運算符及優先級排序如下：
=========================================
() - 分組
! ~ - - 一元運算符（邏輯非、按位非、取負）
* / % - 算數運算符（乘、除得商、除得餘數，即取餘）
+ - - 算數運算符（加、減）
<< >> - 邏輯移位（左移一位、右移一位）
& - 按位“與”
^ - 按位“異”
| - 按位“或”
= *= /= %= += -= - 賦值
&= ^= |= <<= >>=
, - 表達式分隔符（set可一次處理多個表達式）
=========================================
我們知道，批處理中取變量的值是需要用%或者!的，而在set /a 中，直接用變量名稱即可取得變量的值。另外，set支持八進制（數字前綴0）、十進制（數字無前綴）和十六進制（數字前綴0x），且支持不同進制之間的計算，如set /a a=123+0123+0x123，計算及顯示結果爲十進制。
編輯本段批處理概念方法簡介
學習有關批處理的一些比較瑣碎、但又比較有價值的一些知識，運用這些知識後，纔有條件更好的實現的批處理的功能，並能使批處理擺脫黑白世界而顯得更加多姿多彩。
（一）環境變量
所謂“環境變量”，實際上就是C語言裏面的“變量”的意思。批處理的變量可以分爲兩類，由系統定義的系統變量和由用戶根據需要自定義的用戶變量。
【 1、系統變量 】
批處理的一些變量是由操作系統事先定義好的，可以適用於任何批處理，我們稱這些特殊的變量爲“系統變量”。系統變量有很多個，包括硬件類、操作系統類、文件路徑類、系統時間類等。要查看所有的系統變量，請新打開一個cmd窗口，輸入set回車即可。對幾個比較常用的變量解釋如下：
ComputerName 計算機名，即右鍵 我的電腦--屬性--計算機名 選項卡中的“完整的計算機名稱”
ComSpec cmd.exe完整路徑名
HomeDrive 系統分區盤符，一般都是C盤，故而HomeDrive=C:
Path 可執行文件默認搜索路徑。這個東東非常重要！待會兒單獨講解…
ProgramFiles 就是系統的Program Files的路徑啦，一般都是C:/Program Files，這就是安裝軟件時默認的安裝路徑了
Prompt 個性化設置cmd提示符的必備武器！不過，我沒怎麼用過~
SystemDrive 包含系統根目錄的分區，其實就是HomeDrive了
SystemRoot 系統根目錄路徑，一般都是C:/WINDOWS
Temp、Tmp 文件、程序等可使用的臨時目錄，默認是C:/WINDOWS/Temp或Tmp。幾乎所有的程序在運行時都會在這個目錄裏面“臨時”寫入文件。一般情況下，程序寫入的臨時文件都應該被該程序刪除，可惜的是，大部分的程序都很健忘，導致這個文件夾佔據的空間越來越大，自然也就使我們的系統增肥嘍。所以，我們要把它修改到其他分區，並且時時的清理裏面的臨時文件。
UserName 當前用戶名，即所登陸的賬戶名
UserProfile 當前用戶的配置目錄，一般都是C:/Documents and Settings/%UserName%。默認情況下，我們的桌面就是這個目錄下面的“桌面”文件夾；我的文檔就是這個目錄下面的“My Documents”文件夾。所以啦，往桌面上或我的文檔裏面放東西就是放到這個文件夾下面了，也就是放到C盤了，重裝系統時要覆蓋C盤內容的，所以桌面上或我的文檔裏面的東西當然就會Gone with the Wind了~解決方法有兩個，一是保持良好的習慣，不把重要文件放到這兩個地方；二是，修改默認設置，將這兩個文件夾都移到其他分區。
WinDir 操作系統路徑，其實就是SystemRoot了
（二）用戶變量
編寫批處理程序時，用戶根據需要自己定義的變量稱之爲用戶變量。用戶變量類似於C語言裏面的變量，僅僅在定義該變量的程序中有效。
用戶變量由set命令定義，這是批處理中非常非常重要的一個操作，從而使set命令成爲批處理裏面使用頻率最高的幾個命令之一。關於set命令的使用，參考set /?，本教程也會在後面對其進行講解。
【 3、變量引用 】
前面的幾節課裏面，我們已經看到了如何引用變量，即直接用變量名操作變量，通過"%"或"!"來獲取變量的值。其中，只有在for語句裏面重複對同一變量多次賦值時才需要使用"!"，並且在使用"!"調用變量時，要首先“啓用延遲環境變量擴充”，啓動命令爲：SetLocal EnableDelayedExpansion。另外需要說明的是，“啓用延遲環境變量擴充”後，所有的"!"都將被視爲“取變量值”的特殊符號，即使用"^!"也不能輸出符號"!"。若要輸出"!"，則需要“停用延遲環境變量擴充”，命令爲：SetLocal DisableDelayedExpansion
（三）參數
跟C語言類似，在調用函數或其他批處理時可能需要傳遞參數。批處理的參數傳遞分爲直接和間接兩種傳遞參數的方法。
【 1、直接傳遞 】
直接傳遞參數，即在使用call命令時，不使用任何參數，在子函數或子批處理裏面直接對主函數(也稱父批處理)裏面的變量進行修改。這跟彙編語言裏面的參數傳遞方式類似。
直接傳遞參數舉例：
===============================================
@echo off
setlocal enabledelayedexpansion
set var=aCdehiM,?mnrstW y
echo %var%
call :deal
setlocal disabledelayedexpansion
set var=%var:?=!%
echo %var%
pause>nul
exit
:deal
set tm=!var!
set var=
for %%i in (6,3,11,11,16,15,1,4,11,5,12,13,9,0,12,7,15,14,5,10,2,16,18,8) do (
set var=!var!!tm:~%%i,1!
)
goto :eof
===============================================
可以發現，當我們把變量var作爲參數賦予子函數:deal後，子函數對var的值進行了修改；當子函數返回後，主函數裏面的var的值就已經是子函數裏面var被修改後的值了。
該例子中，使用了本節課前面講到的setlocal enabledelayedexpansion和setlocal disabledelayedexpansion，前者保證了var在for循環裏面能夠根據我們的意願進行處理，後者保證了能夠正確輸出符號"!"。另外例子中還使用了命令set，利用set對字符串進行了處理。還有一個地方使用了語句goto :eof，該語句相當於C語言裏面的return或彙編語言裏面的RET，即子程序返回命令。需要說明的是，當子函數本身就在批處理文件的末尾的話，我們是可以省略這句話的，比如將此例的goto :eof刪除是不會產生任何影響的。
【 2、間接傳遞 】
間接傳遞參數，即在使用call命令時，在其後面添加參數，形如call {[:label][ChildBatch]} Parameter1 Parameter2 ... ParameterN。這跟C語言裏面傳遞參數的格式類似。不同於C語言，批處理中的子函數不需要定義形參，更不需要指定參數的個數。傳遞過來的參數，在子函數或子批處理裏面是以%1~%9的形式表示的，即%1~%9分別表示傳遞過來的第1~9個參數。
===============================================
@echo off
call :deal aaa bbb "c c" ddd eee
pause>nul
exit
:deal
echo %%0 = %0
echo %%1 = %1
echo %%2 = %2
echo %%3 = %3
echo %%4 = %4
echo %%5 = %5
===============================================
通過這個例子就可以清晰的看到%n參數表示法的用法。參數列表中包含空格的依舊要用雙引號(")引起來；另外，也可以看到，%0已經變成了子函數的標號了，而不是父批處理的文件名全稱。
【 3、區別 】
這兩種參數傳遞方法本質上是沒有區別的，形式上，直接傳遞直接對原變量進行操作，丟失了原變量的值；間接傳遞則通過%n對原變量進行了簡單的備份，並且通用性更強，即不限定原變量的名稱。另外，使用%n還有一個非常大的好處，就是可以通過%~*i來加強處理變量的能力。關於%~*i，詳細內容參見for /?。
針對二者的差別，可以根據情況決定使用哪種傳遞方式：
--1、作爲參數的變量名固定、且在子函數中不需要對其進行備份的情況下，使用直接傳遞法；
--2、若將子函數作爲一個通用的程序模塊，以適應於對不同變量的處理，或者作爲參數的變量不需要備份時，使用間接傳遞法。
具體使用哪種方法，還需根據實際情況或使用習慣進行選擇。
（四）返回值
有些命令在執行之後將會返回一定的錯誤值(errorlevel)，可以通過errorlevel的值判斷命令執行的狀況。這點類似於C語言裏面的exit(num)，num就是錯誤代碼。
獲取返回值errorlevel的方法就是，在執行命令後，立馬調用返回值errorlevel，如echo %errorlevel%或者if %errorlevel%==1等命令。
errorlevel舉例：
===============================================
@echo off
reg add HKCU /v try /f>nul
reg delete HKCU /v try /f
if errorlevel 0 (echo 刪除成功！) else (echo 刪除失敗！)
reg delete HKCU /v try /f
if %errorlevel%==0 (echo 刪除成功！) else (echo 刪除失敗！)
pause>nul
===============================================
上面例子中，由於第一成功的刪除了註冊表，導致第二次因爲找不到註冊表而宣告失敗。同時我們也看到了errorlevel的使用方法，即if errorlevel 0和if %errorlevel%==0是一樣的。也許你注意到了，裏面還有個笑臉呢~O(∩_∩)O哈哈~這就是ASCII碼啦，後面跟你講啊…
一般情況下，程序或命令成功執行時，返回的errorlevel是0，錯誤時返回1或更高的值。當然，有些命令是沒有返回值的，這點需要注意。
嗯，有沒有想起前面有個類似的東西啊？對了，那就是||和&&了，這兩個符號就是根據errorlevel的值來進行邏輯判斷的~
（五）用戶交互
批處理，黑框白字是它最著名的特徵。雖然當初DOS爲人們使用計算機做出了莫大的貢獻，但在Windows盛行的今天，人們已經疏遠並且懼怕那個黑色的窗口了。微軟爲了讓先天有着批量處理“體力活”能力的DOS避免“冷酷”，便於接近，特意提供了幾個小命令，加強批處理的用戶交互功能。
【 1、視窗 】
首先我們要DIY它的窗口。使用命令：color、mode、msg。
--1、設置窗口背景色和字體顏色by color。詳細內容參見color /?。
--2、設置窗口大小by "MODE CON [COLS=c] [LINES=n]"，cols即寬度，lines即高度。
--3、GUI交互窗口by msg。詳細內容參見msg /?。
視窗DIY舉例：
===============================================
@echo off
set a=10
set b=0
:tex
set /a a+=3
set /a b+=1
mode con cols=%a% lines=%b%
if %a% lss 60 goto :tex
echo O(∩_∩)O 聖誕快樂 O(∩_∩)O
set a=15,a6,2e,d0,34,8b,4f,9d,5e
for %%i in (%a%) do (
ping -n 2 127.1>nul
color %%i
)
for %%i in (%a%,%a%) do (
ping -n 1 127.1>nul
color %%i
)
>>ms.txt echo */. . . * .
>>ms.txt echo ./* . [] * __
>>ms.txt echo */ . .//~~~~~~~~~~~~'/. ^|◆
>>ms.txt echo /* ,/,..,/,...........,/.◆
>>ms.txt echo ^|^| ..▎# ▎田 田 ▎ ^| ▎◆
>>ms.txt echo ^|^| ^&^&▎ ▎ ▎'^|'▎ o
>>ms.txt echo ^|^| ##■■■■■■■■■■〓
msg %username% /w /time:3600 <ms.txt
del ms.txt
pause
===============================================
【 2、聲音 】
呵呵，是不是注意到了批處理沒有聲音吶？閒話不說，直接做實驗吧 ^_^
===============================================
@echo off
echo 做好準備，響了啊！！
pause
cls
echo
echo 怎麼樣？呵呵，刺激吧~
pause
cls
mshta vbscript:createobject("sapi.spvoice").speak("Merry Christmas and Happy New Year!")(window.close)
pause
===============================================
此處，這個就是調用vbs的方法：vbscript:createobject("sapi.spvoice").speak("Merry Christmas and Happy New Year!")
speak 有人說如果tts安裝了中文引擎是可以講中文的。
其實不然我測試了一下只要打上拼音(一個字和一個字的拼音中間需要加空格）就可以說中文啦~
【 3、控制 】
在運行批處理的過程中，我們如何幹預批處理呢？呵呵，直接點叉叉就可以結束它了！嗯，不錯，不過，太野蠻了~
--1、暫停批處理：直接按鍵盤上的Pause鍵嘍
--2、終止批處理：組合鍵Ctrl+C。不過，有時候它好像響應的不太積極啊…
（六）ASCII碼
前面的例子中，我們已經使用過一次ASCII碼了，也就是那個笑臉。ASCII碼是圖形化的符號，可以用來點綴我們的批處理的。
在cmd窗口中我們可以通過任意一個字符的ASCII碼來輸入該字符，比如Ctrl+G、Ctrl+N等，字母a-z對應ASCII碼的97-122。對於ASCII碼大於26的字符，可以通過這個方法來輸入：按住Alt鍵不鬆，通過小鍵盤輸入ASCII碼的十進制值，鬆開Alt鍵即可。
編輯本段批處理文件的應用
批處理文件是將一系列命令按一定的順序集合爲一個可執行的文本文件，其擴展名爲BAT。
1、 REM
REM 是個註釋命令一般是用來給程序加上註解的，該命令後的內容在程序執行的時候將不會被顯示和執行。例：
REM 你現在看到的就是註解，這一句將不會被執行。在以後的例子中解釋的內容都REM 會放在REM後面。請大家注意。
2、 ECHO
ECHO 是一個回顯命令主要參數有OFF和 ON,一般用ECHO message來顯示一個特定的消息 。例：
Echo off
Rem 以上代表關閉回顯即不顯示所執行的命令
Echo 這個就是消息。
Rem 以上代表顯示“這就是消息”這列字符
執行結果：
C:/>ECHO.BAT
這個就是消息。
3、 GOTO
GOTO 即爲跳轉的意思。在批處理中允許以“：XXX”來構建一個標號然後用GOTO ：標號直接來執行標號後的命令。例
:LABEL
REM 上面就是名爲LABEL的標號。
DIR C:/
DIR D:/
GOTO LABEL
REM 以上程序跳轉標號LABEL處繼續執行。
4、CALL
CALL 命令可以在批處理執行過程中調用另一個批處理，當另一個批處理執行完後再繼續執行原來的批處理。例：
批處理2.BAT內容如下：
ECHO 這就是2的內容
批處理1.BAT內容如下：
ECHO 這是1的內容
CALL 2.BAT
ECHO 1和2的內容全部顯示完成
執行結果如下：
C:/>1.BAT
這是1的內容
這就是2的內容
1和2的內容全部顯示完成
5、PAUSE
PAUSE 停止系統命令的執行並顯示下面的內容。例：
C:/> PAUSE
請按任意鍵繼續 . . .
6、 IF
IF 條件判斷語句，語法格式如下：
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
說明：
[NOT] 將返回的結果取反值即“如果沒有”的意思。
ERRORLEVEL 是命令執行完成後返回的退出值
Number 退出值的數字取值範圍0~255。判斷時值的排列順序應該又大到小。返回的值大於或等於指定的值時條件成立。
string1==string2 string1和string2都爲字符的數據，英文字符的大小寫將看做不同，這個條件中的等於號必須是2個（絕對相等），條件相等後即執行後面的 command
EXIST filename 爲文件或目錄存在的意思。
IF ERRORLEVEL這條語句必須放在某一個命令後面。執行命令後由IF ERRORLEVEL來判斷命令的返回值。