PL/SQL Record數據類型

        Oracle PL / SQL語言旨在成爲一種可移植的高性能事務處理語言，與SQL語言緊密集成。實際上，很難找到一個PL / SQL程序，它既不會讀取數據庫中的表，也不會對數據庫中的表進行更改。表由數據行組成，每行包含一列或多列，因此Oracle數據庫可以儘可能簡單地使用PL / SQL程序中的那些數據行。它正是通過實施記錄來實現的。

         Record是一種複合數據類型，這意味着與標量數據類型（如數字或字符串）相比，它可以容納多條信息。事實上，很少有您使用的數據只是一個值，因此Record和其他複合數據類型可能在您的PL / SQL程序中佔據顯着位置。

使用％ROWTYPE聲明Record

        PL / SQL通過提供％ROWTYPE屬性，可以很容易地聲明與遊標的表，視圖或結果集具有相同結構的記錄。

        假設我在應用程序中有一個僱員表，如下所示：

SQL> DESCRIBE omag_employees
 Name         Null?      Type
 ———————————  —————————— —————————————————
 EMPLOYEE_ID  NOT NULL   NUMBER(38)
 LAST_NAME               VARCHAR2(100)
 SALARY                  NUMBER

        表中的每一行由三列組成，每列都有自己的數據類型。以下查詢檢索表中所有行的所有列：

SELECT employee_id，last_name，salary FROM omag_employees

        編寫一個代碼塊，從omag_employees中檢索員工ID的單行數據，然後使用該行中的列值。可以爲每列聲明一個變量，然後獲取這些變量，如下所示：

CREATE PROCEDURE process_employee (
  employee_id_in IN 
    omag_employees.employee_id%TYPE)
IS
  l_employee_id   
     omag_employees.employee_id%TYPE;
  l_last_name     
     omag_employees.last_name%TYPE;
  l_salary        
     omag_employees.salary%TYPE;
BEGIN
  SELECT employee_id,
         last_name,
         salary
    INTO l_employee_id,
         l_last_name,
         l_salary
    FROM omag_employees
  WHERE employee_id = employee_id_in;
END;
    注意:在參數中使用後綴來表示它們的模式。這裏_in表示IN參數。

        然而，這是一大堆用於編寫，讀取和維護的代碼。更好的方法是將該行數據提取到記錄中，聲明該記錄的最佳方法如下：

CREATE PROCEDURE process_employee (
  employee_id_in IN 
     omag_employees.employee_id%TYPE)
IS
  l_employee   omag_employees%ROWTYPE;
BEGIN
  SELECT employee_id,
         last_name,
         salary
    INTO l_employee
    FROM omag_employees
  WHERE employee_id = employee_id_in;
END;

        編譯此過程時，PL / SQL將查找omag_employees表的結構，並定義一個記錄，該記錄具有表中每列的字段，具有相同的名稱和數據類型。通過使用％ROWTYPE來聲明記錄，我還告訴Oracle數據庫該過程依賴於 omag_employees表。例如，如果數據庫管理員將last_name列的最大長度更改爲200，則此Procedure的狀態將更改爲INVALID。重新編譯Procedure時，編譯器將更新此Procedure中記錄的定義以匹配表的新結構。

甚至可以進一步縮短和寫作:

CREATE PROCEDURE process_employee (
  employee_id_in IN 
     omag_employees.employee_id%TYPE)
IS
  l_employee   omag_employees%ROWTYPE;
BEGIN
  SELECT *
    INTO l_employee
    FROM omag_employees
   WHERE employee_id = employee_id_in;
END;

       SELECT *語法告訴Oracle數據庫獲取表中的所有列。

        還可以使用％ROWTYPE聲明一個與遊標中的SELECT語句具有相同結構的記錄。這對於從表中獲取列的子集或從多個表中獲取列特別有用。這是一個例子：

DECLARE
   CURSOR no_ids_cur
   IS
      SELECT last_name, salary
        FROM omag_employees;

   l_employee   no_ids_cur%ROWTYPE;
    注意:通常在明確聲明的遊標的名稱後面添加一個“_cur”後綴。

        無論何時從光標向PL / SQL變量中提取數據，都應該使用％ROWTYPE基於該遊標聲明記錄並獲取該記錄。這樣，當光標的SELECT列表發生變化時，記錄中字段的數量和類型將相應地改變，一切都將保持同步。