在Startup.s文件中包含一個startup的入口函數,該函數爲EBOOT的最開始的入口。在系統上電或者冷啓動的時候,這是第一個被執行的函數。該函數都是由彙編語言編寫的,完成基於硬件平臺的最初的初始化,也就是CPU的相關初始化,如果有必要,也可以在這裏對外圍的設備進行初始化。該函數執行到最後,會跳轉到C語言的入口,一般是Main函數,或者叫做EBootMain函數。
這裏要多說的一件事情就是在BSP當中存在兩個Startup.s文件,一個是EBOOT的Startup.s用於EBOOT本身,另一個是OAL的Startup.s用於WinCE內核。在很多情況下,兩個Startup.s所完成的任務非常的相近,所以一般都會合併成一個Startup.s來完成相應的功能。比如你在EBOOT的Startup.s中完成了相關的初始化操作以後,在OAL的Startup.s中只需要include位於EBOOT下的Startup.s就可以了。當然,這兩個Startup.s也許不能完全一樣,所以不管是真的存在兩個Startup.s文件還是共用一個Startup.s文件,你可能都需要在Startup.s中通過條件編譯或者判斷某個變量的方法來區分。
下面具體說一下在Startup.s中,到底應該做些什麼事情:
1. 在系統上電或者復位時,先將CPU設置到正確的模式下面。一般CPU本身會有幾種模式,比如對於ARM來說,這個時候一般會設置爲管理模式。
2. 關閉所有的CPU中斷。
3. 關閉內存管理單元MMU和TLB。
4. 關閉寫緩衝和Cache。
5. 初始化內存控制器。
6. 設置CPU的PLL,設置時鐘。
7. 創建堆棧。
8. 設置並打開MMU和Cache。
9. 如果需要,自己拷貝EBOOT從Flash到RAM中。
10. 跳轉到C代碼中,一般是Main函數或者EBootMain函數。
下面以ARM爲例,來看一個Startup.s的模板:
- STARTUPTEXT
- LEAF_ENTRY StartUp
- ; 設置ARM的CPSR寄存器來設置ARM爲管理模式並屏蔽所有中斷
- mov r0, #(SVC32Mode :OR: NoINTS)
- msr cpsr_c, r0
- ; 設置CP15協處理器,關閉MMU和Cache
- ldr r0, =CP15ControlInit
- WRMMU_STATE r0
- ldr r0, =CP15AuxControlInit
- WRMMU_AUX_STATE r0
- ; 刷新TLB表和Cache
- mov r0, #0x0
- WRMMU_FlushTB r0
- WRCACHE_FlushIDC r0
- ; 釋放寫緩衝
- mov r0, #0
- mcr p15, 0, r0, c7, c10, 4
- CPWAIT
- ; 創建一個臨時的堆棧,使用SRAM中的頭32KB
- ldr sp, =(CPU_SRAM0 + SZ_32K - 4)
- bl disableInts ; 屏蔽外部中斷
- bl initUART ; 初始化串口
- bl initClocks ; 初始化系統時鐘
- bl initStaticMem ; 初始化Flash片選控制器
- bl initSDRAM ; 初始化SDRAM控制器
- bl sizeSDRAM ; 返回SDRAM的大小
- IF EBOOT
- ; 重定位Flash中的代碼到RAM中
- bl EverythingRelocate
- ; 重定位成功後,跳轉到RealStartup新地址運行,否則接着運行
- cmp r0, #-1
- movne pc, r0
- ENDIF
- RealStartup
- IF EBOOT
- bl EbootMain ; 跳轉到EbootMain函數,就是EBOOT的C語言代碼中
- ELSE
- adr r0, OEMAddressTable ; r0 = physical address of OEMMemoryMap
- bl KernelStart ; 跳轉到KernelStart函數,並傳入物理虛擬地址映射表
- ENDIF
- ; 這裏是一個死循環,代碼應該永遠也執行不到這裏
- spin b spin
- ENTRY_END
整個Startup.s的流程就是這樣,一般開發這段代碼需要對處理器及彙編語言比較瞭解,其實也不是很複雜,就是做最基本的初始化,該函數一般也就幾百行。調試可能稍微費勁一些,在最開始的時候一般通過點燈(Led)的方式來調試,就是說寫個小的彙編函數,通過把GPIO拉高拉低來點亮和熄滅LED燈。然後在Startup.s中的不同位置調用該函數從而判斷函數是否執行到相應的地方。