PB指定某行某列的顏色屬性值uf_setcell_color

PB指定某行某列的顏色屬性值uf_setcell_color

轉自：https://blog.csdn.net/happymagic/article/details/7843031

/*-----------------------------------------------------------------------------------
函數功能：指定某行某列的屬性值(字體、背景顏色等)

	參數：
		 	dw					數據窗口名
			args_properties    	(text: 改變字體顏色;  background: 背景色) 
			args_type        	類型(value:指通過值確定行;  row:指通過行號直接確定)
		 	args_col[]       	列名或者列號
			args_info[]   		行號及對應顏色數組
		 	
		 	
		 
  返回值：無

  注: 1. 由於二維數組無法動態聲明, 因此用一維數組代替, 通過程序處理。
         因此要求傳入到info數組的數據必須是以下格式:
	  
	     {'行號1','顏色','行號2','顏色'}
	  
	  2. 目前針對字段中未設表達式的情況。
	  
	  
	  2004-05-14
	  1. 實現修改字段中已經設置表達式的情況。
	  
----------------------------------------------------------------------------------*/

//如果未傳入值，則返回
IF UpperBound(args_col) <= 0 THEN 
	RETURN
END IF

Integer i, j
String ls_colname, ls_properties, ls_old_value
String ls_head, ls_mid, ls_tail, ls_condition
String ls_value, ls_color
//----------2004-05-14
String ls_sign
Boolean lb_sign
//------------------------


FOR i = 1 TO UpperBound( args_col )
	//取列號
	IF IsNumber( args_col[i] ) THEN
		ls_colname = "#" + String( args_col[i] )
	ELSE
		ls_colname = args_col[i]
	END IF
	
	//修改的屬性(這裏大家可以自己擴展屬性)
	CHOOSE CASE args_properties
		CASE "text"
			ls_properties = "color"
			
		CASE "background"
			dw.modify( ls_colname + ".background.mode = '0' " )
			ls_properties = "background.color"
			
	END CHOOSE
	
	//去改列的表達式
	ls_old_value = dw.Describe( ls_colname + "." + ls_properties )
	
	//=========================================================2004-05-14修改
	//取出的值中若含有("),就說明有表達式,或者初始值,
	//而在重建表達式時,有這兩個"在是不行的,所以要去除。
	IF Pos(ls_old_value, '"') <> 0 THEN
		ls_old_value = Right(ls_old_value, Len(ls_old_value) - Pos(ls_old_value, "~t"))
		ls_old_value = Left( ls_old_value, Len(ls_old_value) - Pos(ls_old_value, "~t") - 1 )  //去掉最後的引號
	END IF
	//=====================================================================
	
	//根據什麼確定行
	CHOOSE CASE args_type
		CASE "value"
			ls_head = "'0~tcase(" + ls_colname +" "
			
		CASE "row"
			ls_head = "'0~tcase(getrow() "
	END CHOOSE
	
	
	FOR j = 1 TO UpperBound( args_info ) STEP 2
		ls_value = args_info[j]		//行號或者改單元格的值
		ls_color = args_info[j+1]	//取顏色
		
		ls_mid = ls_mid + " when " + ls_value + " then " + ls_color
	NEXT
	
	ls_tail = " else " + ls_old_value + ")'"	//結尾
	
	//組合成表達式中的條件
	ls_condition = ls_colname + "." + ls_properties + "="
	ls_condition = ls_condition + ls_head + ls_mid + ls_tail
//	messagebox("abc",ls_condition)
	//執行
	dw.Modify( ls_condition )
	
NEXT