智能合約語言 Solidity 教程系列10 - 完全理解函數修改器 原

這是Solidity教程系列文章第10篇，帶大家完全理解Solidity的函數修改器。 Solidity系列完整的文章列表請查看分類-Solidity。

寫在前面

Solidity 是以太坊智能合約編程語言，閱讀本文前，你應該對以太坊、智能合約有所瞭解， 如果你還不瞭解，建議你先看以太坊是什麼

歡迎訂閱區塊鏈技術專欄閱讀更全面的分析文章。

函數修改器(Function Modifiers)

函數修改器(Modifiers)可以用來改變一個函數的行爲。比如用於在函數執行前檢查某種前置條件。

如果熟悉Python的同學，會發現函數修改器的作用和Python的裝飾器很相似。

修改器是一種可被繼承合約屬性，同時還可被繼承的合約重寫(override)。下面我們來看一段示例代碼：

pragma solidity ^0.4.11;

contract owned {
    function owned() public { owner = msg.sender; }
    address owner;

    // 定義了一個函數修改器，可被繼承
    //  修飾時，函數體被插入到 “_;” 處
    // 不符合條件時，將拋出異常
    modifier onlyOwner {
        require(msg.sender == owner);
        _;
    }
}

contract mortal is owned {
    //  使用繼承的`onlyOwner` 
    function close() public onlyOwner {
        selfdestruct(owner);
    }
}

contract priced {
    // 函數修改器可接收參數
    modifier costs(uint price) {
        if (msg.value >= price) {
            _;
        }
    }
}

contract Register is priced, owned {
    mapping (address => bool) registeredAddresses;
    uint price;

    function Register(uint initialPrice) public { price = initialPrice; }

    // 需要提供payable 以接受以太
    function register() public payable costs(price) {
        registeredAddresses[msg.sender] = true;
    }

    function changePrice(uint _price) public onlyOwner {
        price = _price;
    }
}

上面onlyOwner就是定義的一個函數修改器，當用這個修改器區修飾一個函數時，則函數必須滿足onlyOwner的條件才能運行，這裏的條件是：必須是合約的創建這才能調用函數，否則拋出異常。 我們在實現一個可管理、增發、兌換、凍結等高級功能的代幣文章中就使用了這個函數修改器。

多個修改器

如果同一個函數有多個修改器，他們之間以空格隔開，修飾器會依次檢查執行。

在修改器中或函數內的顯式的return語句，僅僅跳出當前的修改器或函數。返回的變量會被賦值，但執行流會在前一個修改器後面定義的"_"後繼續執行， 如：

contract Mutex {
    bool locked;
    modifier noReentrancy() {
        require(!locked);
        locked = true;
        _;
        locked = false;
    }

    // 防止遞歸調用
    // return 7 之後，locked = false 依然會執行
    function f() public noReentrancy returns (uint) {
        require(msg.sender.call());
        return 7;
    }
}

修改器的參數可以是任意表達式。在此上下文中，所有的函數中引入的符號，在修改器中均可見。但修改器中引入的符號在函數中不可見，因爲它們有可能被重寫。

深入理解修改器的執行次序

再來看一個複雜一點的例子，來深入理解修改器：

pragma solidity ^0.4.11;


contract modifysample {

    uint a = 10;
    
    modifier mf1 (uint b) {
        uint c = b;
        _;
        c = a;
        a = 11;
    }
    
     modifier mf2 () {
        uint c = a;
        _;
    }
    
    modifier mf3() {
        a = 12;
        return ;
        _;
        a = 13;
    }
    
    function test1() mf1(a) mf2 mf3 public   {
        a = 1;
    }
    
     function test2() public constant returns (uint)   {
        return a;  
    }  
}

上面的智能合約運行test1()之後，狀態變量a的值是多少， 是1， 11， 12，還是13呢？ 答案是 11, 大家可以運行下test2獲取下a值。

我們來分析一下 test1， 它擴展之後是這樣的：

uint c = b;
        uint c = a;
            a = 12;
            return ;
            _;
            a = 13;
c = a;
a = 11;

這個時候就一目瞭然了，最後a 爲11， 注意第5及第6行是不是執行的。

參考視頻

我們也推出了目前市面上最全的視頻教程：深入詳解以太坊智能合約語言Solidity 目前我們也在招募體驗師，可以點擊鏈接瞭解。

參考文獻

官方文檔-Function Modifiers

如果你想和認識我，和我建立聯繫，歡迎加入知識星球深入淺出區塊鏈，我會在星球爲大家解答技術問題，作爲星友福利，星友可加入我創建的區塊鏈技術羣，羣內已經聚集了100多位區塊鏈技術愛好者。

☛ 我的知識星球爲各位解答區塊鏈技術問題，歡迎加入討論。 ☛ 關注公衆號“深入淺出區塊鏈技術”第一時間獲取區塊鏈技術信息，系統學習區塊鏈，打造最好的區塊鏈技術文章。