現在我們有3個存儲過程,分別是p1,p2,p3
如果按下列方式執行
begin
p1;
p2;
p3;
end;
它們是串行的。
我們可以使用DBMS_SCHEDULER包來間接實現並行執行,具體用法如下:
begin
dbms_scheduler.create_job(job_name => dbms_scheduler.generate_job_name,
job_type => 'PLSQL_BLOCK',
job_action => 'begin p1; end;',
start_date => sysdate,
enabled => true,
comments => 'temporary job,will be delete soon after complete!',
auto_drop => true
);
dbms_scheduler.create_job(job_name => dbms_scheduler.generate_job_name,
job_type => 'PLSQL_BLOCK',
job_action => 'begin p2; end;',
start_date => sysdate,
enabled => true,
comments => 'temporary job,will be delete soon after complete!',
auto_drop => true
);
dbms_scheduler.create_job(job_name => dbms_scheduler.generate_job_name,
job_type => 'PLSQL_BLOCK',
job_action => 'begin p3; end;',
start_date => sysdate,
enabled => true,
comments => 'temporary job,will be delete soon after complete!',
auto_drop => true
);
end;
使用create_job來創建並立即執行一個job,執行完之後系統會自動刪除。其中:
dbms_scheduler.generate_job_name 用來創建一個job_name,默認是JOB$_加上一個遞增的數字,形如 JOB$_7983
start_time => sysdate 表示立即執行(需要同時將enabled設置爲true)
enabled => true 只有這樣纔會立即執行
auto_drop => true 表示執行完自動刪除
由於我們沒有指定任何重複執行的參數,所以job創建後,它的SCHEDULE_TYPE=ONCE,而不是一般的CALENDAR。
可以通過
select * from user_scheduler_jobs;
查看。
在我的工作中遇到這麼一個實際需求,僞代碼如下:
begin
for rows in (select COL1 from tab) loop
業務邏輯處理;
end loop;
end;
處理邏輯部分比較簡單,但是循環次數比較多,所以考慮將數據分片執行。
begin
for rows in (select col1
from (select mod(rownum, v_parallel_degree) + 1 part,
--part要加1,因爲是取餘
col1
from (select col1 from tab order by col2))
where part = v_part) loop
end loop;
end;
其中:
v_parallel_degree:分片的數量
v_part:用來取第x分片
將以上代碼放到存儲過程中,兩個入參:v_parallel_degree,v_part
最後使用一個存儲過程來調用
--***************************創建一個工具包用來創建job***************************
create or replace package pkg_utils is
procedure exec_pkg(v_pkg_name in varchar2);
--並行執行存儲過程
procedure exec_proc_parallel(v_procedure_name in varchar2,
v_parallel_degree in int);
end pkg_utils;
/
create or replace package body pkg_utils is
--並行執行存儲過程
procedure exec_proc_parallel(v_procedure_name in varchar2,
v_parallel_degree in int) is
begin
for i in 1 .. v_parallel_degree loop
dbms_scheduler.create_job(job_name => dbms_scheduler.generate_job_name,
job_type => 'PLSQL_BLOCK',
job_action => 'begin ' || v_procedure_name || '(' ||
v_parallel_degree || ',' || i ||
'); end;',
start_date => sysdate,
enabled => true,
comments => v_procedure_name || '(' || i ||
' of ' || v_parallel_degree || ')',
auto_drop => true);
end loop;
end exec_proc_parallel;
begin
-- initialization
null;
end pkg_utils;
/
--***************************調用實例***************************
begin
pkg_utils.exec_proc_parallel('PROCEDURE_NAME', 16);
end;
/