文本處理工具三劍客之awk詳解

awk簡介

awk: 中文意思是報告生成器能夠根據我們輸入的信息，將信息格式化以後顯示，將定義好的信息以比較美觀（直觀）的方式顯示出來出現比較早，繼而出現了new awk（nawk）在windows上實現，gawk, awk實現在linux上。awk是一種編程語言，用於在linux/unix下對文本和數據進行處理。數據可以來自標準輸入、一個或多個文件，或其它命令的輸出。它支持用戶自定義函數和動態正則表達式等先進功能，是linux/unix下的一個強大編程工具。它在命令行中使用，但更多是作爲腳本來使用。awk的處理文本和數據的方式是這樣的，它逐行掃描文件，從第一行到最後一行，尋找匹配的特定模式的行，並在這些行上進行你想要的操作。如果沒有指定處理動作，則把匹配的行顯示到標準輸出(屏幕)，如果沒有指定模式，則所有被操作所指定的行都被處理。awk分別代表其作者姓氏的第一個字母，分別是Alfred Aho、Brian Kernighan、Peter Weinberger。gawk是awk的GNU版本，它提供

了Bell實驗室和GNU的一些擴展。下面就對awk進行介紹。

awk使用的基本格式：

# awk [options] 'script' file1 file2, ...
# awk [options] 'PATTERN { action }' file1 file2, ...細化了上面的組合
常用的命令：print（輸出）, printf（打印）

awk工作過程

根據我們所定義的模式，一次從文件中讀取一行文本，awk會對取出的文本做相應的切片，將每一行按照分隔符進行切割，假如我們有一行文本： this is a test.它會使用空白字符當做分隔符，將它們各個分開，切割成了四個片，分別爲： this is a test.這四個片，可以使用變量，分別對應爲$1,$2,$3,$4代表四個切割片，下面就做一個演示，看如何實現awk的強大功能

一、awk的輸出：print

print的使用格式：
print item1, item2, ...

輸出要點：

1、各項目之間使用逗號隔開，而輸出時則以空白字符分隔；

2、輸出的item可以爲字符串或數值、當前記錄的字段(如$1)、變量或awk的表達式；數值會先轉換爲字符串，而後再輸出；

3、print命令後面的item可以省略，此時其功能相當於print $0, 因此，如果想輸出空白行，則需要使用print ""；

實例分析：

顯示整個文本（注意，這裏只是測試，所以只有一行）
#  awk '{print $N}' test.txt
this is a test.
# awk '{print $0}' test.txt
this is a test.
顯示文本的一行中的第一個參數
# awk '{print $1}' test.txt
this
顯示文本的一行中的第二個參數
# awk '{print $2}' test.txt
is
顯示文本的一行中的第四個參數
# awk '{print $4}' test.txt
test.
顯示文本的一行中的第一與第二個個參數
# awk '{print $1,$2}' test.txt
this is
顯示文本的一行中的第一個與第二個參數，中間可以加#號
# awk 'BEGIN{OFS="#"}{print $1,$2}' test.txt
this#is
顯示文本中的各個參數，還可以加修飾符
# awk 'BEGIN{OFS=":"}{print $1,$2,$3,$4}' test.txt
this:is:a:test.
顯示文本中的參數，還可以加修飾符，還可以加字符串
#  awk 'BEGIN{OFS=":"}{print $1,"hello",$2}' test.txt
this:hello:is
輸出三行，注意換行需要加\n
# awk 'BEGIN { print "line one\nline two\nline three" }'
line one
line two
line three

二、awk變量

2.1 awk內置變量之記錄變量：

FS: field separator，讀取文本時所使用的字段分隔符
RS: Record separator，讀取文本信息所使用的換行符
OFS: Output Filed Separator: 輸出文本時使用的字段分隔符
ORS：Output Row Separator：輸出文本時使用的行分隔符

2.2 awk內置變量之數據變量：

NR: The number of input records，awk命令所處理的記錄數；如果有多個文件，這個數目會把處理的多個文件中行統一計數；

