系統狀態備份腳本

將以下腳本保存爲vbs格式

********************************************************************************************

'備份系統狀態，以日期命名，並刪除早於指定日期的備份文件

strFolder = "D:\SystemBackup\"
strFileName = Date() &".BAK"
intKeepDay = 4
strBackupCmd = "Ntbackup.exe backup systemstate /J ""定時備份系統狀態""" _
 &"/F """ &strFolder &strFileName &""""

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(strFolder)
Set objFiles = objFolder.Files
For Each objFile In objFiles
 If objFile.DateCreated < Date() - intKeepDay And Right(objFile.Name,3) = "BAK" Then
  objFile.Delete
 End If
Next

Set objWshShell = CreateObject("WScript.Shell")
Return = objWshShell.Run(strBackupCmd,0,True)
If Return = 0 Then 
 objWshShell.LogEvent 0,Now() &" 備份系統狀態成功"
Else
 objWshShell.LogEvent 1,Now() &" 備份系統狀態失敗"
End If

***************************************************************************************************

腳本說明：

 

腳本作用：

備份Windows系統狀態（System State）到指定目錄，並刪除早於指定天數的備份。

使用方法：

（1）在有足夠磁盤空間的分區上建立目錄SystemBackup，將腳本拷貝到該目錄下。通常情況下，每次系統狀態備份文件大小爲600-1000MB，請確保有足夠的磁盤空間；

（2）修改腳本的以下部分，按照需要設置備份文件保存目錄，文件名後綴，以及備份文件保留天數：

strFolder = "D:\SystemBackup\"

strFileName = Date() &".BAK"

intKeepDay = 4

（3）配置完成後，可直接運行腳本，測試正常後，建議將腳本運行配置爲定時任務；

（4）確認系統服務“Task Scheduler”已經啓動，啓動模式設置爲“自動”；

（5）從“控制面板”-“計劃任務”中添加定時任務，“運行”中填寫：

C:\Windows\system32\cscript.exe "D:\SystemBackup\SysBackup.vbs"

“起始於”填寫：

D:\systemBackup

“運行方式”中配置有足夠權限的用戶帳戶（管理員帳戶或者已經加入Backup Operators組的用戶賬戶）。

“日程安排”設置爲“每天一次”，“開始時間”爲較爲空閒的時間，例如20:00-0:00之間

（6）計劃任務配置後，測試是否正確。腳本運行成功與否，可以查看Windows日誌的“應用程序”日誌。

本文出自 “小飛俠的博客” 博客，請務必保留此出處http://wuxiaohui.blog.51cto.com/697989/424587