ALV面向對象方法研究：添加自定義工具欄（三）

      本文主要講解添加自定義工具欄。

      跟雙擊一樣，添加自定義的工具欄其實也是在CLASS裏面添加方法並實現之。

      引進圖標：      

INCLUDE <ICON>.

      定義：

* 定義事件屬性跟方法
  CLASS LCL_EVENT_RECEIVER DEFINITION.
PUBLIC SECTION.
      METHODS:
*     雙擊方法
      HANDLE_DOUBLE_CLICK
FOR EVENT DOUBLE_CLICK OF CL_GUI_ALV_GRID
      IMPORTING E_ROW E_COLUMN,
*     按鈕處理方法
      HANDLE_TOOLBAR
FOR EVENT TOOLBAR OF CL_GUI_ALV_GRID
      IMPORTING E_OBJECT E_INTERACTIVE,
*     用戶交互事件處理
      HANDLE_USER_COMMAND
FOR EVENT USER_COMMAND OF CL_GUI_ALV_GRID
      IMPORTING E_UCOMM.
  ENDCLASS.                    "LCL_EVENT_RECEIVER DEFINITION

實現：

*----------------------------------------------------------------------*
*       CLASS LCL_EVENT_RECEIVER IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
  CLASS LCL_EVENT_RECEIVER IMPLEMENTATION.
* 雙擊方法實現
    METHOD HANDLE_DOUBLE_CLICK.
      PERFORM GETRECORD USING E_ROW-INDEX E_COLUMN-FIELDNAME.
    ENDMETHOD.                    "HANDLE_DOUBLE_CLICK
* 處理按鈕事件
    METHOD HANDLE_TOOLBAR.
      DATA: LS_TOOLBAR TYPE STB_BUTTON.
      CLEAR LS_TOOLBAR.
      MOVE 3 TO LS_TOOLBAR-BUTN_TYPE.
* 取工具條接口
      APPEND LS_TOOLBAR TO E_OBJECT->MT_TOOLBAR.
      CLEAR LS_TOOLBAR.
*加入功能碼
      MOVE 'SHOW_DETA' TO LS_TOOLBAR-FUNCTION.
*圖標，可以用SHOWICON系統程序查閱使用的圖標
      MOVE ICON_PPE_ENODE TO LS_TOOLBAR-ICON.
*按鈕文本和提示
      MOVE '明細顯示' TO LS_TOOLBAR-QUICKINFO.
      MOVE '明細顯示'(112) TO LS_TOOLBAR-TEXT.
      MOVE '' TO LS_TOOLBAR-DISABLED.
*添加到工具條
      APPEND LS_TOOLBAR TO E_OBJECT->MT_TOOLBAR.
    ENDMETHOD.                    "HANDLE_TOOLBAR
* 處理功能碼事件
    METHOD HANDLE_USER_COMMAND.
      DATA: LT_ROWS TYPE LVC_T_ROW.
CASE E_UCOMM.
* 定義的按鈕事件
WHEN 'SHOW_DETA'.
*取得所有選擇行
          CALL METHOD GR_ALVGRID->GET_SELECTED_ROWS
            IMPORTING
              ET_INDEX_ROWS = LT_ROWS.
          CALL METHOD CL_GUI_CFW=>FLUSH.
IF SY-SUBRC EQ 0.
* 提示成功
            MESSAGE  '已經選擇行！' TYPE 'S'.
*調用子程序顯示行內容
            PERFORM  READDATA TABLES LT_ROWS.
          ENDIF.
      ENDCASE.
    ENDMETHOD.                    "HANDLE_USER_COMMAND                   "HANDLE_DOUBLE_CLICK
  ENDCLASS.                    "LCL_EVENT_RECEIVER IMPLEMENTATION


* 顯示選擇行內容模版
  FORM READDATA TABLES P_ET_INDEX_ROWS STRUCTURE LVC_S_ROW.
* 定義選擇行
    DATA: LS_SELECTED_LINE LIKE LVC_S_ROW,
          LF_ROW_INDEX TYPE LVC_INDEX.
*定義合併字段及分割字段
    DATA: S1(200) TYPE C,
          S2(3)  TYPE C.
    S2 = '-'.
*讀取所有選擇行
    LOOP AT P_ET_INDEX_ROWS INTO LS_SELECTED_LINE.
      LF_ROW_INDEX = LS_SELECTED_LINE-INDEX.
* 從內表中按順序讀取內容
READ TABLE IT_SFLIGHT INDEX LF_ROW_INDEX.
      S1 = '選擇行內容：'.
*  合併
      CONCATENATE S1 IT_SFLIGHT-CONNID IT_SFLIGHT-CARRID
INTO S1 SEPARATED BY S2.
* 彈出窗口提示
      MESSAGE S1 'I'.
    ENDLOOP.
  ENDFORM.                   

當然，最後還得在刷新alv前添加：

*   將用戶交互事件分配ALV
SET HANDLER EVENT_RECEIVER->HANDLE_USER_COMMAND FOR GR_ALVGRID.
*   將按鈕相關事件分配ALV
SET HANDLER EVENT_RECEIVER->HANDLE_TOOLBAR FOR GR_ALVGRID.
*   調用處理工具條處理方法，使自定義工具條生效
      CALL METHOD GR_ALVGRID->SET_TOOLBAR_INTERACTIVE.