使用組策略計算機啓動腳本部署 Office 2010

在測試環境中部署 Office 2010

本節闡述並介紹了組策略計算機啓動腳本基礎設施的測試網絡環境。它還包括了使用組策略計算機啓動腳本部署 Microsoft Office Professional Plus 2010 的過程步驟。

網絡環境

下圖中顯示了本文的測試網絡環境。

所有服務器（A 和 B）都運行 Windows Server 2008 R2，並且是同一域 (CPANDL.COM) 的成員，該域包括運行 Windows 7 Professional 和 Windows Vista 的客戶端計算機 (C)。每臺客戶端計算機的完全限定的域名 (FQDN)、每臺服務器所運行的應用程序和角色、帶有所含計算機的組織單位 (OU) 以及組策略對象 (GPO) 如下所列：

• A – <DC.CPANDL.COM> Active Directory、DNS、DHCP、GPO-Office2010_GPO、OU-Office2010_OU、W7C01 和 WVC02 是 OU Office2010_OU 的成員

• B – <FS.CPANDL.COM> 文件服務、文件共享-\\FS\Office2010SourceFiles（只讀訪問）、文件共享-\\FS\Office2010LogFiles（讀寫訪問）

• C – <W7C01.CPANDL.COM 和 WVC02.CPANDL.COM> Windows 7 Professional 和 Windows Vista Enterprise

重要：

確保經過驗證的用戶對網絡共享具有讀取訪問權限。在此示例中，網絡共享爲 \\FS\Office2010SourceFiles。

注意：

Office2010_GPO 鏈接到 Office2010_OU。這樣，就能夠將 GPO 的設置分配給 OU 內所含的計算機對象。若要將 GPO 鏈接到 OU，請使用 MMC 管理單元“組策略管理”。

在生產環境中自定義並部署 Office 2010 之前，我們建議您閱讀以下文章：規劃 Office 2010 的批量激活、部署 Office 2010 的批量激活、Office 2010 自定義概述、爲 Office 2010 創建網絡安裝點、2007 Office system 中的 Office 自定義工具、Office 2010 中的 Config.xml 文件、自定義 Office 2010 和 64 位 Office 2010 版本。

自定義 Office 2010 安裝程序

用於爲 Office 2010 創建安裝程序自定義文件的程序文件是從包含 Office 安裝 CD 中所有文件的副本的源目錄中運行的。在本例中，源文件已複製到 \\FS\Office2010SourceFiles。

在 Office 2010 中，由安裝程序來控制整個安裝。這包括 Windows Installer 在 2007 Office system 之前的 Office 版本中處理的過程。自定義安裝程序的默認行爲使您可以控制過程。在本例中，您使用 Config.xml 文件來自定義 Office 2010 無提示安裝的安裝，並使用 Office 自定義工具 (OCT) 來自定義 Office 2010 產品的安裝，例如，指定批量許可證密鑰和選擇要安裝 Microsoft Office 中的哪些應用程序。在計算機上安裝 Office 時，安裝程序將應用 config.xml 和 .msp 文件（通過使用 OCT 創建）中的自定義項。

在 Config.xml 中指定無提示安裝選項

若要爲 Office 2010 產品配置不需要用戶交互的無提示安裝（無人蔘與安裝），請爲要安裝的產品修改 Config.xml 文件並將 Display 元素的 Level 屬性設置爲 "none" (Display Level="none")，然後保存 Config.xml 文件，如以下過程所示。Display 元素指定安裝程序向用戶顯示的用戶界面級別。

1. 使用文本編輯器工具（例如記事本）打開所安裝 Office 產品（本例中爲 Office Professional Plus 2010）的 Config.xml 文件。默認情況下，Config.xml 文件位於核心產品 .WW 文件夾（本例中爲 \\FS\Office2010SourceFiles\ProPlus.WW）中。

2. 找到包含 Display 元素的行，如下面的示例所示：

   <!-- <Display Level="full" CompletionNotice="yes" SuppressModal="no" AcceptEula="no" /> -->

3. 通過要使用的無提示選項修改 Display 元素項。請確保刪除註釋分隔符“<!--”和“-->”。例如，使用以下語法：

   <Display Level="none" CompletionNotice="no" SuppressModal="yes" AcceptEula="yes" />

   這些選項將指示安裝程序以無提示方式運行，防止提示用戶輸入信息，並防止安裝等待任何用戶交互。有關語法和 Config.xml 的詳細信息，請參閱 Office 2010 中的 Config.xml 文件中的 Display 元素。

