1. 问题介绍
在SAP系统中,有很多主键是复合在一个参考字段中的,例如字段BKPF-AWKEY。在某些情况下,我们需要通过查找这个复合主键来SELECT数据。
如何进行操作呢?
2. 解决方式
SAP的OPEN SQL中提供了丰富的string操作方法,对于上面例子中的问题,我们可以通过动态拼接的方式,直接完成查找。
例如:对于AWTYPE = 'BKPF'类型的日志,AWKEY会是BLNER + BUKRS + GJAHR的组合。
也即:
示例代码如下:
TYPES: BEGIN OF ts_doc_key,
bukrs TYPE bkpf-bukrs,
belnr TYPE bkpf-belnr,
gjahr TYPE bkpf-gjahr,
END OF ts_doc_key,
BEGIN OF ts_doc_header,
bukrs TYPE bkpf-bukrs,
belnr TYPE bkpf-belnr,
gjahr TYPE bkpf-gjahr,
awtyp TYPE bkpf-awtyp,
awsys TYPE bkpf-awsys,
awkey TYPE bkpf-awkey,
END OF ts_doc_header.
DATA: lt_doc_key TYPE SORTED TABLE OF ts_doc_key WITH UNIQUE KEY bukrs belnr gjahr.
DATA: lt_header1 TYPE STANDARD TABLE OF ts_doc_header WITH EMPTY KEY,
lt_header2 TYPE STANDARD TABLE OF ts_doc_header WITH EMPTY KEY.
BREAK-POINT.
* prepare 10 document keys
SELECT bukrs,
belnr,
gjahr
FROM bkpf
INTO TABLE @lt_doc_key
UP TO 10 ROWS
WHERE awtyp = 'BKPF'.
* concat ( BUKRS, BELNR, GJAHR ) to join the composite key BKPF-AWKEY.
SELECT a~bukrs,
a~belnr,
a~gjahr,
a~awtyp,
a~awsys,
a~awkey
FROM bkpf AS a INNER JOIN @lt_doc_key AS b
ON a~awkey = concat( concat( b~belnr , b~bukrs ), b~gjahr )
WHERE a~awtyp = 'BKPF'
INTO TABLE @lt_header1.
* lt_header1 = lt_header2 ??
SELECT a~bukrs,
a~belnr,
a~gjahr,
a~awtyp,
a~awsys,
a~awkey
FROM bkpf AS a INNER JOIN @lt_doc_key AS b
ON a~bukrs = b~bukrs
AND a~belnr = b~belnr
AND a~gjahr = b~gjahr
WHERE a~awtyp = 'BKPF'
INTO TABLE @lt_header2.
WRITE: 'Done'.