NF：Number of Field，當前記錄的field個數；

FNR: 與NR不同的是，FNR用於記錄正處理的行是當前這一文件中被總共處理的行數；

實例分析：

顯示文本的行數
# awk '{print NR}' test.txt
1
顯示一行總共有幾個參數
# awk '{print NF}' test.txt
4
顯示文本的最後一個參數
# awk '{print $NF}' test.txt
test.
同時查看多個文本 
# awk '{print FNR}' test.txt /etc/fstab
1  顯示的是第一個文本的行數
1  顯示的是第二個文本的第一行數，一此類推
2  顯示的是第二個文本的第二行數
3  顯示的是第二個文本的第三行數

ARGV: 數組，保存命令行本身這個字符串，如awk '{print $0}' a.txt b.txt這個命令中，ARGV[0]保存awk，ARGV[1]保存a.txt；

ARGC: awk命令的參數的個數；

FILENAME: awk命令所處理的文件的名稱；

ENVIRON：當前shell環境變量及其值的關聯數組；

查看環境變量
# awk 'BEGIN{print ENVIRON["PATH"]}'
/usr/kerberos/sbin:/usr/kerberos/bin:/usr/local/sbin:/usr/local/bin:/sbin:/
bin:/usr/sbin:/usr/bin:/usr/local/apache/bin:/usr/local/mysql/bin:/root/bin

2.3 用戶自定義變量

gawk允許用戶自定義自己的變量以便在程序代碼中使用，變量名命名規則與大多數編程語言相同，只能使用字母、數字和下劃線，且不能以數字開頭。gawk變量名稱區分字符大小寫。

2.3.1 在腳本中賦值變量

在gawk中給變量賦值使用賦值語句進行

2.3.2 在命令行中使用賦值變量

gawk命令也可以在“腳本”外爲變量賦值，並在腳本中進行引用。

實例分析：

輸出一個變量，並賦值
# awk 'BEGIN{var="variable testing";print var}'
variable testing
# awk -v var="variable testing" 'BEGIN{print var}'
variable testing

三、awk打印工具：printf

printf命令的使用格式：
printf format, item1, item2, ...

printf要點：

1、其與print命令的最大不同是，printf需要指定format；

2、format用於指定後面的每個item的輸出格式；

3、printf語句不會自動打印換行符；需要添加\n

format格式的指示符都以%開頭，後跟一個字符；如下：

%c: 顯示第一個參數的第一個字符

%d, %i：十進制整數；

%e, %E：科學計數法顯示數值；

%f: 顯示浮點數；

%g, %G: 以科學計數法的格式或浮點數的格式顯示數值；

%s: 顯示字符串；

%u: 無符號整數；

%%: 顯示%自身；

修飾符：

N: 顯示寬度；

-: 左對齊；

+：顯示數值符號；

舉例分析：

# awk '{printf "%c\n",$1}' test.txt
t 顯示第一個參數的第一個字母
# awk '{printf "%s\n",$1}' test.txt
this  顯示第一個參數
# awk '{printf "%10s\n",$1}' test.txt
      this 顯示時用了10個字符串，默認是右對齊
# awk '{printf "%-10s\n",$1}' test.txt
this  顯示時左對齊，後面有6個空字符串
# awk '{printf "%-10s,%-10s\n",$1,$2}' test.txt
this      ,is 
# awk '{printf "%-10s%-10s\n",$1,$2}' test.txt
this      is  
# awk -F: '{printf "%5d",$3}' /etc/passwd
    0    1    2    3    4    5    6    7    8    9   10   11   12   13   14   99   81   28   69   77   38   70   32   47   51   74   16   68  100   2965534   43   42  500  501  502  503 2002 2003 2004 4004 2033 2034 4005 4006 4007 4011 4017 4018 4019 4026 4027 4028   48   25  101
# awk -F: '{printf "%-5d\n",$3}' /etc/passwd   左對齊
# awk -F: '{printf "%+5d\n",$3}' /etc/passwd   右對齊
# awk -F: '{printf "%-15s %i\n",$1,$3}' test.txt
this is a test. 0

