Inno Setup腳本語法及關鍵字

; 腳本由 Inno Setup 腳本嚮導 生成！
; 有關創建 Inno Setup 腳本文件的詳細資料請查閱幫助文檔！
;Inno Setup 是一個免費的 Windows 安裝程序製作軟件。
;第一次發表是在 1997 年，Inno Setup 今天在功能設置和穩定性上的競爭力可能已經超過一些商業的安裝程序製作軟件
;它是真正免費的軟件，即使作爲商業應用
;還有一個特點，壓縮率特別高，特別適合VB軟件，我這個安裝打包後只有3.7M，其他打包工具5M多
;安裝程序用編譯腳本的方式創建，腳本其實就是一個類似 .INI 文件格式的 ASCII 碼文本文件。 (它不象你想象的那麼複雜!)
;腳本文件一般可以用安裝程序編譯器程序內置的編輯器進行編輯。在你編寫完腳本後，下一個最終步驟就是選擇安裝程序編譯器
;中的“編譯”。創建完成後，就可以運行根據你腳本編譯的安裝程序了。
;按默認，這個安裝程序創建在包含腳本文件目錄下的名爲“輸出”目錄中
 
 #define CSDN "一入代碼深似海"


[Setup]
;這個段包含用於安裝程序和卸載程序的全局設置。某些提示對於你創建的任何安裝程序都是必需的
;一個必需的指示，用以指定你正在安裝的應用程序的標題。不包含版本號，與 AppVerName 指示用於同樣的目的。AppName 始終在安裝過程中顯示在安裝屏幕的左上角以及安裝嚮導中
AppName=一入代碼深似海
;這個必需的指示值應該與 AppName 的值相同 (或類似)，但它還應該包含程序的版本號
AppVerName=一入代碼深似海 V1.0
;這是所有用於在 Windows 2000/XP 中添加/刪除程序控件面板對話框中的“支持”信息中顯示的內容。這些設置是可選的，在早期的 Windows 版本中無效
AppPublisher=一入代碼深似海
;這是所有用於在 Windows 2000/XP 中添加/刪除程序控件面板對話框中的“支持”信息中顯示的內容。這些設置是可選的，在早期的 Windows 版本中無效
AppPublisherURL=http://www.upc.edu.cn
AppSupportURL=http://www.upc.edu.cn
AppUpdatesURL=http://www.upc.edu.cn
;這個必需的指示值是用於選擇目標位置嚮導面中的默認目錄名，通常它用一個目錄常量作爲前綴，{pf}\SinyoCDManager將顯示:C:\Program Files\SinyoCDManager
DefaultDirName={pf}\一入代碼深似海
;這個指示的值是用在嚮導的選擇開始菜單文件夾頁中使用的默認開始菜單文件夾名。如果這個指示是空白或未指定，它將用“默認”作爲名字
DefaultGroupName=一入代碼深似海

InfoBeforeFile=D:\一入代碼深似海\使用說明.txt
;指定許可協議文件名 (可選)，用 .txt 或 .rtf (富文本) 格式，在用戶選擇程序目標目錄前顯示
LicenseFile=D:\一入代碼深似海\License.txt
;指定“自述”文件名 (可選)，用 .txt 或 .rtf (富文本) 格式，用於在安裝完成後顯示
;InfoAfterFile=D:\一入代碼深似海\使用說明.txt
;這是指定要在文件中使用的壓縮方法，以及壓縮標準
Compression=lzma
;如果設爲 yes，固實壓縮將啓用。這會使所有文件一次性壓縮
SolidCompression=yes

