SQL Server 中，實現 varbinary 與 varchar 類型之間的數據轉換

 

在工控應用上，返回的數據經常會以二進制的形成存儲，而這些二進制數據又是以每4個bit表示一個十六進制的數據內容。

解析的時候，往往是一個字節（Byte）佔用8個位（bit），高位4bit 表示一個十六進制數據，低位4bit 表示一個十六進制數據。

 

問題描述：在SQL Server 數據庫中，如何實現二進制數據與字符串數據之間的直接轉換？

一定會有人立馬反問我：爲什麼不在程序中使用 C# 或者 JAVA 或者 C++ 來處理這個業務呢？

我的回答是：這個我知道，也已經實現了。但在一些特殊的應用環境和業務需求面前（如：對數據的統計、對數據的分析），我必須這麼做！

 

SQL Server 數據庫中，實現 varbinary 類型轉換成 varchar 類型

這個已經有人實現了，並且處理得相當巧妙。實現的思路是：

每次取得 varbinary 中一個字節的數據，然後除以16 獲得高位的4bit數據，再模16獲得低位的4bit數據；

分別從固定字符串中以下標的形式匹配對應的字符，最後累加起來即可。

代碼如下：

    --==============================================
    --  FUNCTION  varbin2hexstr
    --  將 varbinary 類型的數據轉換爲 varchar 類型
    --==============================================
    
    IF OBJECT_ID ('dbo.varbin2hexstr') IS NOT NULL
        DROP FUNCTION dbo.varbin2hexstr
    GO
    
    CREATE function varbin2hexstr(
    @bin varbinary(8000)
    )returns varchar(8000)
    as
    begin
        declare @re varchar(8000),@i int
        select @re='',@i=datalength(@bin)
        while @i>0
            select @re=substring('0123456789ABCDEF',substring(@bin,@i,1)/16+1,1)
                    +substring('0123456789ABCDEF',substring(@bin,@i,1)%16+1,1)
                    +@re
                ,@i=@i-1
       -- return('0x'+@re)
        return @re
    end
    
    GO

測試示例：

select dbo.varbin2hexstr(0x1432fabcdef1234567890)

來源：SqlServer中varbinary轉換成字符串

 

SQL Server 數據庫中，實現 varchar類型轉換成 varbinary 類型

一定會有人立馬就說：既然已經實現了varbinary 類型轉換成 varchar 類型，你需要做的，只是將函數逆向反轉實現便可。

如果真是這麼簡單，估計網上早就應該有了。但結果是：網上找不到（至少我沒有找到），實現也並非如此！

只能自己動手，豐衣足食了。實現的思路是：

先將整個字符串按照每兩位分組；

     爲什麼不按照每8位或每4位進行分組？是爲了考慮到函數的通用性。

     如果按照每 8位 或者 每4位 分組，則整個字符串必須是8或者4的倍數，否則將出現字符不足，前面補 0的情況。

然後對每個字符進行處理，如：字符“A B C D E F” 對應轉換爲“10 11 12 13 14 15”；

接着對每2個字符進行 16 的冪運算，並求和。如： AB = 10 * 16的一次方 + 11 * 16的零次方；

再將這個2個字符的整數和，轉換爲一個字節（Byte）長度的 varbinary 數據；

最後將所有的 varbinary 數據直接相加即可。

代碼如下：

--==============================================
--  FUNCTION  hexstr2varbin
--  將 varchar 類型的數據轉換爲 varbinary 類型
--==============================================

IF OBJECT_ID ('dbo.hexstr2varbin') IS NOT NULL
    DROP FUNCTION dbo.hexstr2varbin
GO

CREATE function [dbo].[hexstr2varbin](
  @char varchar(8000)
)returns varbinary(8000)
as
begin
    declare @re varbinary(8000), @tempchar varchar(2), 
            @getchar varchar(1), @getint int, @n int, @totalint int,
            @i int, @tempint int, @runNum int -- 字符串截取段數

     select @tempchar='',@i=datalength(@char), @re=0x; 

    if( @i>0)
    begin
        if ( @i%2 = 0) set @runNum= @i/2
        else set @runNum= @i/2 + 1 

        while (@runNum > 0)
        begin
            if(@runNum = 1) set @tempchar = @char 
            else set @tempchar = substring(@char, (@runNum-1)*2,2)

            select @n=1,@totalint=0;
            
            -- 循環處理截取的每個字符串 (這裏的字符串長度爲2)
            while @n < ( datalength(@tempchar) + 1 )
            begin
                set @getchar=substring(@tempchar,@n,1);

                -- 將字符轉換爲十六進制對應的數字
                select @getint=case  
                       when @getchar='a' then 10 
                       when @getchar='b' then 11
                       when @getchar='c' then 12 
                       when @getchar='d' then 13
                       when @getchar='e' then 14 
                       when @getchar='f' then 15
                       else  convert(int,@getchar) end;

                set @tempint=@getint*power(16,datalength(@tempchar)-@n)
                set @totalint = @totalint + @tempint
                set @n=@n+1
            end 

               set @re=convert(varbinary(1),@totalint) + @re;    
               set @runNum=@runNum-1;         
        end
    end
   return @re

end
GO

測試示例：

select dbo.hexstr2varbin('ffffff2353f5feefaffae1fff1ffbaf1faffa33333333ff3aaafffffffaaff')

（完）