四、輸出重定向

print items > output-file
print items >> output-file
print items | command
特殊文件描述符：
/dev/stdin：標準輸入
/dev/sdtout: 標準輸出
/dev/stderr: 錯誤輸出
/dev/fd/N: 某特定文件描述符，如/dev/stdin就相當於/dev/fd/0；
例子：
# awk -F: '{printf "%-15s %i\n",$1,$3 > "/dev/stderr" }' /etc/passwd
root            0
bin             1
daemon          2
adm             3
lp              4
sync            5
shutdown        6
halt            7

五、awk的操作符：

5.1 算術操作符：

-x: 負值

+x: 轉換爲數值；

x^y:

x**y: 次方

x*y: 乘法

x/y：除法

x+y:

x-y:

x%y:

5.2 字符串操作符：

只有一個，而且不用寫出來，用於實現字符串連接；

5.3 賦值操作符：

=、+=、-=、*=、/=、%=、^=、**=、++、--

需要注意的是，如果某模式爲=號，此時使用/=/可能會有語法錯誤，應以/[=]/替代；

5.4 布爾值

awk中，任何非0值或非空字符串都爲真，反之就爲假；

5.5 比較操作符：

x < y      x小於y爲真，反之爲假
x <= y     x小於等於y爲真，反之爲假
x > y      x大於y爲真，反之爲假
x >= y     x大於等於y爲真，反之爲假
x == y    x恆等於y爲真，反之爲假
x != y    x不等於y爲真，反之爲假
x ~ y   True if the string x matches the regexp denoted by y.
x !~ y  True if the string x does not match the regexp denoted by y.
subscript in array    True if the array array has an element with the
subscript subscript.

5.5 表達式間的邏輯關係符：

&&：邏輯與

|| ：邏輯或

5.6 條件表達式：相當於if語句

舉例：若a大於b，則取a is max，反之取b is max
a=3
b=4
a>b?a is max:b is max

5.7 函數調用：

function_name (para1,para2)

六、awk的模式：

awk 'program' input-file1 input-file2 ...

其中的program爲:

pattern { action }

...

6.1 常見的模式類型：

1、Regexp: 正則表達式，格式爲/regular expression/

例如：顯示以r開頭的行
# awk -F: '/^r/{print $1}' /etc/passwd
root
rpc
rpcuser

2、expresssion：表達式，其值非0或爲非空字符時滿足條件，如：$1 ~ /foo/ 或 $1 == "magedu"，用運算符~(匹配)和~!(不匹配)。

例題：
顯示id號小於等於2的用戶和id號
# awk -F: '$3-1<5{print $1,$3}' /etc/passwd
root 0
bin 1
daemon 2
# awk -F: '$3<=5{print $1,$3}' /etc/passwd
root 0
bin 1
daemon 2
取出默認shell爲bash的用戶
# awk -F: '$7~"bash$"{print $1,$7}' /etc/passwd
root /bin/bash
student /bin/bash
visitor /bin/bash
myuseradd /bin/bash
顯示默認shell不是bash的用戶
# awk -F: '$7!~"bash"{print $1,$7}' /etc/passwd
bin /sbin/nologin
daemon /sbin/nologin
adm /sbin/nologin
lp /sbin/nologin

3、Ranges：指定的匹配範圍，格式爲pat1,pat2

顯示id號爲0或者shell爲/sbin/nologin的用戶
# awk -F: '$3==0,$7~"nologin"{print $1,$3,$7}' /etc/passwd
root 0 /bin/bash
bin 1 /sbin/nologin

4、BEGIN/END：特殊模式，僅在awk命令執行前運行一次或結束前運行一次

