perl XML::Parser使用object方法處理XML

參考資料：http://search.cpan.org/~msergeant/XML-Parser-2.36/Parser.pm中的Object解說。

操作文件：

[root@dou xml]# cat sample1
<FORECAST>
  <OUTLOOK>
    Partly Cloudy
  </OUTLOOK>
  <TEMPERATURE TYPE="MAX" DEGREES="C">12</TEMPERATURE>
  <TEMPERATURE TYPE="MIN" DEGREES="C">6</TEMPERATURE>
</FORECAST>
[root@dou xml]#
 

腳本：

[root@dou xml]# cat sample3.pl
#!/usr/bin/perl -w
use strict;
use XML::Parser;

my $file = "sample1";
my $p = XML::Parser->new(Style =>'Objects');
my $doc = $p->parsefile($file);

process_node($doc->[0]);
sub process_node {
        my($node) = @_;
        my $type = ref $node;
        $type =~ s/^.*:://;
        if ($type eq 'OUTLOOK') {
                my $attr = {%$node};
                my $outlook = $attr->{Kids}->[0];
                my $outlookcont = $outlook->{Text};
                exchange($outlookcont);
        }elsif ($type eq 'TEMPERATURE') {
                my $attr = {%$node};
                my $temperature = $attr->{Kids}->[0];
                my $tempnum = $temperature->{Text};
                print "$attr->{TYPE}:",$tempnum," $attr->{DEGREES}","\n";
        }
        else {
                foreach my $node (@{$node->{Kids}}) {
                        process_node($node);
                }
        }
}
sub exchange {
        my $value = shift;
        $value =~ s/\n/ /g;
        $value =~ s/^\s+//;
        $value =~ s/\s+$//;
        print "OUTLOOK: $value\n";
}
[root@dou xml]#
 

執行結果：

[root@dou xml]# perl sample3.pl
OUTLOOK: Partly Cloudy
MAX:12 C
MIN:6 C
[root@dou xml]#
 

腳本解說：

想要明白Object怎麼操縱XML的，需要理解經過Object之後的XML生成的數據結構是怎麼樣的，比如：使用Data::Dumper來分析下生成的數據結構，然後去操作該數據結構即可。