注：以下是轉來的內容，但是設計PLSQL代碼，原文有問題，所以PLSQL代碼我都驗證修改了。測試需要在scott/tiger下進行，對於沒有的表，需要自行創建，表複製的語句爲
CREATE TABLE former_emp AS SELECT * FROM EMP;
遊標(CURSOR)是ORACLE系統在內存中開闢的一個工作區,在其中存放SELECT語句返回的查詢結果.
這個查詢結果既可以是零記錄,單條記錄,也可以是多條記錄.在遊標所定義的工作區中,存在着一個指針(POINTER),
在初始狀態它指向查詢結果的首記錄.
SQL是用於訪問ORACLE數據庫的語言，PL/SQL擴展和加強了SQL的功能，它同時引入了更強的程序邏輯。
PL/SQL支持DML命令和SQL的事務控制語句。DDL在PL/SQL中不被支持，這就意味作在PL/SQL程序塊中不能創建表或其他任何對象。
較好的PL/SQL程序設計是在PL/SQL塊中使用象DBMS_SQL這樣的內建包或執行EXECUTE IMMEDIATE命令建立動態SQL來執行DDL命令，
PL/SQL編譯器保證對象引用以及用戶的權限。
下面我們將討論各種用於訪問ORACLE數據庫的DML和TCL語句。
查詢
SELECT語句用於從數據庫中查詢數據，當在PL/SQL中使用SELECT語句時，要與INTO子句一起使用，查詢的返回值被賦予INTO子句中的變量，變量的聲明是在DELCARE中。SELECT INTO語法如下：
SELECT [DISTICT|ALL]{*|column[,column,...]}
INTO (variable[,variable,...] |record)
FROM {table|(sub-query)}[alias]
WHERE............
PL/SQL中SELECT語句只返回一行數據。如果超過一行數據，那麼就要使用顯式遊標（對遊標的討論我們將在後面進行），
INTO子句中要有與SELECT子句中相同列數量的變量。INTO子句中也可以是記錄變量。
%TYPE屬性
在PL/SQL中可以將變量和常量聲明爲內建或用戶定義的數據類型，以引用一個列名，同時繼承他的數據類型和大小。
這種動態賦值方法是非常有用的，比如變量引用的列的數據類型和大小改變了，如果使用了%TYPE,那麼用戶就不必修改代碼，
否則就必須修改代碼。
例：
v_empno SCOTT.EMP.EMPNO%TYPE;
v_salary EMP.SALARY%TYPE;
不但列名可以使用%TYPE,而且變量、遊標、記錄，或聲明的常量都可以使用%TYPE。這對於定義相同數據類型的變量非常有用。
DECLARE
V_A NUMBER(5) := 10;
V_B V_A%TYPE := 15;
V_C V_A%TYPE;
BEGIN
DBMS_OUTPUT.PUT_LINE('V_A=' || V_A || 'V_B=' || V_B || 'V_C=' || V_C);
END;
SQL>/
V_A=10 V_B=15 V_C=
PL/SQL procedure successfully completed.
SQL>
其他DML語句
其它操作數據的DML語句是:INSERT、UPDATE、DELETE和LOCK TABLE,這些語句在PL/SQL中的語法與在SQL中的語法相同。
我們在前面已經討論過DML語句的使用這裏就不再重複了。在DML語句中可以使用任何在DECLARE部分聲明的變量，如果是嵌套塊，
那麼要注意變量的作用範圍。
例：
CREATE OR REPLACE PROCEDURE FIRE_EMPLOYEE(p_empno in number) AS
begin
declare
v_ename scott.EMP.ENAME%TYPE;
BEGIN
SELECT ename INTO v_ename FROM emp WHERE empno = p_empno;
INSERT INTO FORMER_EMP (EMPNO, ENAME) VALUES (p_empno, v_ename);
DELETE FROM emp WHERE empno = p_empno;
UPDATE former_emp SET HIREDATE = SYSDATE WHERE empno = p_empno;
EXCEPTION
WHEN NO_DATA_FOUND THEN
DBMS_OUTPUT.PUT_LINE('Employee Number Not Found!');
END;
end FIRE_EMPLOYEE;
DML語句的結果
當執行一條DML語句後，DML語句的結果保存在四個遊標屬性中，這些屬性用於控制程序流程或者瞭解程序的狀態。
當運行DML語句時，PL/SQL打開一個內建遊標並處理結果，遊標是維護查詢結果的內存中的一個區域，遊標在運行DML語句時打開，完成後關閉。
隱式遊標只使用SQL%FOUND,SQL%NOTFOUND,SQL%ROWCOUNT三個屬性.SQL%FOUND,SQL%NOTFOUND是布爾值，SQL%ROWCOUNT是整數值。
SQL%FOUND和SQL%NOTFOUND
在執行任何DML語句前SQL%FOUND和SQL%NOTFOUND的值都是NULL,在執行DML語句後，SQL%FOUND的屬性值將是：
. TRUE :INSERT
. TRUE :DELETE和UPDATE，至少有一行被DELETE或UPDATE.
. TRUE :SELECT INTO至少返回一行
當SQL%FOUND爲TRUE時,SQL%NOTFOUND爲FALSE。
SQL%ROWCOUNT
在執行任何DML語句之前，SQL%ROWCOUNT的值都是NULL,對於SELECT INTO語句，如果執行成功，SQL%ROWCOUNT的值爲1,如果沒有成功，
SQL%ROWCOUNT的值爲0，同時產生一個異常NO_DATA_FOUND.
SQL%ISOPEN
df
事務控制語句
事務是一個工作的邏輯單元可以包括一個或多個DML語句，事物控制幫助用戶保證數據的一致性。
如果事務控制邏輯單元中的任何一個DML語句失敗，那麼整個事務都將回滾，
在PL/SQL中用戶可以明確地使用COMMIT、ROLLBACK、SAVEPOINT以及SET TRANSACTION語句。
COMMIT語句終止事務，永久保存數據庫的變化，同時釋放所有LOCK,ROLLBACK終止現行事務釋放所有LOCK，
但不保存數據庫的任何變化,SAVEPOINT用於設置中間點，當事務調用過多的數據庫操作時，中間點是非常有用的，
SET TRANSACTION用於設置事務屬性，比如read-write和隔離級等。
顯式遊標
當查詢返回結果超過一行時，就需要一個顯式遊標，此時用戶不能使用select into語句。PL/SQL管理隱式遊標，
當查詢開始時隱式遊標打開，查詢結束時隱式遊標自動關閉。顯式遊標在PL/SQL塊的聲明部分聲明，
在執行部分或異常處理部分打開，取數據,關閉。下表顯示了顯式遊標和隱式遊標的差別：
使用遊標
這裏要做一個聲明，我們所說的遊標通常是指顯式遊標，因此從現在起沒有特別指明的情況，我們所說的遊標都是指顯式遊標。
要在程序中使用遊標，必須首先聲明遊標。
聲明遊標
語法：
CURSOR cursor_name IS select_statement;
在PL/SQL中游標名是一個未聲明變量，不能給遊標名賦值或用於表達式中。
例：
DELCARE
CURSOR C_EMP IS SELECT empno,ename,salary
FROM emp
WHERE salary>2000
ORDER BY ename;
........
BEGIN
在遊標定義中SELECT語句中不一定非要表可以是視圖，也可以從多個表或視圖中選擇的列，甚至可以使用*來選擇所有的列 。
打開遊標
使用遊標中的值之前應該首先打開遊標，打開遊標初始化查詢處理。打開遊標的語法是：
OPEN cursor_name
cursor_name是在聲明部分定義的遊標名。
例：
OPEN C_EMP;
關閉遊標
語法：
CLOSE cursor_name
例：
CLOSE C_EMP;
從遊標提取數據
從遊標得到一行數據使用FETCH命令。每一次提取數據後，遊標都指向結果集的下一行。語法如下：
FETCH cursor_name INTO variable[,variable,...]
對於SELECT定義的遊標的每一列，FETCH變量列表都應該有一個變量與之相對應，變量的類型也要相同。
例：
DECLARE
v_ename EMP.ENAME%TYPE;
v_salary EMP.SAL%TYPE;
CURSOR c_emp IS
SELECT ename, SAL FROM emp;
BEGIN
OPEN c_emp;
FETCH c_emp
INTO v_ename, v_salary;
DBMS_OUTPUT.PUT_LINE('Salary of Employee' || v_ename || 'is' ||
v_salary);
FETCH c_emp
INTO v_ename, v_salary;
DBMS_OUTPUT.PUT_LINE('Salary of Employee' || v_ename || 'is' ||
v_salary);
FETCH c_emp
INTO v_ename, v_salary;
DBMS_OUTPUT.PUT_LINE('Salary of Employee' || v_ename || 'is' ||
v_salary);
CLOSE c_emp;
END;
這段代碼無疑是非常麻煩的，如果有多行返回結果，可以使用循環並用遊標屬性爲結束循環的條件，以這種方式提取數據，
程序的可讀性和簡潔性都大爲提高，下面我們使用循環重新寫上面的程序：
DECLARE
v_ename EMP.ENAME%TYPE;
v_salary EMP.SAL%TYPE;
CURSOR c_emp IS
SELECT ename, SAL FROM emp;
BEGIN
OPEN c_emp;
LOOP
FETCH c_emp
INTO v_ename, v_salary;
EXIT WHEN c_emp%NOTFOUND;
DBMS_OUTPUT.PUT_LINE('Salary of Employee' || v_ename || 'is' ||
v_salary);
END LOOP;
END;
記錄變量
定義一個記錄變量使用TYPE命令和%ROWTYPE，關於%ROWsTYPE的更多信息請參閱相關資料。
記錄變量用於從遊標中提取數據行，當遊標選擇很多列的時候，那麼使用記錄比爲每列聲明一個變量要方便得多。
當在表上使用%ROWTYPE並將從遊標中取出的值放入記錄中時，如果要選擇表中所有列，
那麼在SELECT子句中使用*比將所有列名列出來要安全得多。
例：
DECLARE
R_emp EMP%ROWTYPE;
CURSOR c_emp IS
SELECT * FROM emp;
BEGIN
OPEN c_emp;
LOOP
FETCH c_emp
INTO r_emp;
EXIT WHEN c_emp%NOTFOUND;
DBMS_OUTPUT.PUT_LINE('Salary of Employee' || r_emp.ename || 'is' ||
r_emp.sal);
END LOOP;
CLOSE c_emp;
END;
%ROWTYPE也可以用遊標名來定義，這樣的話就必須要首先聲明遊標：
DECLARE
CURSOR c_emp IS
SELECT ename, sal FROM emp;
R_emp c_emp%ROWTYPE;
BEGIN
OPEN c_emp;
LOOP
FETCH c_emp
INTO r_emp;
EXIT WHEN c_emp%NOTFOUND;
DBMS_OUTPUT.PUT_LINE('Sal of Employee' || r_emp.ename || 'is' ||
r_emp.sal);
END LOOP;
CLOSE c_emp;
END;