4. 保存 Config.xml 文件，在本例中保存到 \\FS\Office2010SourceFiles\ProPlus.WW。

使用 OCT 指定批量許可證密鑰並選擇要安裝的應用程序

1. 若要自定義 Office 安裝程序，請使用命令行 setup.exe /admin 啓動 Office 自定義工具。在本例中，在命令提示符處，從程序包源目錄 \\FS\Office2010SourceFiles 中運行setup.exe /admin。

2. 在本例中，若要輸入批量許可證密鑰並選擇要安裝的應用程序，請按如下方式修改和配置設置：

3. 選擇位於“授權和用戶界面”下的“輸入另一個產品密鑰”選項，然後輸入一個有效的多次激活密鑰 (MAK) 密鑰。

   注意：

   在本例中，由於無提示安裝的參數是在 Config.xml 文件中配置的，因此在使用 OCT 時不必同時配置這些參數。這是因爲您在 Config.xml 中定義的自定義項優先於使用 OCT 所創建自定義文件中的自定義項。

   
   

4. 選擇位於“功能”下的“設置功能安裝狀態”選項，然後選擇要安裝哪些應用程序。在本例中，爲了加快安裝過程，只選擇了 Microsoft Word。

   有關可在使用 OCT 時配置的不同參數的其他資源，請參閱 2007 Office system 中的 Office 自定義工具、配置 Office 2010 的功能安裝狀態和爲 Office 2010 配置用戶設置。

5. 保存並命名新創建的 .msp 文件，然後將其放在包含源文件的計算機上 Office 2010 的 \Updates 文件夾中，在本例中，該位置爲 \\FS\Office2010SourceFiles\Updates\Office2010ProPlus.MSP。

警告：

只支持在 Updates 文件夾中包含每個產品的一個安裝程序自定義 .msp 文件。如果在部署 Office 2010 的初始安裝，並且希望部署 Office 2010 軟件更新（例如 Service Pack 和修補程序），安裝程序可以在安裝過程中應用產品更新。您可以將在安裝完成後應用的 Office 2010 產品更新放在 Updates 文件夾中。有關詳細信息，請參閱 2007 Office system 中的 Office 自定義工具

下一步是在域控制器（本例中爲 DC.CPANDL.COM）上配置腳本。

在域控制器上配置腳本

在域控制器上配置腳本的過程涉及以下步驟：

1. 將腳本複製到 GPO 的啓動文件夾。

2. 將腳本添加到 GPO。

3. 爲啓動腳本設置最長運行時間。

警告：

