出處：http://blog.csdn.net/maotoula/article/details/6762062
tag:彙編,pascal,fastcall,stdcall,thiscall,cdecl,調用約定,函數調用約定,返回值傳遞方式
摘要：文章講述了幾種主要程序語言中的函數調用約定；詳細說明時主要以VC6中的函數調用約定爲主,闡釋方式主要是以C++程序編譯後得到的彙編代碼來進行說明;
文章來源於abp論壇中的一篇帖子:http://bbs.allaboutprogram.com/viewtopic.php?t=1245
我所使用的編譯器和平臺：WindowsXP + 賽揚1G + VC6(主要工具)/Delphi6/C++Builder6;
一：函數調用約定;
函數調用約定是函數調用者和被調用的函數體之間關於參數傳遞、返回值傳遞、堆棧清除、寄存器使用的一種約定;
它是需要二進制級別兼容的強約定,函數調用者和函數體如果使用不同的調用約定,將可能造成程序執行錯誤,必須把它看作是函數聲明的一部分;
二：常見的函數調用約定;
VC6中的函數調用約定;
調用約定 堆棧清除 參數傳遞
__cdecl 調用者 從右到左,通過堆棧傳遞
__stdcall 函數體 從右到左,通過堆棧傳遞
__fastcall 函數體 從右到左,優先使用寄存器(ECX,EDX),然後使用堆棧
thiscall 函數體 this指針默認通過ECX傳遞,其它參數從右到左入棧
__cdecl是C/C++的默認調用約定; VC的調用約定中並沒有thiscall這個關鍵字,它是類成員函數默認調用約定;
C/C++中的main(或wmain)函數的調用約定必須是__cdecl,不允許更改;
默認調用約定一般能夠通過編譯器設置進行更改,如果你的代碼依賴於調用約定,請明確指出需要使用的調用約定;
Delphi6中的函數調用約定;
調用約定 堆棧清除 參數傳遞
register 函數體 從左到右,優先使用寄存器(EAX,EDX,ECX),然後使用堆棧
pascal 函數體 從左到右,通過堆棧傳遞
cdecl 調用者 從右到左,通過堆棧傳遞(與C/C++默認調用約定兼容)
stdcall 函數體 從右到左,通過堆棧傳遞(與VC中的__stdcall兼容)
safecall 函數體 從右到左,通過堆棧傳遞(同stdcall)
Delphi中的默認調用約定是register,它也是我認爲最有效率的一種調用方式,而cdecl是我認爲綜合效率最差的一種調用方式;
VC中的__fastcall調用約定一般比register效率稍差一些;
C++Builder6中的函數調用約定;
調用約定 堆棧清除 參數傳遞
__fastcall 函數體 從左到右,優先使用寄存器(EAX,EDX,ECX),然後使用堆棧 (兼容Delphi的register)
(register與__fastcall等同)
__pascal 函數體 從左到右,通過堆棧傳遞
__cdecl 調用者 從右到左,通過堆棧傳遞(與C/C++默認調用約定兼容)
__stdcall 函數體 從右到左,通過堆棧傳遞(與VC中的__stdcall兼容)
__msfastcall 函數體 從右到左,優先使用寄存器(ECX,EDX),然後使用堆棧(兼容VC的__fastcall)
常見的函數調用約定中,只有cdecl約定需要調用者來清除堆棧;
C/C++中的函數支持參數數目不定的參數列表,比如printf函數;由於函數體不知道調用者在堆棧中壓入了多少參數,
所以函數體不能方便的知道應該怎樣清除堆棧,那麼最好的辦法就是把清除堆棧的責任交給調用者;
這應該就是cdecl調用約定存在的原因吧;
VB一般使用的是stdcall調用約定;(ps：有更強的保證嗎)
Windows的API中,一般使用的是stdcall約定;(ps: 有更強的保證嗎)
建議在不同語言間的調用中(如DLL)最好採用stdcall調用約定,因爲它在語言間兼容性支持最好;
三:函數返回值傳遞方式
其實，返回值的傳遞從處理上也可以想象爲函數調用的一個out形參數； 函數返回值傳遞方式也是函數調用約定的一部分；
有返回值的函數返回時：一般int、指針等32bit數據值(包括32bit結構)通過eax傳遞，(bool,char通過al傳遞，short通過ax傳遞),特別的__int64等64bit結構(struct) 通過edx,eax兩個寄存器來傳遞(同理：32bit整形在16bit環境中通過dx,ax傳遞); 其他大小的結構(struct)返回時把其地址通過eax返回；(所以返回值類型不是1,2,4,8byte時，效率可能比較差)
參數和返回值傳遞中，引用方式的類型可以看作與傳遞指針方式相同；
float/double(包括Delphi中的extended)都是通過浮點寄存器st(0)返回；
四：通過VC中的C++例子和產生出的彙編清單來對函數調用約定進行說明;
(ps:後面雖然列出了很多彙編,但是我做了很詳細的註釋,我希望那些對彙編感到“恐懼”的人
也能順利的閱讀; 併爲那些想在VC中使用匯編的人提供一些幫助
A:
測試代碼：
int x;
int __cdecl add(int a,int b) { return a+b; }//使用__cdecl調用約定
int main(int argc, char* argv[])
{
x=add(1,2);
return 0;
}
; Debug模式編譯後得到的彙編代碼
PUBLIC ?x@@3HA
; x
_BSS SEGMENT
?x@@3HA DD 01H DUP (?) ; x變量
_BSS ENDS
PUBLIC ?add@@YAHHH@Z ; add
PUBLIC _main
EXTRN __chkesp:NEAR
; COMDAT _main
_TEXT SEGMENT
_main PROC NEAR ; COMDAT //main函數體
push ebp ; //保存ebp的值到堆棧,退出函數前用pop ebp恢復
mov ebp, esp ; //ebp指向當前堆棧; 函數中可以通過ebp來進行堆棧訪問
sub esp, 64 ; //在堆棧中開闢64byte局部空間
; //說明：這三條彙編指令是很多函數體開始的慣用法;
; //用ebp指向堆棧(不會改變);並通過ebp來訪問參數和局部變量;
push ebx ; //一般按照函數間調用的約定,函數中可以自由使用eax,ecx,edx;
push esi ; //其它寄存器如果需要使用則需要保存,用完時恢復；也就是寄存器的使用約定； 這也使函數調用約定的一部分；
push edi ; //即:在函數中調用了別的函數後,eax,ecx,edx很可能已經改變,
; //而其它寄存器(ebx,esi,edi,ebp)的值可以放心繼續使用(esp除外)
lea edi, DWORD PTR [ebp-64]
mov ecx, 16 ; 00000010H
mov eax, -858993460 ; ccccccccH
rep stosd ; //前面開闢的(16*4)byte局部空間全部填充0xCC
; //注意: 0xCC是調試中斷(__asm int 3)的指令碼,所以可以想象,當
; //程序錯誤的跳轉到這個區域進行執行時將產生調試中斷
push 2 ; //代碼: x=add(1,2);
push 1 ; //從右到左入棧 (__cdecl調用約定!!!)
call ?add@@YAHHH@Z ; 調用add函數;call指令將把下一條指令的地址(返回地址)壓入堆棧
add esp, 8 ; add函數調用完以後,調用者負責清理堆棧 (__cdecl調用約定!!!)
; 兩個int型參數共使用了8byte空間的堆棧
mov DWORD PTR ?x@@3HA, eax ; 將add函數的返回值存入x變量中,可以看出add函數的返回值放在eax中
xor eax, eax ; //原代碼:return 0; 執行eax清零,main函數的返回值0放在eax中
pop edi
pop esi
pop ebx ; //恢復edi,esi,ebx寄存器
add esp, 64 ; //恢復64byte局部空間
cmp ebp, esp
call __chkesp ; //到這裏時應該ebp==esp, Debug版進行確認,如果不等,拋出異常等
mov esp, ebp
pop ebp ; //恢復ebp寄存器
ret 0
_main ENDP
_TEXT ENDS
;//下面是add函數的代碼,就不用解釋的像上面那麼詳細了
; COMDAT ?add@@YAHHH@Z
_TEXT SEGMENT
_a$ = 8 ;//參數a相對於堆棧偏移8
_b$ = 12 ;//參數b相對於堆棧偏移12
?add@@YAHHH@Z PROC NEAR ; add, COMDAT //add函數體
push ebp
mov ebp, esp
sub esp, 64 ; 00000040H
push ebx
push esi
push edi
lea edi, DWORD PTR [ebp-64]
mov ecx, 16 ; 00000010H
mov eax, -858993460 ; ccccccccH
rep stosd
mov eax, DWORD PTR _a$[ebp] ;將參數a的值移動到eax
add eax, DWORD PTR _b$[ebp] ;將參數b的值累加到eax; 可以看出返回值通過eax返回
pop edi
pop esi
pop ebx
mov esp, ebp
pop ebp
ret 0 ; 函數體不管堆棧的參數清理 (__cdecl調用約定!!!)
; ret指令將取出call指令壓入的返回地址,並跳轉過去繼續執行
?add@@YAHHH@Z ENDP ; add
_TEXT ENDS
END
; 再來看一下Release模式編譯後得到的彙編代碼
; 可以看出,這比Debug模式少了很多的彙編指令,速度當然可能更快了;不再做詳細說明了,請對照上面的解釋
PUBLIC ?x@@3HA
; x
_BSS SEGMENT
?x@@3HA DD 01H DUP (?) ; x
_BSS ENDS
PUBLIC ?add@@YAHHH@Z ; add
PUBLIC _main
; COMDAT _main
_TEXT SEGMENT
_main PROC NEAR ; COMDAT //main函數體
push 2
push 1 ; //從右到左入棧 (__cdecl調用約定!!!)
call ?add@@YAHHH@Z ; //調用add函數;
mov DWORD PTR ?x@@3HA, eax ; x
add esp, 8 ; //調用者負責清理堆棧 (__cdecl調用約定!!!)
xor eax, eax
ret 0
_main ENDP
_TEXT ENDS
; COMDAT ?add@@YAHHH@Z
_TEXT SEGMENT
_a$ = 8
_b$ = 12
?add@@YAHHH@Z PROC NEAR ; add, COMDAT //add函數體
mov eax, DWORD PTR _b$[esp-4] ;將參數b的值移動到eax
mov ecx, DWORD PTR _a$[esp-4] ;將參數a的值移動到ecx
add eax, ecx ;將ecx的值累加到eax; 返回值通過eax傳遞
ret 0 ;函數體不管堆棧的參數清理 (__cdecl調用約定!!!)
?add@@YAHHH@Z ENDP ; add
_TEXT ENDS
END
下面的分析中將只給出Release模式編譯後的彙編代碼
B:
聲明add函數爲__stdcall調用約定
int x;
int __stdcall add(int a,int b) { return a+b; }
int main(int argc, char* argv[])
{
x=add(1,2);
return 0;
}
;來看產生的彙編代碼：
; //main函數體
push 2
push 1 ; //從右到左入棧
call ?add@@YGHHH@Z ; add
mov DWORD PTR ?x@@3HA, eax ; x
xor eax, eax
ret 0
; //add函數體
mov eax, DWORD PTR _b$[esp-4]
mov ecx, DWORD PTR _a$[esp-4]
add eax, ecx
ret 8 ; //函數體負責清棧 ;兩個int型參數共使用了8byte空間的堆棧
C:
聲明add函數爲__fastcall調用約定
int x;
int __fastcall add(int a,int b) { return a+b; }
int main(int argc, char* argv[])
{
x=add(1,2);
return 0;
}
;來看產生的彙編代碼：
; //main函數體
mov edx, 2 ; b通過寄存器edx傳遞
mov ecx, 1 ; a通過寄存器ecx傳遞
call ?add@@YIHHH@Z ; add
mov DWORD PTR ?x@@3HA, eax ; x
xor eax, eax
ret 0
; //add函數體
lea eax, DWORD PTR [ecx+edx] ; //a,b參數值已經在ecx,edx中,該句將這兩個值的和放到eax作爲返回值;
ret 0 ; //這裏應該函數體負責清棧 ;但因爲兩個參數已經通過寄存器傳遞
; //了,沒有使用堆棧,所以ret 0;
D:
來看一下類的成員函數的調用：
struct T
{
int start0;
T():start0(1){}
int add(int a,int b); //類成員函數;只要不明確聲明調用約定則默認使用thiscall調用約定;
};
int T::add(int a,int b) { return (*this).start0+a+b; }
int x;
int main(int argc, char* argv[])
{
T t;
x=t.add(1,2);
return 0;
}
來看產生的彙編代碼：
; //main函數體
push ecx ; //保存ecx
push 2
push 1 ; //參數從右到左入棧
lea ecx, DWORD PTR _t$[esp+12] ; //t的地址保存到ecx
mov DWORD PTR _t$[esp+12], 1 ; //執行t::start0=1;
call ?add@T@@QAEHHH@Z ; //調用T::add函數,這時ecx中存放了t的的地址(this指針);
mov DWORD PTR ?x@@3HA, eax ; x
xor eax, eax
pop ecx
ret 0
; //T::add函數體
mov eax, DWORD PTR [ecx] ; //通過this指針(保存在ecx)將start0的值移動到eax
mov ecx, DWORD PTR _a$[esp-4] ; //把a的值移動到ecx; this的值將丟失,但函數體中已經不需要了
add eax, ecx ; //將a的值累加到eax
mov ecx, DWORD PTR _b$[esp-4] ; //把b的值移動到ecx;
add eax, ecx ; //將b的值累加到eax
ret 8 ; //函數體負責清棧 ;
五: 其他
1.在VC中實現一個函數體時可以使用__declspec(naked)聲明,它告訴編譯器,不要爲函數體自動產生開始和結束碼;
2.在VC6中,想得到彙編代碼清單,設置方法爲：
引用:[Project]->[Setting...]->[C++]->[Category:]->[Listing Files]->[Listing file type:]->[Assembily ,...]
3.VC6中嵌入彙編代碼的方式爲：
__asm { <彙編語句s> }
或 __asm <一條彙編語句>
4.VC6中重新設定函數使用的默認調用約定的方法是：
引用:
在[Project]->[Setting...]->[C++]->[Project Options:]中增加編譯設置
比如：/Gd 代表__cdecl; /Gr 代表__fastcall; /Gz 代表__stdcall
轉自：http://blog.csdn.net/housisong/article/details/504970
當高級語言函數被編譯成機器碼時，有一個問題就必須解決：因爲CPU沒有辦法知道一個函數調用需要多少個、什麼樣的參數。即計算機不知道怎麼給這個函數傳遞參數，傳遞參數的工作必須由函數調用者和函數本身來協調。爲此，計算機提供了一種被稱爲棧的數據結構來支持參數傳遞。
函數調用時，調用者依次把參數壓棧，然後調用函數，函數被調用以後，在堆棧中取得數據，並進行計算。函數計算結束以後，或者調用者、或者函數本身修改堆棧，使堆棧恢復原裝。在參數傳遞中，有兩個很重要的問題必須得到明確說明：
1) 當參數個數多於一個時，按照什麼順序把參數壓入堆棧；
2) 函數調用後，由誰來把堆棧恢復原裝。
3）函數的返回值放在什麼地方
在高級語言中，通過函數調用規範(Calling Conventions)來說明這兩個問題。常見的調用規範有：
stdcall cdecl fastcall thiscall naked call
stdcall調用規範
stdcall很多時候被稱爲pascal調用規範，因爲pascal是早期很常見的一種教學用計算機程序設計語言，其語法嚴謹，使用的函數調用約定是stdcall。在Microsoft C++系列的C/C++編譯器中，常常用PASCAL宏來聲明這個調用約定，類似的宏還有WINAPI和CALLBACK。
stdcall調用規範聲明的語法爲：
int __stdcall function(int a,int b)
1）參數從右向左壓入堆棧；
2）函數自身修改堆棧；
3) 函數名自動加前導的下劃線，後面緊跟一個@符號，其後緊跟着參數的尺寸。
push 2 第二個參數入棧 push 1 第一個參數入棧 call function 調用參數，注意此時自動把cs:eip入棧
push ebp 保存ebp寄存器，該寄存器將用來保存堆棧的棧頂指針，可以在函數退出時恢復 mov ebp,esp 保存堆棧指針 mov eax,[ebp + 8H] 堆棧中ebp指向位置之前依次保存有ebp,cs:eip,a,b,ebp +8指向a add eax,[ebp + 0CH] 堆棧中ebp + 12處保存了b mov esp,ebp 恢復esp pop ebp ret 8
而在編譯時，這個函數的名字被翻譯成_function@8
注意不同編譯器會插入自己的彙編代碼以提供編譯的通用性，但是大體代碼如此。其中在函數開始處保留esp到ebp中，在函數結束恢復是編譯器常用的方法。
從函數調用看，2和1依次被push進堆棧，而在函數中又通過相對於ebp(即剛進函數時的堆棧指針）的偏移量存取參數。函數結束後，ret 8表示清理8個字節的堆棧，函數自己恢復了堆棧。
cdecl調用規範
cdecl調用約定又稱爲C調用約定，是C語言缺省的調用約定，它的定義語法是：
int function (int a ,int b) // 不加修飾就是C調用約定 int __cdecl function(int a,int b) // 明確指出C調用約定
cdecl調用約定的參數壓棧順序是和stdcall是一樣的，參數首先由有向左壓入堆棧。所不同的是，函數本身不清理堆棧，調用者負責清理堆棧。由於這種變化，C調用約定允許函數的參數的個數是不固定的，這也是C語言的一大特色。對於前面的function函數，使用cdecl後的彙編碼變成：
調用處 push 1 push 2 call function add esp,8 注意：這裏調用者在恢復堆棧
被調用函數_function處 push ebp 保存ebp寄存器，該寄存器將用來保存堆棧的棧頂指針，可以在函數退出時恢復 mov ebp,esp 保存堆棧指針 mov eax,[ebp + 8H] 堆棧中ebp指向位置之前依次保存有ebp,cs:eip,a,b,ebp +8指向a add eax,[ebp + 0CH] 堆棧中ebp + 12處保存了b mov esp,ebp 恢復esp pop ebp ret 注意，這裏沒有修改堆棧
MSDN中說，該修飾自動在函數名前加前導的下劃線，因此函數名在符號表中被記錄爲_function。
由於參數按照從右向左順序壓棧，因此最開始的參數在最接近棧頂的位置，因此當採用不定個數參數時，第一個參數在棧中的位置肯定能知道，只要不定的參數個數能夠根據第一個後者後續的明確的參數確定下來，就可以使用不定參數，例如對於sprintf函數，定義爲：
int sprintf(char* buffer,constchar* format,...)
fastcall調用規範
1) 函數的第一個和第二個DWORD參數（或者尺寸更小的）通過ecx和edx傳遞，其他參數通過從右向左的順序壓棧；
2) 被調用函數清理堆棧；
3) 函數名修改規則同stdcall。
thiscall調用規範
thiscall是唯一一個不能明確指明的函數修飾，因爲thiscall不是關鍵字。它是C++類成員函數缺省的調用約定。由於成員函數調用還有一個this指針，因此必須特殊處理，thiscall意味着：
1) 參數從右向左入棧；
2) 如果參數個數確定，this指針通過ecx傳遞給被調用者；如果參數個數不確定，this指針在所有參數壓棧後被壓入堆棧；
3) 對參數個數不定的，調用者清理堆棧，否則函數自己清理堆棧。
class A { public: int function1(int a,int b); int function2(int a,...); }; int A::function1 (int a,int b) { return a+b; } int A::function2(int a,...) { va_list ap; va_start(ap,a); int i; int result = 0; for(i = 0 ; i < a ; i ++) { result += va_arg(ap,int); } return result; } void callee() { A a; a.function1(1,2); a.function2(3,1,2,3); }
// 函數function1調用 0401C1D push 2 00401C1F push 1 00401C21 lea ecx,[ebp-8] 00401C24 call function1 注意，這裏this沒有被入棧 // 函數function2調用 00401C29 push 3 00401C2B push 2 00401C2D push 1 00401C2F push 3 00401C31 lea eax,[ebp-8] 這裏引入this指針 00401C34 push eax 00401C35 call function2 00401C3A add esp,14h
naked call調用規範
__declspec(naked) int add(int a,int b) { __asm mov eax,a __asm add eax,b __asm ret }
mov eax,[ebp+8] add eax,[ebp+12] ret 8
__declspec(naked) int __stdcall function(int a,int b) { __asm mov eax,a __asm add eax,b __asm ret 8//注意後面的8 }
函數調用約定導致的常見問題
1) 函數原型聲明和函數體定義不一致
2) DLL導入函數時聲明瞭不同的函數約定