創建讀寫二進制文件的存儲過程,內容如下:
/*--bcp-二進制文件的導入導出,調用示例 :
create table tb (img image);
--數據導入
exec sp_binaryIO '.', 'sa', '', 'test..tb', 'img', 'c:/abc.jpg', 0
--數據導出
exec sp_binaryIO '.', 'sa', '', 'test..tb', 'img', 'c:/a.jpg', 1
drop table tb;
--*/
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[sp_binaryIO]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[sp_binaryIO]
GO
Create proc sp_binaryIO
@servename varchar (30), --服務器名稱
@username varchar (30), --用戶名
@password varchar (30), --密碼
@tbname varchar (500), --數據庫..表名
@fdname varchar (30), --字段名
@fname varchar (1000), --目錄+文件名
@isout bit=1 --1導出((默認), 0導入
AS
declare @fname_in varchar(1000), --bcp處理應答文件名
@fsize varchar(20), --要處理的文件的大小
@m_tbname varchar(50), --臨時表名
@sql varchar(8000)
--取得導入文件的大小
if @isout=1
set @fsize = '0'
else
begin
create table #tb(可選名 varchar(20), 大小 int, 創建日期 varchar(10), 創建時間 varchar(20),
上次寫操作日期 varchar(10), 上次寫操作時間 varchar(20), 上次訪問日期 varchar(10),
上次訪問時間 varchar(20), 特性 int)
insert into #tb exec master..xp_getfiledetails @fname
select @fsize = 大小 from #tb
drop table #tb
if @fsize is null
begin
print '文件未找到'
return
end
end
--生成數據處理應答文件
set @m_tbname = '[##temp' + cast(newid() as varchar(40)) + ']'
set @sql = 'select * into ' + @m_tbname + ' from (
select null as 類型
union all select 0 as 前綴
union all select ' + @fsize + ' as 長度
union all select null as 結束
union all select null as 格式
) a'
exec(@sql)
select @fname_in = @fname + '_temp',
@sql = 'bcp "' + @m_tbname + '" out "' + @fname_in + '" /S"' + @servename
+ case when isnull(@username,'') = '' then '' else '" /U"' + @username end
+ '" /P"' + isnull(@password, '') + '" /c'
exec master..xp_cmdshell @sql
--刪除臨時表
set @sql = 'drop table ' + @m_tbname
exec(@sql)
if @isout=1
begin
-- 導出
set @sql = 'bcp "select top 1 ' + @fdname + ' from ' + @tbname
+ '" queryout "' + @fname + '" /S"' + @servename
+ case when isnull(@username,'') = '' then '' else '" /U"' + @username end
+ '" /P"' + isnull(@password,'')
+ '" /i"' + @fname_in + '"'
exec master..xp_cmdshell @sql
end
else
begin
-- 導入
set @sql = 'bcp "'+ @tbname + '" in "' + @fname
+ '" /S"' + @servename
+ case when isnull(@username,'')='' then '' else '" /U"' + @username end
+ '" /P"' + isnull(@password, '') + '" /i"' + @fname_in + '"'
exec master..xp_cmdshell @sql
end
--刪除數據處理應答文件
set @sql = 'del ' + @fname_in
exec master..xp_cmdshell @sql
go
有了這個存儲過程就可以讀寫任意的文件了。