教程 | 教你如何一步步創建ERC20代幣轉

艾伯特AI 人工智能（公衆號：aibbtcom）按：

看這篇文章需要對以太坊，智能合約，代幣等概念有基本的瞭解。

什麼是ERC20

可以把ERC20簡單理解成以太坊上的一個代幣協議，所有基於以太坊開發的代幣合約都遵守這個協議。遵守這些協議的代幣我們可以認爲是標準化的代幣，而標準化帶來的好處是兼容性好。這些標準化的代幣可以被各種以太坊錢包支持，用於不同的平臺和項目。說白了，你要是想在以太坊上發行代幣融資，必須要遵守ERC20標準。

ERC20的標準接口是這樣的:

  contract ERC20 {
      function name() constant returns (string name)
      function symbol() constant returns (string symbol)
      function decimals() constant returns (uint8 decimals)
      function totalSupply() constant returns (uint totalSupply);
      function balanceOf(address _owner) constant returns (uint balance);
      function transfer(address _to, uint _value) returns (bool success);
      function transferFrom(address _from, address _to, uint _value) returns (bool success);
      function approve(address _spender, uint _value) returns (bool success);
      function allowance(address _owner, address _spender) constant returns (uint remaining);
      event Transfer(address indexed _from, address indexed _to, uint _value);
      event Approval(address indexed _owner, address indexed _spender, uint _value);
    }

name

返回ERC20代幣的名字，例如"My test token"。

symbol

返回代幣的簡稱，例如：MTT，這個也是我們一般在代幣交易所看到的名字。

decimals

返回token使用的小數點後幾位。比如如果設置爲3，就是支持0.001表示。

totalSupply

返回token的總供應量

balanceOf

返回某個地址(賬戶)的賬戶餘額

transfer

從代幣合約的調用者地址上轉移 _value的數量token到的地址 _to，並且必須觸發Transfer事件。

transferFrom

從地址 _from發送數量爲 _value的token到地址 _to,必須觸發Transfer事件。

transferFrom方法用於允許合同代理某人轉移token。條件是from賬戶必須經過了approve。這個後面會舉例說明。

approve

允許 _spender多次取回您的帳戶，最高達 _value金額。如果再次調用此函數，它將以 _value覆蓋當前的餘量。

allowance

返回 _spender仍然被允許從 _owner提取的金額。

後面三個方法不好理解，這裏還需要補充說明一下，

approve是授權第三方（比如某個服務合約）從發送者賬戶轉移代幣，然後通過 transferFrom() 函數來執行具體的轉移操作。

賬戶A有1000個ETH，想允許B賬戶隨意調用他的100個ETH，過程如下：

A賬戶按照以下形式調用approve函數approve(B,100)
B賬戶想用這100個ETH中的10個ETH給C賬戶，調用transferFrom(A, C, 10)
調用allowance(A, B)可以查看B賬戶還能夠調用A賬戶多少個token

另外，我推薦這篇文章，對這部分概念講解的比較清楚。

乾貨 | 代幣支付的以太坊智能服務（http://www.aibbt.com/a/26166.html）

（編者按：亦見文末超鏈接《科普 | 釋放阻塞的以太坊交易》）

後面兩個是事件，事件是爲了獲取日誌方便提供的。前者是在代幣被轉移時觸發，後者是在調用approve方法時觸發。

基於ERC20編寫的一個代幣合約

pragma solidity ^0.4.16;
contract Token{
    uint256 public totalSupply;

    function balanceOf(address _owner) public constant returns (uint256 balance);
    function transfer(address _to, uint256 _value) public returns (bool success);
    function transferFrom(address _from, address _to, uint256 _value) public returns   
    (bool success);

    function approve(address _spender, uint256 _value) public returns (bool success);

    function allowance(address _owner, address _spender) public constant returns 
    (uint256 remaining);

    event Transfer(address indexed _from, address indexed _to, uint256 _value);
    event Approval(address indexed _owner, address indexed _spender, uint256 
    _value);
}

contract TokenDemo is Token {

    string public name;                   //名稱，例如"My test token"
    uint8 public decimals;               //返回token使用的小數點後幾位。比如如果設置爲3，就是支持0.001表示.
    string public symbol;               //token簡稱,like MTT

    function TokenDemo(uint256 _initialAmount, string _tokenName, uint8 _decimalUnits, string _tokenSymbol) public {
        totalSupply = _initialAmount * 10 ** uint256(_decimalUnits);         // 設置初始總量
        balances[msg.sender] = totalSupply; // 初始token數量給予消息發送者，因爲是構造函數，所以這裏也是合約的創建者

        name = _tokenName;                   
        decimals = _decimalUnits;          
        symbol = _tokenSymbol;
    }

    function transfer(address _to, uint256 _value) public returns (bool success) {
        //默認totalSupply 不會超過最大值 (2^256 - 1).
        //如果隨着時間的推移將會有新的token生成，則可以用下面這句避免溢出的異常
        require(balances[msg.sender] >= _value && balances[_to] + _value > balances[_to]);
        require(_to != 0x0);
        balances[msg.sender] -= _value;//從消息發送者賬戶中減去token數量_value
        balances[_to] += _value;//往接收賬戶增加token數量_value
        Transfer(msg.sender, _to, _value);//觸發轉幣交易事件
        return true;
    }


    function transferFrom(address _from, address _to, uint256 _value) public returns 
    (bool success) {
        require(balances[_from] >= _value && allowed[_from][msg.sender] >= _value);
        balances[_to] += _value;//接收賬戶增加token數量_value
        balances[_from] -= _value; //支出賬戶_from減去token數量_value
        allowed[_from][msg.sender] -= _value;//消息發送者可以從賬戶_from中轉出的數量減少_value
        Transfer(_from, _to, _value);//觸發轉幣交易事件
        return true;
    }
    function balanceOf(address _owner) public constant returns (uint256 balance) {
        return balances[_owner];
    }


    function approve(address _spender, uint256 _value) public returns (bool success)   
    { 
        allowed[msg.sender][_spender] = _value;
        Approval(msg.sender, _spender, _value);
        return true;
    }

    function allowance(address _owner, address _spender) public constant returns (uint256 remaining) {
        return allowed[_owner][_spender];//允許_spender從_owner中轉出的token數
    }
    mapping (address => uint256) balances;
    mapping (address => mapping (address => uint256)) allowed;
}

代碼不必過多的解釋，註釋都寫得很清楚了。

這裏可能有人會有疑問，name，totalSupply這些按照標準不應該都是方法嗎，怎麼這裏定義的是屬性變量？這是因爲solidity會自動給public變量生成同名的getter接口。