通過組策略可以影響組織中成百上千臺計算機的配置。因此，在將所有新組策略配置或部署移到生產環境中之前在測試環境中對其進行嚴格測試至關重要。有關暫存組策略部署的詳細信息，請參閱組策略規劃和部署指南 (http://go.microsoft.com/fwlink/?linkid=182208&clcid=0x804) 中的暫存組策略部署。

將腳本複製到 GPO 的啓動文件夾

本例包括一個示例批處理文件腳本，該腳本闡釋如何在尚未安裝產品的情況下運行 Microsoft Office Setup.exe，並將錯誤或成功信息記錄到集中式日誌文件。已爲此測試部署方案修改了該腳本開頭處的變量。例如，添加了帶有 Office14 前綴的產品名稱 ProPlus 以及 Office 源文件 \\FS\Office2010SourceFiles 和日誌文件 \\FS\Office2010LogFiles 的路徑。此示例腳本隨後複製到記事本中，並使用文件名 Office2010StartupScript.bat 保存。然後，該腳本文件將保存到域控制器上 GPO 啓動腳本的默認目錄，在本例中爲 C:\Windows\SYSVOL\sysvol\adatum.com\Policies\{GUID of GPO}\Machine\Scripts\Startup。

注意：

可通過右鍵單擊 GPO（在本例中爲 Office2010_GPO），然後單擊“屬性”，在 MMC 管理單元的“組策略管理編輯器”中找到表示該 GPO 的 GUID。GUID 列在“唯一的名稱”字段中。

setlocal

REM *********************************************************************
REM Environment customization begins here. Modify variables below.
REM *********************************************************************

REM Get ProductName from the Office product's core Setup.xml file, and then add "office14." as a prefix. 
set ProductName=Office14.PROPLUS

REM Set DeployServer to a network-accessible location containing the Office source files.
set DeployServer=\\FS\Office2010SourceFiles

REM Set ConfigFile to the configuration file to be used for deployment (required)
set ConfigFile=\\FS\Office2010SourceFiles\ProPlus.WW\config.xml

REM Set LogLocation to a central directory to collect log files.
set LogLocation=\\FS\Office2010LogFiles

REM *********************************************************************
REM Deployment code begins here. Do not modify anything below this line.
REM *********************************************************************

IF NOT "%ProgramFiles(x86)%"=="" (goto ARP64) else (goto ARP86)

REM Operating system is X64. Check for 32 bit Office in emulated Wow6432 uninstall key
:ARP64
reg query HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432NODE\Microsoft\Windows\CurrentVersion\Uninstall\%ProductName%
if NOT %errorlevel%==1 (goto End)

REM Check for 32 and 64 bit versions of Office 2010 in regular uninstall key.(Office 64bit would also appear here on a 64bit OS) 
:ARP86
reg query HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\%ProductName%
if %errorlevel%==1 (goto DeployOffice) else (goto End)

REM If 1 returned, the product was not found. Run setup here.
:DeployOffice
start /wait %DeployServer%\setup.exe /config %ConfigFile%
echo %date% %time% Setup ended with error code %errorlevel%. >> %LogLocation%\%computername%.txt

REM If 0 or other was returned, the product was found or another error occurred. Do nothing.
:End

Endlocal

將腳本添加到 GPO

若要將腳本添加到 GPO，請使用 MMC 管理單元“組策略管理編輯器”，並右鍵單擊“啓動”（“GPO”|“計算機配置”|“策略”|“Windows 設置”|“腳本(啓動/關機)”|“啓動”），依次單擊“屬性”、“添加”、“瀏覽”，然後突出顯示並選擇腳本文件，在本例中爲 Office2010StartupScript.bat。

設置啓動腳本的最長運行時間

默認情況下，系統最多隻允許合併的腳本組運行 600 秒（10 分鐘）。管理員可以使用策略設置調整此時間間隔以確保啓動腳本完成運行。“組策略腳本的最長等待時間”策略設置指定系統等待組策略所應用的腳本運行的時間。此設置限制了組策略所應用的所有登錄、啓動和關機腳本完成運行所需的總時間。與任何組策略部署一樣，您必須在暫存環境中全面測試您的啓動腳本，然後再將它們部署到您的生產環境。通過測試，可以幫助您確定要用於特定網絡環境的“組策略腳本的最長等待時間”策略的值。此值設置得過低可能導致安裝過早終止。有些因素可能會影響此值，如網絡速度、客戶端計算機硬件以及在客戶端計算機上運行的其他腳本。通過全面測試此策略設置，您可以確定要用於特定環境的適當的值。

在此示例方案中，“組策略腳本的最長等待時間”策略設置的值設置爲 0，該值將指示系統在腳本完成之前一直等待，而不管腳本花費了多長時間。

若要更改 GPO（本例中爲 Office2010_GPO）的“組策略腳本的最長等待時間”策略的值，請使用 MMC 管理單元“組策略管理編輯器”，並雙擊“組策略腳本的最長等待時間”（“GPO”|“計算機配置”|“策略”|“管理模板”|“系統”|“腳本”）。

將對 GPO 所做的計算機啓動腳本策略更改應用於目標計算機（本例中爲 W7C01.CPANDL.COM 和 WVC02.CPANDL.COM）後，計算機啓動腳本將在計算機啓動時執行。您可以在客戶端計算機上的命令提示符處發出以下命令行，而不是等待域控制器在客戶端計算機上刷新策略： gpupdate /force您可以使用策略的結果集 (RSoP) MMC 管理單元來驗證計算機啓動腳本的計算機策略設置是否存在於客戶端計算機上。

驗證計算機啓動腳本狀態

在本例中，腳本日誌記錄信息寫入 computername.txt 文件並保存到網絡共享 \\FS\Office2010LogFiles。日誌文件中的返回代碼 0 表示安裝成功完成。返回代碼 3010 表示需要重新啓動。有關 Office 產品的 Windows Installer 進程的其他錯誤代碼的詳細信息，請參閱 Microsoft 知識庫文章 290158：Office 2003 產品和 Office XP 產品中 Windows Installer 進程的錯誤代碼和錯誤信息列表。