Quick Test Professional 自動化腳本示例

執行基本操作：

配置運行選項並運行測試

 

'************************************************************************************************************************
'描述：
'
'該示例打開測試，配置運行選項和設置，
'運行該測試，然後檢查測試運行的結果。
'
'假定：
'QuickTest 中當前未打開沒有保存的測試。
'有關詳細信息，請參閱 Test.SaveAs 方法的示例。
'打開 QuickTest 時，將加載測試所必需的加載項。
'有關詳細信息，請參閱 Test.GetAssociatedAddins 方法的示例。
'************************************************************************************************************************

Dim qtApp ' As QuickTest.Application ' 聲明 Application 對象變量
Dim qtTest 'As QuickTest.Test ' 聲明 Test 對象變量
Dim qtResultsOpt 'As QuickTest.RunResultsOptions ' 聲明 Run Results Options 對象變量

Set qtApp = CreateObject("QuickTest.Application") ' 創建 Application 對象
qtApp.Launch ' 啓動 QuickTest
qtApp.Visible = True ' 使 QuickTest 應用程序可見

' 設置 QuickTest 運行選項
qtApp.Options.Run.CaptureForTestResults = "OnError"
qtApp.Options.Run.RunMode = "Fast"
qtApp.Options.Run.ViewResults = False

qtApp.Open "C:\Tests\Test1", True ' 以只讀模式打開測試

' 爲測試設置運行設置
Set qtTest = qtApp.Test
qtTest.Settings.Run.IterationMode = "rngIterations" ' 僅運行循環 2 到 4
qtTest.Settings.Run.StartIteration = 2
qtTest.Settings.Run.EndIteration = 4
qtTest.Settings.Run.OnError = "NextStep" ' 指示 QuickTest 在發生錯誤時執行下一步驟

Set qtResultsOpt = CreateObject("QuickTest.RunResultsOptions") ' 創建 Run Results Options 對象
qtResultsOpt.ResultsLocation = "C:\Tests\Test1\Res1" ' 設置結果位置

qtTest.Run qtResultsOpt ' 運行測試

MsgBox qtTest.LastRunResults.Status ' 檢查測試運行的結果
qtTest.Close ' 關閉測試

Set qtResultsOpt = Nothing ' 釋放 Run Results Options 對象
Set qtTest = Nothing ' 釋放 Test 對象
Set qtApp = Nothing ' 釋放 Application 對象

 

 

執行基本操作：

檢查測試狀態並保存測試

 

'************************************************************************************************************************
'描述：
'
'該示例保存已修改的測試，以便可以打開新的測試
'或退出應用程序，而不丟失任何未保存的信息。
'************************************************************************************************************************

Dim qtApp ' As QuickTest.Application ' 聲明 Application 對象變量

Set qtApp = CreateObject("QuickTest.Application") ' 創建 Application 對象
qtApp.Launch ' 啓動 QuickTest（如果未啓動）
qtApp.Visible = True ' 使其可見

' 保存當前測試並根據需要決定是否打開一個新的測試
If qtApp.Test.Modified Then ' 如果修改了測試
    If qtApp.Test.IsNew Then ' 如果是新的測試（無標題）
        qtApp.Test.SaveAs "C:\Temp\TempTest" ' 使用臨時名稱保存測試（覆蓋現有的臨時測試）
    Else ' 如果存在測試（具有名稱）
        qtApp.Test.Save ' 保存更改
    End If
End If

If Not qtApp.Test.IsNew Then ' 如果當前測試不是新的測試
    qtApp.New ' 打開新的測試
End If

Set qtApp = Nothing ' 釋放 Application 對象
 

 

 

執行基本操作：

配置 QuickTest 顯示選項

'************************************************************************************************************************
'描述：
'
'該示例配置 QuickTest 視圖和窗格，以便以可見模式運行 QuickTest。
'************************************************************************************************************************

Dim qtApp ' As QuickTest.Application ' 聲明 Application 對象變量
Set qtApp = CreateObject("QuickTest.Application") ' 創建 Application 對象
qtApp.Launch ' 啓動 QuickTest


qtApp.ActivateView "ExpertView" ' 顯示專家視圖
qtApp.ShowPaneScreen "ActiveScreen", True ' 顯示 Active Screen 窗格
qtApp.ShowPaneScreen "DataTable", False ' 隱藏“數據表”窗格
qtApp.ShowPaneScreen "DebugViewer", True ' 顯示“調試查看器”窗格
qtApp.WindowState = "Maximized" ' 最大化 QuickTest 窗口
qtApp.Visible = True ' 使 QuickTest 窗口可見

Set qtApp = Nothing ' 釋放 Application 對象

 

執行基本操作：

爲業務流程測試新建業務組件

'************************************************************************************************************************
'描述：
'
' 該示例爲特定的業務流程測試找到關聯的加載項的列表。
' 然後新建業務組件，並與關聯 BPT 的業務組件
'關聯相同的加載項。
'
'************************************************************************************************************************


Dim qtApp ' As QuickTest.Application ' 聲明 Application 對象變量
Dim arrBCAddins ' 聲明變量，用於存儲與組件關聯的加載項
Dim blnNeedChangeAddins ' 聲明一個標誌，用於指明當前是否已加載與組件關聯的加載項

Set qtApp = CreateObject("QuickTest.Application") ' 創建 Application 對象
qtApp.Launch ' 啓動 QuickTest
qtApp.Visible = True ' 使 QuickTest 應用程序可見

qtApp.TDConnection.Connect "http://qcserver/qcbin", _
              "MY_DOMAIN", "My_Project", "James", "not4you", False ' 連接到 Quality Center


If qtApp.TDConnection.IsConnected Then ' 如果連接成功