# awk -F: '$3==0,$7~"nologin"{printf "%-10s%-20s\n",$1,$7}' /etc/passwd
root      /bin/bash          
bin       /sbin/nologin
可以在顯示時顯示錶頭
# awk -F: 'BEGIN{print "Username shell"}{printf "%-10s%-20s\n",$1,$7}' /etc/passwd
Username      shell
root      /bin/bash          
bin       /sbin/nologin      
daemon    /sbin/nologin      
adm       /sbin/nologin 
顯示錶頭和表尾
#  awk -F: 'BEGIN{print "Username  shell"} {printf "%-10s%-20s\n",$1,$7}END
{print "END OF report"}' /etc/passwd
Username      shell
root      /bin/bash          
bin       /sbin/nologin      
daemon    /sbin/nologin      
adm       /sbin/nologin   
END OF report

5、Empty(空模式)：匹配任意輸入行，對文件中的每一行做匹配

# awk -F:  '{printf "%-10s%-20s\n",$1,$7}' /etc/passwd
root      /bin/bash          
bin       /sbin/nologin      
daemon    /sbin/nologin      
adm       /sbin/nologin

6.2 常見的Action（動作）

1、Expressions:表達式
2、Control statements：控制語句（if、while...do、for....等待)
3、Compound statements:複合語句
4、Input statements：輸入語句
5、Output statements：輸出語句

/正則表達式/：使用通配符的擴展集。

關係表達式：可以用下面運算符表中的關係運算符進行操作，可以是字符串或數字的比較，如$2>%1選擇第二個

字段比第一個字段長的行。

模式匹配表達式：

模式，模式：指定一個行的範圍。該語法不能包括BEGIN和END模式。

BEGIN：讓用戶指定在第一條輸入記錄被處理之前所發生的動作，通常可在這裏設置全局變量。

END：讓用戶在最後一條輸入記錄被讀取之後發生的動作。

七、控制語句：

7.1 if-else

語法：if (condition) {then-body} else {[ else-body ]}

實例分析：

若用戶是root則顯示“admin”否則顯示爲“Common user”
# awk -F: '{if ($1=="root") print $1,"admin"; else print $1, "Common user"}' /etc/passwd
root admin
bin Common user
daemon Common user
adm Common user
lp Common user
這是對上面的語法格式化了，看起來更美觀
# awk -F: '{if ($1=="root") printf "%-15s: %s\n", $1,"Admin"; else printf "%-15s: %s\n", $1, "Common User"}' /etc/passwd
root           : Admin
bin            : Common User
daemon         : Common User
adm            : Common User
lp             : Common User
統計id號大於等於500的用戶個數
# awk -F: -v sum=0 '{if ($3>=500) sum++}END{print sum}' /etc/passwd
21

7.2 while

語法： while (condition){statement1; statment2; ...}

實例分析：

顯示字符串大於等於8的（每一個字符串都要做一下判斷）
# awk -F: '{i=1;while (i<=NF) {if (length($i)>=8) {print $i}; i++ }}' /etc/passwd
/bin/bash
/sbin/nologin
/sbin/nologin
/var/adm
/sbin/nologin
/var/spool/lpd
顯示字符串大於等於4的
# awk -F: '{i=1;while (i<=NF){if (length($i)>=4) {print $i}; i++}}' /etc/passwd
root
root
/root
/bin/bash
/bin
/sbin/nologin
daemon
daemon

7.3 do-while

語法： do {statement1, statement2, ...} while (condition)

顯示字符串小於等於4的（注意使用do語句時，先執行的是條件）
# awk -F: '{i=1;do {print $i;i++}while(i<=3)}' /etc/passwd
root
x
0
bin

7.4 for

語法： for ( variable assignment; condition; iteration process) { statement1, statement2, ...}

例題：