VersionInfoCompany=HTTP://www.upc.edu.cn
VersionInfoDescription=一入代碼深似海
VersionInfoVersion=1.0.0.0 
VersionInfoProductName = {#CSDN}
VersionInfoCopyright=Copyright (C) 2009-2010 CDream
;可重新修復軟件
;AppModifyPath="{app}\Setup.exe" /modify=1
;資源管理器更改環境變量
;ChangesEnvironment=1
;[Tasks]
;這個段是隻選的。它定義安裝程序在執行安裝期間所有由用戶定製的任務。這些任務以選項框和單選項形式在附加任務嚮導頁中出現
; 注意: 下面的條目包含一箇中文用語 (“創建桌面快捷方式”和“添加快捷方式”)。如果需要你可以翻譯爲其它語言。
[Tasks]
Name: "desktopicon"; Description: "創建桌面快捷方式"; GroupDescription: "添加快捷方式:"; Flags: checkedonce
; 注意: 下面的條目包含一箇中文用語 (“創建快速運行欄快捷方式”和“添加快捷方式”)。如果需要你可以翻譯爲其它語言。
;Name: "quicklaunchicon"; Description: "創建快速運行欄快捷方式"; GroupDescription: "添加快捷方式:"; Flags: checkedonce

[Files]
;這是定義安裝程序安裝文件到用戶系統中的可選文件段
;因這是VB軟件，除軟件本身包含的文件外，還必須包含相關的鏈接庫
;以下即軟件本身的文件，注：安裝目錄下有一個 "\Config" 的子目錄
Source: "D:\一入代碼深似海\License.txt"; DestDir: "{app}"; Flags: ignoreversion
Source: "D:\一入代碼深似海\使用說明.txt"; DestDir: "{app}"; Flags: ignoreversion
Source: "D:\一入代碼深似海\幫助.chm"; DestDir: "{app}"; Flags: ignoreversion
Source: "D:\一入代碼深似海\使用手冊.doc"; DestDir: "{app}"; Flags: isreadme
Source: "D:\一入代碼深似海\Config\*"; DestDir: "{app}\Config"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "D:\一入代碼深似海\XdictGrb.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: "D:\一入代碼深似海\msvcrt.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile
; 注意: 不要在任何共享系統文件中使用“Flags: ignoreversion”
[INI]
;這是你希望安裝程序在用戶系統中設置 .INI 文件條目的可選段。
;寫一個文件“訪問我們.url”用於訪問作者網站
Filename: "{app}\訪問我們.url"; Section: "InternetShortcut"; Key: "URL"; String: "http://www.upc.edu.cn";

[Icons]
;這個可選段定義所有創建在開始菜單和/或其它位置 (比如桌面) 的快捷方式
Name: "{group}\一入代碼深似海"; Filename: "{app}\Recognise.exe"; WorkingDir:"{app}"
Name: "{group}\幫助"; Filename: "{app}\幫助.chm"; WorkingDir:"{app}"
Name: "{group}\使用說明"; Filename: "{app}\使用說明.txt"; WorkingDir:"{app}"

; 注意: 下列條目包含一箇中文用語 (“網站”)。如果需要你可以翻譯爲其它語言。
Name: "{group}\訪問主頁"; Filename: "{app}\訪問我們.url"; WorkingDir:"{app}"
Name: "{group}\卸載"; Filename: "{app}\unins000.exe"

Name: "{userdesktop}\一入代碼深似海"; Filename: "{app}\Recognise.exe"; Tasks: desktopicon; WorkingDir:"{app}"
;Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\一入代碼深似海"; Filename: "{app}\Recognise.exe"; Tasks: quicklaunchicon; WorkingDir:"{app}"

[Run]
; 注意: 下列條目包含一箇中文用語 (“運行”)。如果需要你可以翻譯爲其它語言。
;[Run] 段是可選的，用來指定程序完成安裝後、在安裝程序顯示最終對話框之前要執行的程序
Filename: "{app}\Recognise.exe"; Description: "運行 一入代碼深似海"; Flags: nowait postinstall skipifsilent

;更改顯示在程序中顯示的消息文本
[Messages]
BeveledLabel=一入代碼深似海
;卸載對話框說明
ConfirmUninstall=您真的想要從電腦中卸載一入代碼深似海嗎?%n%n按 [是] 則完全刪除 %1 以及它的所有組件;%n按 [否]則讓軟件繼續留在您的電腦上.
;定義解壓說明
;StatusExtractFiles=解壓並複製主程序文件及相關庫文件...

;用與在用戶系統中創建，修改或刪除註冊表健值

[UninstallDelete]
;這個可選段定義你想讓卸載程序刪除除用 [Files] 或 [Dirs] 條目安裝/創建外的其它文件或目錄，或由你應用程序創建的一些公共使用的 .INI 文件。卸載程序在卸載時最後一步處理這些條目
Type: files; Name: "{app}\訪問我們.url"