'找到與業務流程測試關聯的加載項，並關聯到具有新的業務組件的
'同一列表。
    arrBCAddins = qtApp.GetAssociatedAddinsForBPT("[QualityCenter] Subject\MyFolder\MyBPT")
    qtApp.NewBusinessComponent
    qtApp.BusinessComponent.SetAssociatedAddins arrBCAddins

End If

 

執行基本操作：

 爲業務組件加載正確的加載項

'************************************************************************************************************************
'描述：
'
' 該示例查找與特定業務組件關聯的加載項。
' 如果尚未加載某些必需的加載項，則其加載它們，重新啓動 QuickTest，打開業務組件，
' 並確認打開的文檔是否確實是業務組件。
'
'************************************************************************************************************************


Dim qtApp ' As QuickTest.Application ' 聲明 Application 對象變量
Dim arrBCAddins ' 聲明變量，用於存儲與組件關聯的加載項
Dim blnNeedChangeAddins ' 聲明一個標誌，用於指明當前是否已加載與組件關聯的加載項

Set qtApp = CreateObject("QuickTest.Application") ' 創建 Application 對象
qtApp.Launch ' 啓動 QuickTest
qtApp.Visible = True ' 使 QuickTest 應用程序可見

qtApp.TDConnection.Connect "http://qcserver/qcbin", _
              "MY_DOMAIN", "My_Project", "James", "not4you", False ' 連接到 Quality Center

If qtApp.TDConnection.IsConnected Then ' 如果連接成功

    arrBCAddins = qtApp.GetAssociatedAddinsForBC("[QualityCenter] Components\MyFolder\MyBC")

    ' 檢查是否已加載所有必需的加載項
    blnNeedChangeAddins = False ' 假定無需作任何更改
    For Each bcAddin In arrBCAddins ' 循環與組件關聯的加載項列表
        If qtApp.Addins(bcAddin).Status <> "Active" Then ' 如果存在未加載的關聯加載項
            blnNeedChangeAddins = True ' 指明需要對加載的加載項進行更改
            Exit For ' 退出循環
        End If
    Next

    If qtApp.Launched And blnNeedChangeAddins Then
        qtApp.Quit ' 如果有必要進行更改，則退出 QuickTest，修改已加載的加載項
    End If

    If blnNeedChangeAddins Then
        Dim blnActivateOK
        blnActivateOK = qtApp.SetActiveAddins(arrBCAddins, errorDescription) ' 加載與組件關聯的加載項並檢查它們是否已加載成功。
        If Not blnActivateOK Then ' 如果在加載加載項時發生問題
            MsgBox errorDescription ' 顯示包含錯誤的消息
            WScript.Quit ' 並結束自動程序。
        End If
    End If
End If

If Not qtApp.Launched Then ' 如果尚未打開 QuickTest
    qtApp.Launch ' 啓動 QuickTest（已加載正確的加載項）
    qtApp.Visible = True ' 使 QuickTest 應用程序可見
    qtApp.TDConnection.Connect "http://qcserver/qcbin", _
              "MY_DOMAIN", "My_Project", "James", "not4you", False ' 連接到 Quality Center
End If

If qtApp.TDConnection.IsConnected Then ' 如果連接成功
    qtApp.OpenBusinessComponent "[QualityCenter] Components\MyFolder\MyBC", False ' 打開業務組件
    MsgBox qtApp.CurrentDocumentType '確認打開的文檔是否是業務組件
End If
 

 

執行基本操作：

檢查和加載加載項

'************************************************************************************************************************
'描述：
'
'該示例打開一個測試，並加載所有與測試關聯的加載項。
'
'假定：
'QuickTest 中當前未打開沒有保存的測試。
'有關詳細信息，請參閱 Test.SaveAs 方法的示例。
'************************************************************************************************************************

Dim qtApp ' As QuickTest.Application ' 聲明 Application 對象變量
Dim blnNeedChangeAddins ' 聲明一個標誌，用於指明當前是否已加載與測試關聯的加載項
Dim arrTestAddins ' 聲明變量，用於存儲與測試關聯的加載項

Set qtApp = CreateObject("QuickTest.Application") ' 創建 Application 對象

arrTestAddins = qtApp.GetAssociatedAddinsForTest("C:\Tests\Test1") ' 創建一個數組，用於包含與該測試關聯的加載項的列表

' 檢查是否已加載所有必需的加載項
blnNeedChangeAddins = False ' 假定無需作任何更改
For Each testAddin In arrTestAddins ' 循環與測試關聯的加載項列表
    If qtApp.Addins(testAddin).Status <> "Active" Then ' 如果存在未加載的關聯加載項
        blnNeedChangeAddins = True ' 指明需要對加載的加載項進行更改
        Exit For ' 退出循環
    End If
Next

If qtApp.Launched And blnNeedChangeAddins Then
        qtApp.Quit ' 如果有必要進行更改，則退出 QuickTest，修改已加載的加載項
End If

If blnNeedChangeAddins Then
    Dim blnActivateOK
    blnActivateOK = qtApp.SetActiveAddins(arrTestAddins, errorDescription) ' 加載與測試關聯的加載項並檢查它們是否已加載成功。
    If Not blnActivateOK Then ' 如果在加載加載項時發生問題
        MsgBox errorDescription ' 顯示包含錯誤的消息
    WScript.Quit ' 並結束自動程序。
    End If
End If

If Not qtApp.Launched Then ' 如果尚未打開 QuickTest
    qtApp.Launch ' 啓動 QuickTest（已加載正確的加載項）
End If
qtApp.Visible = True ' 使 QuickTest 應用程序可見

qtApp.Open "C:\Tests\Test1" ' 打開測試
Set qtApp = Nothing ' 釋放 Application 對象