1、顯示字符串大於等於4的
# awk -F: '{for(i=1;i<=NF;i++) {if (length($i)>=4) {print $i}}}' /etc/passwd
root
root
/root
/bin/bash
2、顯示字符串小於等於4的
# awk -F: '{for(i=1;i<=3;i++) print $i}' /etc/passwd
root
x
0
bin
for循環還可以用來遍歷數組元素：
語法： for (i in array) {statement1, statement2
例如：顯示
# awk -F: '$NF!~/^$/{BASH[$NF]++}END{for(A in BASH){printf "%-15s:%i\n",A,BASH[A]}}' /etc/passwd
/bin/sync      :1
/bin/bash      :20
/sbin/nologin  :31
/sbin/halt     :1
/etc/tcsh      :1
/sbin/shutdown :1

7.5 case

語法：switch (expression) { case VALUE or /REGEXP/: statement1, statement2,... default:

statement1, ...}

7.6 break 和 continue

常用於循環或case語句中

7.7 next

提前結束對本行文本的處理，並接着處理下一行；例如，下面的命令將顯示其ID號爲奇數的用戶：

# awk -F: '{if($3%2==0) next;print $1,$3}' /etc/passwd
bin 1
adm 3
sync 5
halt 7
news 9
operator 11

八、awk中使用數組

8.1 數組

array[index-expression]

index-expression可以使用任意字符串；需要注意的是，如果某數據組元素事先不存在，那麼在引用其時，awk會自動創建此元素並初始化爲空串；因此，要判斷某數據組中是否存在某元素，需要使用index in array的方式。要遍歷數組中的每一個元素，需要使用如下的特殊結構：

for (var in array) { statement1, ... }

顯示各個shell的個數和
# awk -F: '{shell[$NF]++}END{for(A in shell) {print A,shell[A]}}' /etc/passwd
 1
/bin/sync 1
/bin/bash 20
/sbin/nologin 31
/sbin/halt 1
/etc/tcsh 1
/sbin/shutdown 1
其中，var用於引用數組下標，而不是元素值；
統計tcp連接狀態的個數（$6也是最後一個字段，可以使用$NF)
# netstat -ant | awk '/^tcp/ {STATE[$NF]++} END {for(a in STATE) print a, STATE[a]}'
LISTEN 11
ESTABLISHED 2
每出現一次被/^tcp/模式匹配到的行，數組S[$NF]就加1，NF爲當前匹配到的行的
最後一個字段，此處用其值做爲數組S的元素索引；
統計訪問本地的IP及個數
# awk '{count[$1]++}END{for(ip in count) {printf "%-20s:%d\n",ip,count[ip]}}'
/var/log/httpd/access_log
192.168.10.1      ：1
172.16.50.5       ：10
用法與上一個例子相同，用於統計某日誌文件中IP地的訪問量

8.2 刪除數組變量

從關係數組中刪除數組索引需要使用delete命令。使用格式爲：

delete array[index]

九、awk的內置函數

split(string, array [, fieldsep [, seps ] ])

功能：將string表示的字符串以fieldsep爲分隔符進行分隔，並將分隔後的結果保存至array爲名的數組中；數組下標爲從0開始的序列；

# netstat -ant | awk '/:80\>/{split($5,clients,":");IP[clients[1]]++}END{for(i in IP){print IP[i],i}}' | sort -rn | head -50

length([string])

功能：返回string字符串中字符的個數；

substr(string, start [, length])

功能：取string字符串中的子串，從start開始，取length個；start從1開始計數；

system(command)

功能：執行系統command並將結果返回至awk命令

systime()

功能：取系統當前時間

tolower(s)

功能：將s中的所有字母轉爲小寫

toupper(s)

功能：將s中的所有字母轉爲大寫

十、用戶自定義函數

自定義函數使用function關鍵字。格式如下：

function F_NAME([variable])

{

statements

}

函數還可以使用return語句返回值，格式爲“return value”。

文本處理工具三劍客之awk詳解

AI 畫圖真刺激，手把手教你如何用 ComfyUI 來畫出刺激的圖

公司剛入職了一名 Java 中級開發，短短 4 行代碼居然湊齊了 3 個 bug！我哭了~~

公衆號5月C#/.NET熱文一覽

git 下載大陸鏡像地址

iptables系列之基礎原理+基礎應用+顯示擴展

安全工具ssl

我的友情鏈接

手把手教你實現MySQL的主從複製及半同步複製

vsftpd+pam+mysql

https://yachay.unat.edu.pe/blog/index.php?comment_area=format_blog&comment_component=blog&comment_co

linux以太網驅動總結