一鍵調節音量

Ctrl+→：增大音量並顯示當前音量；
Ctrl＋←：減小音量並顯示當前音量。
Ctrl＋小鍵盤*：靜音

^Right::
 Goto, vol+
 return
 ^Left:: ;還可以這樣:>^left::SoundSet -5
 Goto, vol-
 return
 ^NumpadMult::Send {Volume_mute}

vol+:
 vol-:

GUI_W=700 ;設置gui的寬度;
GUI_H=80 ;設置gui的高度(包括上下文字在內了)
Gui_X :=(A_ScreenWidth-GUI_W)/2 ;"" 取屏幕中間一半的地方放置gui
 Gui_Y := A_ScreenHeight-190 ;s
 wp:=GUI_W*0.9 ;w-H ;進度條的長度
hp:=GUI_H/3 ;進度條高度
xp:=(GUI_W-wp)/2 ;進度條x位置
Back_Colour := 0x000000 ;背景色:黑色
Font_Colour := 0xFFFFFF ;字體顏色:白色;
BackBar_Colour := 0x000000 ;進度條背景色：黑色
Bar_Colour := 0x0000FF ;活動進度條顏色：藍色
Max_Trans := 200 ;最大透明度
SoundGet, Vol ;獲取主音量；
Curr_Vol := Vol ;將當前主音量賦予當前的音量；
Trans := Max_Trans ;透明度賦值
IfWinnotExist,Vol_OSD ;若不存在則創建窗口;
 {
GUI, Color, % Back_Colour, ;設置gui背景顏色爲黑色;
GUI, Font, c%Font_Colour% s13 ;設置gui上面的字體字體大小;
GUI, Add, Text, w%wp% x%xp% Center, ZL音量調節 ;添加gui標題爲volume。【其實,也就是第一行添加字體,寫字,第二行添加進度條,第三行添加字體數值】
GUI, Font
 GUI Add, Progress,horizontal vProgress x%xp% w%wp% h%hp% c%Bar_Colour% +Background%BackBar_Colour% , % Curr_Vol ;gui添加進度條;
GUI, Font, c%Font_Colour% s13 ;設置gui下面的字體大小;
SoundGet, Vol ;獲取當前音量;

RegExMatch( Vol, "(?<Percent>\d+)\.", rg ) ;對當前音量格式進行正則匹配處理;目的就是獲取音量數值；
GUI, Add, Text, w%wp% x%xp% Center vVol, % rgPercent ;w500
 GUI, Show, NoActivate h%GUi_H% w%GUi_W% x%Gui_X% y%Gui_Y%, Vol_OSD

GUI_wR:=GUI_W*1.25
 GUI_HR:=GUI_H*1.5
 WinSet, Region, w%GUI_WR% h%GUI_HR% R10-10 0-0, Vol_OSD
 WinSet, Transparent, %Trans%, Vol_OSD ;設置透明度;
GUI, -Caption +AlwaysOnTop +E0x20 +SysMenu
 }

WinSet, Transparent, 255, Vol_OSD ;255爲不透明;0爲全透明;
SoundSet, % InStr(A_ThisLabel,"+") ? "+1" : "-1", MASTER
 SoundGet, Vol ;再次獲取修改後的主音量;
GuiControl,, Progress, % Vol
 RegExMatch( Vol, "(?<Percent>\d+)\.", rg )
 GuiControl,, Vol, % rgPercent
 SetTimer, Fade, -1500
 return

Fade: ;設置gui消失時間;
While ( Trans > 0) ;這樣做是增加淡出效果;
 { Trans -= 2
 WinSet, Transparent, % Trans, Vol_OSD
Sleep, 5
 }
 GUI,destroy
 winclose,Vol_OSD
Return