原文鏈接：http://www.cnblogs.com/SGSoft/archive/2010/09/12/1824228.html
1 echo 和 @
回顯命令
@ #關閉單行回顯
echo off #從下一行開始關閉回顯
@echo off #從本行開始關閉回顯。一般批處理第一行都是這個
echo on #從下一行開始打開回顯
echo #顯示當前是 echo off 狀態還是 echo on 狀態
echo. #輸出一個”回車換行”，空白行
#(同echo, echo; echo+ echo[ echo] echo/ echo)
2 errorlevel
echo %errorlevel%
每個命令運行結束，可以用這個命令行格式查看返回碼
默認值爲0，一般命令執行出錯會設 errorlevel 爲1
3 dir
顯示文件夾內容
dir #顯示當前目錄中的文件和子目錄
dir /a #顯示當前目錄中的文件和子目錄，包括隱藏文件和系統文件
dir c: /a:d #顯示 C 盤當前目錄中的目錄
dir c: /a:-d #顯示 C 盤根目錄中的文件
dir c: /b/p #/b只顯示文件名，/p分頁顯示
dir *.exe /s #顯示當前目錄和子目錄裏所有的.exe文件
4 cd
切換目錄
cd #進入根目錄
cd #顯示當前目錄
cd /d d:sdk #可以同時更改盤符和目錄
5 md
創建目錄
md d:abc #如果 d:a 不存在，將會自動創建中級目錄
#如果命令擴展名被停用，則需要鍵入 mkdir abc。
6 rd
刪除目錄
rd abc #刪除當前目錄裏的 abc 子目錄，要求爲空目錄
rd /s/q d:temp #刪除 d:temp 文件夾及其子文件夾和文件，/q安靜模式
7 del
刪除文件
del d:test.txt #刪除指定文件，不能是隱藏、系統、只讀文件
del /q/a/f d:temp*.*
刪除 d:temp 文件夾裏面的所有文件，包括隱藏、只讀、系統文件，不包括子目錄
del /q/a/f/s d:temp*.*
刪除 d:temp 及子文件夾裏面的所有文件，包括隱藏、只讀、系統文件，不包括子目錄
8 ren
重命名命令
ren d:temp tmp #支持對文件夾的重命名
9 cls
清屏
10 type
顯示文件內容
type c:boot.ini #顯示指定文件的內容，程序文件一般會顯示亂碼
type *.txt #顯示當前目錄裏所有.txt文件的內容
11 copy
拷貝文件
copy c:test.txt d:test.bak
複製 c:test.txt 文件到 d: ，並重命名爲 test.bak
copy con test.txt
從屏幕上等待輸入，按 Ctrl+Z 結束輸入，輸入內容存爲test.txt文件
con代表屏幕，prn代表打印機，nul代表空設備
copy 1.txt + 2.txt 3.txt
合併 1.txt 和 2.txt 的內容，保存爲 3.txt 文件
如果不指定 3.txt ，則保存到 1.txt
copy test.txt +
複製文件到自己，實際上是修改了文件日期
12 title
設置cmd窗口的標題
title 新標題 #可以看到cmd窗口的標題欄變了
13 ver
顯示系統版本
14 label 和 vol
設置卷標
vol #顯示卷標
label #顯示卷標，同時提示輸入新卷標
label c:system #設置C盤的卷標爲 system
15 pause
暫停命令
16 rem 和 ::
註釋命令
註釋行不執行操作
17 date 和 time
日期和時間
date #顯示當前日期，並提示輸入新日期，按"回車"略過輸入
date/t #只顯示當前日期，不提示輸入新日期
time #顯示當前時間，並提示輸入新時間，按"回車"略過輸入
time/t #只顯示當前時間，不提示輸入新時間
18 goto 和 :
跳轉命令
:label #行首爲:表示該行是標籤行，標籤行不執行操作
goto label #跳轉到指定的標籤那一行
19 find (外部命令)
查找命令
find "abc" c:test.txt
在 c:test.txt 文件裏查找含 abc 字符串的行
如果找不到，將設 errorlevel 返回碼爲1
find /i “abc” c:test.txt
查找含 abc 的行，忽略大小寫
find /c "abc" c:test.txt
顯示含 abc 的行的行數
20 more (外部命令)
逐屏顯示
more c:test.txt #逐屏顯示 c:test.txt 的文件內容
21 tree
顯示目錄結構
tree d: #顯示D盤的文件目錄結構
22 &
順序執行多條命令，而不管命令是否執行成功
23 &&
順序執行多條命令，當碰到執行出錯的命令後將不執行後面的命令
find "ok" c:test.txt && echo 成功
如果找到了"ok"字樣，就顯示"成功"，找不到就不顯示
24 ||
順序執行多條命令，當碰到執行正確的命令後將不執行後面的命令
find "ok" c:test.txt || echo 不成功
如果找不到"ok"字樣，就顯示"不成功"，找到了就不顯示
25 |
管道命令
dir *.* /s/a | find /c ".exe"
管道命令表示先執行 dir 命令，對其輸出的結果執行後面的 find 命令
該命令行結果：輸出當前文件夾及所有子文件夾裏的.exe文件的個數
type c:test.txt|more
這個和 more c:test.txt 的效果是一樣的
26 > 和 >>
輸出重定向命令
> 清除文件中原有的內容後再寫入
>> 追加內容到文件末尾，而不會清除原有的內容
主要將本來顯示在屏幕上的內容輸出到指定文件中
指定文件如果不存在，則自動生成該文件
type c:test.txt >prn
屏幕上不顯示文件內容，轉向輸出到打印機
echo hello world>con
在屏幕上顯示hello world，實際上所有輸出都是默認 >con 的
copy c:test.txt f: >nul
拷貝文件，並且不顯示"文件複製成功"的提示信息，但如果f盤不存在，還是會顯示出錯信息
copy c:test.txt f: >nul 2>nul
不顯示”文件複製成功”的提示信息，並且f盤不存在的話，也不顯示錯誤提示信息
echo ^^W ^> ^W>c:test.txt
生成的文件內容爲 ^W > W
^ 和 > 是控制命令，要把它們輸出到文件，必須在前面加個 ^ 符號
27 <
從文件中獲得輸入信息，而不是從屏幕上
一般用於 date time label 等需要等待輸入的命令
@echo off
echo 2005-05-01>temp.txt
date <temp.txt
del temp.txt
這樣就可以不等待輸入直接修改當前日期
28 %0 %1 %2 %3 %4 %5 %6 %7 %8 %9 %*
命令行傳遞給批處理的參數
%0 批處理文件本身
%1 第一個參數
%9 第九個參數
%* 從第一個參數開始的所有參數
批參數(%n)的替代已被增強。您可以使用以下語法:
%~1 - 刪除引號(")，擴充 %1
%~f1 - 將 %1 擴充到一個完全合格的路徑名
%~d1 - 僅將 %1 擴充到一個驅動器號
%~p1 - 僅將 %1 擴充到一個路徑
%~n1 - 僅將 %1 擴充到一個文件名
%~x1 - 僅將 %1 擴充到一個文件擴展名
%~s1 - 擴充的路徑指含有短名
%~a1 - 將 %1 擴充到文件屬性
%~t1 - 將 %1 擴充到文件的日期/時間
%~z1 - 將 %1 擴充到文件的大小
%~$PATH : 1 - 查找列在 PATH 環境變量的目錄，並將 %1
擴充到找到的第一個完全合格的名稱。如果環境
變量名未被定義，或者沒有找到文件，此組合鍵會
擴充到空字符串
可以組合修定符來取得多重結果:
%~dp1 - 只將 %1 擴展到驅動器號和路徑
%~nx1 - 只將 %1 擴展到文件名和擴展名
%~dp$PATH:1 - 在列在 PATH 環境變量中的目錄裏查找 %1，
並擴展到找到的第一個文件的驅動器號和路徑。
%~ftza1 - 將 %1 擴展到類似 DIR 的輸出行。
可以參照 call/? 或 for/? 看出每個參數的含意
echo load "%%1" "%%2">c:test.txt
生成的文件內容爲 load "%1" "%2"
批處理文件裏，用這個格式把命令行參數輸出到文件
29 if
判斷命令
if "%1"=="/a" echo 第一個參數是/a
if /i "%1" equ "/a" echo 第一個參數是/a
/i 表示不區分大小寫，equ 和 == 是一樣的，其它運算符參見 if/?
if exist c:test.bat echo 存在c:test.bat文件
if not exist c:windows (
echo 不存在c:windows文件夾
)
if exist c:test.bat (
echo 存在c:test.bat
) else (
echo 不存在c:test.bat
)
30 setlocal 和 endlocal
設置”命令擴展名”和”延緩環境變量擴充”
SETLOCAL ENABLEEXTENSIONS #啓用"命令擴展名"
SETLOCAL DISABLEEXTENSIONS #停用"命令擴展名"
SETLOCAL ENABLEDELAYEDEXPANSION #啓用"延緩環境變量擴充"
SETLOCAL DISABLEDELAYEDEXPANSION #停用"延緩環境變量擴充"
ENDLOCAL #恢復到使用SETLOCAL語句以前的狀態
“命令擴展名”默認爲啓用
“延緩環境變量擴充”默認爲停用
批處理結束系統會自動恢復默認值
可以修改註冊表以禁用"命令擴展名"，詳見 cmd /? 。所以用到"命令擴展名"的程
序，建議在開頭和結尾加上 SETLOCAL ENABLEEXTENSIONS 和 ENDLOCAL 語句，以確
保程序能在其它系統上正確運行
"延緩環境變量擴充"主要用於 if 和 for 的符合語句，在 set 的說明裏有其實用例程
31 set
設置變量
引用變量可在變量名前後加 % ，即 %變量名%
set #顯示目前所有可用的變量，包括系統變量和自定義的變量
echo %SystemDrive% #顯示系統盤盤符。系統變量可以直接引用
set p #顯示所有以p開頭的變量，要是一個也沒有就設errorlevel=1
set p=aa1bb1aa2bb2 #設置變量p，並賦值爲 = 後面的字符串，即aa1bb1aa2bb2
echo %p% #顯示變量p代表的字符串，即aa1bb1aa2bb2
echo %p:~6% #顯示變量p中第6個字符以後的所有字符，即aa2bb2
echo %p:~6,3% #顯示第6個字符以後的3個字符，即aa2
echo %p:~0,3% #顯示前3個字符，即aa1
echo %p:~-2% #顯示最後面的2個字符，即b2
echo %p:~0,-2% #顯示除了最後2個字符以外的其它字符，即aa1bb1aa2b
echo %p:aa=c% #用c替換變量p中所有的aa，即顯示c1bb1c2bb2
echo %p:aa=% #將變量p中的所有aa字符串置換爲空，即顯示1bb12bb2
echo %p:*bb=c% #第一個bb及其之前的所有字符被替換爲c，即顯示c1aa2bb2
set p=%p:*bb=c% #設置變量p，賦值爲 %p:*bb=c% ，即c1aa2bb2
set /a p=39 #設置p爲數值型變量，值爲39
set /a p=39/10 #支持運算符，有小數時用去尾法，39/10=3.9，去尾得3，p=3
set /a p=p/10 #用 /a 參數時，在 = 後面的變量可以不加%直接引用
set /a p=”1&0″ #”與”運算，要加引號。其它支持的運算符參見set/?
set p= #取消p變量
set /p p=請輸入
屏幕上顯示”請輸入”，並會將輸入的字符串賦值給變量p
注意這條可以用來取代 choice 命令
注意變量在 if 和 for 的複合語句裏是一次性全部替換的，如
@echo off
set p=aaa
if %p%==aaa (
echo %p%
set p=bbb
echo %p%
)
結果將顯示
aaa
aaa
因爲在讀取 if 語句時已經將所有 %p% 替換爲aaa
這裏的"替換"，在 /? 幫助裏就是指"擴充"、"環境變量擴充"
可以啓用”延緩環境變量擴充”，用 ! 來引用變量，即 !變量名!
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set p=aaa
if %p%==aaa (
echo %p%
set p=bbb
echo !p!
)
ENDLOCAL
結果將顯示
aaa
bbb
還有幾個動態變量，運行 set 看不到
%CD% #代表當前目錄的字符串
%DATE% #當前日期
%TIME% #當前時間
%RANDOM% #隨機整數，介於0~32767
%ERRORLEVEL% #當前 ERRORLEVEL 值
%CMDEXTVERSION% #當前命令處理器擴展名版本號
%CMDCMDLINE% #調用命令處理器的原始命令行
可以用echo命令查看每個變量值，如 echo %time%
注意 %time% 精確到毫秒，在批處理需要延時處理時可以用到
32 start
批處理中調用外部程序的命令，否則等外部程序完成後才繼續執行剩下的指令
33 call
批處理中調用另外一個批處理的命令，否則剩下的批處理指令將不會被執行
有時有的應用程序用start調用出錯的，也可以call調用
34 choice (外部命令)
選擇命令
讓用戶輸入一個字符，從而選擇運行不同的命令，返回碼errorlevel爲1234……
win98裏是choice.com
win2000pro裏沒有，可以從win98裏拷過來
win2003裏是choice.exe
choice /N /C y /T 5 /D y>nul
延時5秒
35 assoc 和 ftype
文件關聯
assoc 設置'文件擴展名'關聯，關聯到'文件類型'
ftype 設置'文件類型'關聯，關聯到'執行程序和參數'
當你雙擊一個.txt文件時，windows並不是根據.txt直接判斷用 notepad.exe 打開
而是先判斷.txt屬於 txtfile '文件類型'
再調用 txtfile 關聯的命令行 txtfile=%SystemRoot%system32NOTEPAD.EXE %1
可以在"文件夾選項"→"文件類型"裏修改這2種關聯
assoc #顯示所有'文件擴展名'關聯
assoc .txt #顯示.txt代表的'文件類型'，結果顯示 .txt=txtfile
assoc .doc #顯示.doc代表的'文件類型'，結果顯示 .doc=Word.Document.8
assoc .exe #顯示.exe代表的'文件類型'，結果顯示 .exe=exefile
ftype #顯示所有'文件類型'關聯
ftype exefile #顯示exefile類型關聯的命令行，結果顯示 exefile="%1" %*
assoc .txt=Word.Document.8
設置.txt爲word類型的文檔，可以看到.txt文件的圖標都變了
assoc .txt=txtfile
恢復.txt的正確關聯
ftype exefile="%1" %*
恢復 exefile 的正確關聯
如果該關聯已經被破壞，可以運行 command.com ，再輸入這條命令
36 pushd 和 popd
切換當前目錄
@echo off
c: & cd & md mp3 #在 C: 建立 mp3 文件夾
md d:mp4 #在 D: 建立 mp4 文件夾
cd /d d:mp4 #更改當前目錄爲 d:mp4
pushd c:mp3 #保存當前目錄，並切換當前目錄爲 c:mp3
popd #恢復當前目錄爲剛纔保存的 d:mp4
37 for
循環命令
這個比較複雜，請對照 for/? 來看
for %%i in (c: d: e: f:) do echo %%i
依次調用小括號裏的每個字符串，執行 do 後面的命令
注意%%i，在批處理中 for 語句調用參數用2個%
默認的字符串分隔符是"空格鍵"，"Tab鍵"，"回車鍵"
for %%i in (*.txt) do find "abc" %%i
對當前目錄裏所有的txt文件執行 find 命令
for /r . %%i in (*.txt) do find "abc" %%i
在當前目錄和子目錄裏所有的.txt文件中搜索包含 abc 字符串的行
for /r . %%i in (.) do echo %%~pni
顯示當前目錄名和所有子目錄名，包括路徑，不包括盤符
for /r d:mp3 %%i in (*.mp3) do echo %%i>>d:mp3.txt
把 d:mp3 及其子目錄裏的mp3文件的文件名都存到 d:mp3.txt 裏去
for /l %%i in (2,1,8) do echo %%i
生成2345678的一串數字，2是數字序列的開頭，8是結尾，1表示每次加1
for /f %%i in ('set') do echo %%i
對 set 命令的輸出結果循環調用，每行一個
for /f "eol=P" %%i in ('set') do echo %%i
取 set 命令的輸出結果，忽略以 P 開頭的那幾行
for /f %%i in (d:mp3.txt) do echo %%i
顯示 d:mp3.txt 裏的每個文件名，每行一個，不支持帶空格的名稱
for /f "delims=" %%i in (d:mp3.txt) do echo %%i
顯示 d:mp3.txt 裏的每個文件名，每行一個，支持帶空格的名稱
for /f "skip=5 tokens=4" %%a in ('dir') do echo %%a
對 dir 命令的結果，跳過前面5行，餘下的每行取第4列
每列之間的分隔符爲默認的"空格"
可以注意到 dir 命令輸出的前5行是沒有文件名的
for /f "tokens=1,2,3 delims=- " %%a in ('date /t') do (
echo %%a
echo %%b
echo %%c
)
對 date /t 的輸出結果，每行取1、2、3列
第一列對應指定的 %%a ，後面的 %%b 和 %%c 是派生出來的，對應其它列
分隔符指定爲 - 和"空格"，注意 delims=- 後面有個"空格"
其中 tokens=1,2,3 若用 tokens=1-3 替換，效果是一樣的
for /f "tokens=2* delims=- " %%a in ('date /t') do echo %%b
取第2列給 %%a ，其後的列都給 %%b
38 subst (外部命令)
映射磁盤。
subst z: serverd #這樣輸入z:就可以訪問serverd了
subst z: /d #取消該映射
subst #顯示目前所有的映時
39 xcopy (外部命令)
文件拷貝
xcopy d:mp3 e:mp3 /s/e/i/y
複製 d:mp3 文件夾、所有子文件夾和文件到 e: ，覆蓋已有文件
加 /i 表示如果 e: 沒有 mp3 文件夾就自動新建一個，否則會有詢問
批處理中符號的意義
一、單符號
~
① 在for中表示使用增強的變量擴展。
② 在%var:~n,m%中表示使用擴展環境變量指定位置的字符串。
③ 在set/a中表示一元運算符，將操作數按位取反。
!
① 在set /a中一元運算符，表示邏輯非。比如set /a a=!0，這時a就表示邏輯1。
@
① 隱藏命令行本身的回顯，常用於批處理中。
$
① 在findstr命令裏面表示一行的結束。
② 在prompt命令裏面，表示將其後的字符轉義（符號化或者效果化）。
%
① 在set /a中的二元運算符，表示算術取餘。
② 命令行環境下，在for命令in前，後面接一個字符（可以是字母、數字或者一些特定字符），表示指定一個循環或者遍歷指標變量。
③ 批處理中，後接一個數字表示引用本批處理當前執行時的指定的參數。
④ 其它情況下，%將會被脫去（批處理）或保留（命令行）
^
① 取消特定字符的轉義作用，比如& | > < ! "等，但不包括%。比如要在屏幕顯示一些特殊的字符，比如> >> | ^ &等符號時，就可以在其前面加一個^符號來顯示這個^後面的字符了，^^就是顯示一個^，^|就是顯示一個|字符了;
② 在set/a中的二元運算符，表示按位異或。
③ 在findstr/r的[]中表示不匹配指定的字符集。
&
① 命令連接字符。比如我要在一行文本上同時執行兩個命令，就可以用&命令連接這兩個命令。
② 在set/a中是按位與。
*
① 代表任意個任意字符，就是我們通常所說的"通配符";比如想在c盤的根目錄查找c盤根目錄裏所有的文本文件(.txt)，那麼就可以輸入命令"dir c:\*.txt"。
② 在set /a中的二元運算符，表示算術乘法。
③ 在findstr/r中表示將前一個字符多次匹配。
-
① 範圍表示符，比如日期的查找，for命令裏的tokens操作中就可以用到這個字符。
② 在findstr/r中連接兩個字符表示匹配範圍。
③ -跟在某些命令的/後表示取反向的開關。
④ 在set /a中：
1.表示一個負數。
2.表示算術減運算。
+
① 主要是在copy命令裏面會用到它，表示將很多個文件合併爲一個文件，就要用到這個+字符了。
② 在set/a中的二元運算符,表示算術加法。
:
① 標籤定位符，表示其後的字符串爲以標籤，可以作爲goto命令的作用對象。比如在批處理文件裏面定義了一個":begin"標籤，用"goto begin"命令就可以轉到":begin"標籤後面來執行批處理命令了。
② 在%var:string1=string2%中分隔變量名和被替換字串關係。
|
① 管道符，就是將上一個命令的輸出，作爲下一個命令的輸入."dir /a/b |more"就可以逐屏的顯示dir命令所輸出的信息。
② 在set/a中的二元運算符，表示按位或。
③ 在幫助文檔中表示其前後兩個開關、選項或參數是二選一的。
/
① 表示其後的字符（串）是命令的功能開關（選項）。比如"dir /s/b/a-d"表示"dir"命令指定的不同的參數。
② 在set/a中表示除法。
>
① 命令重定向符，將其前面的命令的輸出結果重新定向到其後面的設備中去，後面的設備中的內容被覆蓋。比如可以用"dir > lxmxn.txt"將"dir"命令的結果輸出到"lxmxn.txt"這個文本文件中去。
② 在findstr/r中表示匹配單詞的右邊界，需要配合轉義字符\使用。
<
① 將其後面的文件的內容作爲其前面命令的輸入。
② 在findstr/r中表示匹配單詞的左邊界，需要配合轉義字符\使用。
=
① 賦值符號，用於變量的賦值。比如"set a=windows"的意思意思是將"windows"這個字符串賦給變量"a"。
② 在set/a中表示算術運算，比如"set /a x=5-6*5"。
\
① 這個"\"符號在有的情況下，代表的是當前路徑的根目錄.比如當前目錄在c:\windows\system32下，那麼你"dir \"的話，就相當與"dir c:\"。
② 在findstr/r中表示正則轉義字符。
,
① 在set /a中表示連續表達式的分割符。
② 在某些命令中分割元素。
.
① 在路徑的\後緊跟或者單獨出現時：
一個.表示當前目錄。
兩個.表示上一級目錄。
② 在路徑中的文件名中出現時：
最後的一個.表示主文件名與擴展文件名的分隔。
?
① 在findstr/r中表示在此位置匹配一個任意字符。
② 在路徑中表示在此位置通配任意一個字符。
③ 緊跟在/後表示獲取命令的幫助文檔。
二、多符號(符號不能分隔)
&&
① 連接兩個命令，當&&前的命令成功時，才執行&&後的命令。
||
① 連接兩個命令，當||前的命令失敗時，才執行||後的命令。
>&
① 將一個句柄的輸出寫入到另一個句柄的輸入中。
<&
① 從一個句柄讀取輸入並將其寫入到另一個句柄輸出中。
%%
① 兩個連續的%表示在預處理中脫爲一個%。
② 批處理中，在for語句的in子句之前，連續兩個%緊跟一個字符（可以是字母、數字和一些特定字符），表示指定一個循
環或者遍歷指標變量。
③ 批處理中，在for語句中，使用與in之前指定的指標變量相同的串，表示引用這個指標變量。
>>
① 命令重定向符，將其前面的命令的輸出結果追加到其後面的設備中去。
② 在set /a中的二元運算符，表示邏輯右移。
==
① 在if命令中判斷==兩邊的元素是否相同。
<<
① 在set /a中的二元運算符，表示邏輯左移。
+=
① 在set /a中的二元運算符。例如set /a a+=b表示將a加上b的結果賦值給a。
-=
① 在set /a中的二元運算符。例如set /a a-=b表示將a減去b的結果賦值給a。
*=
① 在set /a中的二元運算符。例如set /a a*=b表示將a乘以b的結果賦值給a。
/=
① 在set /a中的二元運算符。例如set /a a/=b表示將a加上b的結果賦值給a。
%=
① 在set /a中的二元運算符。例如set /a a%=b表示將a除以b的餘數賦值給a。
【注：命令行可以直接用 set /a a%=b ，在批處理裏面可以用 set /a a%%=b 。】
^=
① 在set /a中的二元運算符。例如set /a a"^="b表示將a與b按位異的結果賦值給a。
【注：這裏 "^=" 加引號是爲了防止^被轉義，下同。】
&=
① 在set /a中的二元運算符。例如set /a a"&="b表示將a與b按位與的結果賦值給a。
|=
① 在set /a中的二元運算符。例如set /a a"|="b表示將a與b按位或的結果賦值給a。
<<=
① 在set /a中的二元運算符。例如set /a a"<<="b表示將a按位左移b位的結果賦值給a。
>>=
① 在set /a中的二元運算符。例如set /a a">>="b表示將a按位右移b位的結果賦值給a。
\<
① 在findstr的一般表達式中表示字的開始處。
\>
① 在findstr的一般表達式中表示字的結束處。
三、雙符號對(兩個符號之間須指定字符串)
! !
① 當啓用變量延遲時，使用!!將變量名擴起來表示對變量值的引用。
' '
① 在for/f中表示將它們包含的內容當作命令行執行並分析其輸出。
② 在for/f "usebackq"中表示將它們包含的字符串當作字符串分析。
( )
① 命令包含或者是具有優先權的界定符，比如for命令要用到這個()，我們還可以在if，echo等命令中見到它的身影。
② 在set /a中表示表達式分組。
" "
① 界定符，在表示帶有空格的路徑時常要用""來將路徑括起來，在一些命令裏面也需要" "符號。
② 在for/f中將表示它們包含的內容當作字符串分析。
③ 在for/f "usebackq"表示它們包含的內容當作文件路徑並分析其文件的內容。
④ 在其它情況下表示其中的內容是一個完整的字符串，其中的>、>>、<、&、|、空格等不再轉義。
` `
① 在for/f中表示它們所包含的內容當作命令行執行並分析它的輸出。
% %
① 使用兩個單獨的%包含一個字符串表示引用以此串爲名的環境變量。比如一個%time%可以擴展到當前的系統時間。
[ ]
① 在幫助文檔表示其中的開關、選項或參數是可選的。
② 在findstr /r中表示按其中指定的字符集匹配。
dos 批處理 字符處理
擴展名是bat(在nt/2000/xp/2003下也可以是cmd)的文件就是批處理文件。
==== 注 =======================================
.bat是dos下的批處理文件
.cmd是nt內核命令行環境的另一種批處理文件
從更廣義的角度來看，unix的shell腳本以及其它操作系統甚至應用程序中由外殼進行解釋執行的文本，都具有與批處理文件十分相似的作用，而且同樣是由專用解釋器以行爲單位解釋執行，這種文本形式更通用的稱謂是腳本語言。所以從某個程度分析，batch, unix shell, awk, basic, perl 等腳本語言都是一樣的，只不過應用的範圍和解釋的平臺各有不同而已。甚至有些應用程序仍然沿用批處理這一稱呼，而其內容和擴展名與dos的批處理卻又完全不同。
===================================
首先批處理文件是一個文本文件，這個文件的每一行都是一條DOS命令（大部分時候就好象我們在DOS提示符下執行的命令行一樣），你可以使用DOS下的Edit或者Windows的記事本(notepad)等任何文本文件編輯工具創建和修改批處理文件。
==== 注 ===================
批處理文件中完全可以使用非dos命令，甚至可以使用不具有可執行特性的普通數據性文件，這緣於windows系統這個新型解釋平臺的涉入，使得批處理的應用越來越"邊緣化"。所以我們討論的批處理應該限定在dos環境或者命令行環境中，否則很多觀念和設定都需要做比較大的變動。
========================
其次，批處理文件是一種簡單的程序，可以通過條件語句(if)和流程控制語句(goto)來控制命令運行的流程，在批處理中也可以使用循環語句(for)來循環執行一條命令。當然，批處理文件的編程能力與C語言等編程語句比起來是十分有限的，也是十分不規範的。批處理的程序語句就是一條條的DOS命令（包括內部命令和外部命令），而批處理的能力主要取決於你所使用的命令。
==== 注 ==================
批處理文件(batch file)也可以稱之爲批處理程序(batch program)，這一點與編譯型語言有所不同，就c語言來說，擴展名爲c或者cpp的文件可以稱之爲c語言文件或者c語言源代碼，但只有編譯連接後的 exe文件纔可以稱之爲c語言程序。因爲批處理文件本身既具有文本的可讀性，又具有程序的可執行性，這些稱謂的界限是比較模糊的。
===========================
第三，每個編寫好的批處理文件都相當於一個DOS的外部命令，你可以把它所在的目錄放到你的DOS搜索路徑(path)中來使得它可以在任意位置運行。一個良好的習慣是在硬盤上建立一個bat或者batch目錄（例如C:BATCH），然後將所有你編寫的批處理文件放到該目錄中，這樣只要在path中設置上 c:atch，你就可以在任意位置運行所有你編寫的批處理程序。
==== 注 =====
純以dos系統而言，可執行程序大約可以細分爲五類，依照執行優先級由高到低排列分別是：DOSKEY宏命令（預先駐留內存），COMMAND.COM中的內部命令（根據內存的環境隨時進駐內存），以com爲擴展名的可執行程序（由command.com 直接載入內存），以exe位擴展名的可執行程序（由command.com 重定位後載入內存），以bat位擴展名的批處理程序（由command.com 解釋分析，根據其內容按優先級順序調用第2，3，4，5種可執行程序，分析一行，執行一行，文件本身不載入內存）
============
第四，在DOS和Win9x/Me系統下，C:盤根目錄下的AUTOEXEC.BAT批處理文件是自動運行批處理文件，每次系統啓動時會自動運行該文件，你可以將系統每次啓動時都要運行的命令放入該文件中，例如設置搜索路徑，調入鼠標驅動和磁盤緩存，設置系統環境變量等。下面是一個運行於Windows 98下的autoexec.bat的示例：
@ECHO OFF
PATH C:WINDOWS;C:WINDOWSCOMMAND;C:UCDOS;C:DOSTools;
C:SYSTOOLS;C:WINTOOLS;C:BATCH
LH SMARTDRV.EXE /X
LH DOSKEY.COM /insert
LH CTMOUSE.EXE
SET TEMP=D:TEMP
SET TMP=D:TEMP
==== 注 =====
AUTOEXEC.BAT爲DOS系統的自動運行批處理文件，由COMMAND.COM啓動時解釋執行；
而在Win9x環境中，不僅增加支持了 DOSSTART.BAT, WINSTART.BAT 等許多其它自動運行的批處理文件，對AUTOEXEC.BAT 也增加了 .DOS .W40 .BAK .OLD .PWS 等許多變體以適應複雜的環境和多變的需求。
==== willsort 編注 =============
以下關於命令的分類，有很多值得推敲的地方。常用命令中的@本不是命令，而dir、copy等也很常用的命令卻沒有列入, 而特殊命令中所有命令對我來說都是常用命令。建議將批處理所引用的命令分爲內部命令、外部命令、第三方程序三類。而內部命令和外部命令中別有一類是專用於或常用於批處理中的命令可稱之爲"批處理命令"。
以下摘錄MS-DOS 6.22 幫助文檔中關於"批處理命令"的文字，當然，其中有些概念和定義已經有些落後了。
批處理命令
批處理文件或批處理程序是一個包含若干MS-DOS命令的正文文件，擴展名爲.BAT。當在命令提示符下敲入批處理程序的名稱時，MS-DOS成組執行此批處理程序中的命令。
任何在命令提示符下可使用的命令都可用在批處理程序中。此外，下面MS-DOS命令是專門在批處理程序中使用的。
==========
常用命令
echo、@、call、pause、rem(小技巧：用::代替rem)是批處理文件最常用的幾個命令，我們就從他們開始學起。
==== 注 ===========
首先, @ 不是一個命令, 而是DOS 批處理的一個特殊標記符, 僅用於屏蔽命令行回顯. 下面是DOS命令行或批處理中可能會見到的一些特殊標記符:
CR(0D) 命令行結束符
Escape(1B) ANSI轉義字符引導符
Space(20) 常用的參數界定符
Tab(09) ; = 不常用的參數界定符
+ COPY命令文件連接符
* ? 文件通配符
"" 字符串界定符
| 命令管道符
< > >> 文件重定向符
@ 命令行回顯屏蔽符
/ 參數開關引導符
: 批處理標籤引導符
% 批處理變量引導符
其次, :: 確實可以起到rem 的註釋作用, 而且更簡潔有效; 但有兩點需要注意:
第一, 除了 :: 之外, 任何以 :開頭的字符行, 在批處理中都被視作標號, 而直接忽略其後的所有內容, 只是爲了與正常的標號相區別, 建議使用 goto 所無法識別的標號, 即在 :後緊跟一個非字母數字的一個特殊符號.
第二, 與rem 不同的是, ::後的字符行在執行時不會回顯, 無論是否用echo on打開命令行回顯狀態, 因爲命令解釋器不認爲他是一個有效的命令行, 就此點來看, rem 在某些場合下將比 :: 更爲適用; 另外, rem 可以用於 config.sys 文件中.
=====================
echo 表示顯示此命令後的字符
echo off 表示在此語句後所有運行的命令都不顯示命令行本身
@與echo off相象，但它是加在每個命令行的最前面，表示運行時不顯示這一行的命令行（只能影響當前行）。
call 調用另一個批處理文件（如果不用call而直接調用別的批處理文件，那麼執行完那個批處理文件後將無法返回當前文件並執行當前文件的後續命令）。
pause 運行此句會暫停批處理的執行並在屏幕上顯示Press any key to continue...的提示，等待用戶按任意鍵後繼續
rem 表示此命令後的字符爲解釋行（註釋），不執行，只是給自己今後參考用的（相當於程序中的註釋）。
==== 注 =====
此處的描述較爲混亂, 不如直接引用個命令的命令行幫助更爲條理
-------------------------
ECHO
當程序運行時，顯示或隱藏批處理程序中的正文。也可用於允許或禁止命令的回顯。
在運行批處理程序時，MS-DOS一般在屏幕上顯示（回顯）批處理程序中的命令。
使用ECHO命令可關閉此功能。
語法
ECHO [ON|OFF]
若要用echo命令顯示一條命令，可用下述語法：
echo [message]
參數
ON|OFF
指定是否允許命令的回顯。若要顯示當前的ECHO的設置，可使用不帶參數的ECHO
命令。
message
指定讓MS-DOS在屏幕上顯示的正文。
-------------------
CALL
從一個批處理程序中調用另一個批處理程序，而不會引起第一個批處理的中止。
語法
CALL [drive:][path]filename [batch-parameters]
參數
[drive:][path]filename
指定要調用的批處理程序的名字及其存放處。文件名必須用.BAT作擴展名。
batch-parameters
指定批處理程序所需的命令行信息。
-------------------------------
PAUSE
暫停批處理程序的執行並顯示一條消息，提示用戶按任意鍵繼續執行。只能在批處
理程序中使用該命令。
語法
PAUSE
REM
在批處理文件或CONFIG.SYS中加入註解。也可用REM命令來屏蔽命令（在CONFIG.SYS
中也可以用分號 ; 代替REM命令，但在批處理文件中則不能替代）。
語法
REM [string]
參數
string
指定要屏蔽的命令或要包含的註解。
=======================
例1：用edit編輯a.bat文件，輸入下列內容後存盤爲c:a.bat，執行該批處理文件後可實現：將根目錄中所有文件寫入 a.txt中，啓動UCDOS，進入WPS等功能。
批處理文件的內容爲: 命令註釋：
@echo off 不顯示後續命令行及當前命令行
dir c:*.* >a.txt 將c盤文件列表寫入a.txt
call c:ucdosucdos.bat 調用ucdos
echo 你好 顯示"你好"
pause 暫停,等待按鍵繼續
rem 準備運行wps 註釋：準備運行wps
cd ucdos 進入ucdos目錄
wps 運行wps
批處理文件的參數
批處理文件還可以像C語言的函數一樣使用參數（相當於DOS命令的命令行參數），這需要用到一個參數表示符"%"。
%[1-9]表示參數，參數是指在運行批處理文件時在文件名後加的以空格（或者Tab）分隔的字符串。變量可以從%0到%9，%0表示批處理命令本身，其它參數字符串用%1到%9順序表示。
例2：C:根目錄下有一批處理文件名爲f.bat，內容爲：
@echo off
format %1
如果執行C:>f a:
那麼在執行f.bat時，%1就表示a:，這樣format %1就相當於format a:，於是上面的命令運行時實際執行的是format a:
例3：C:根目錄下一批處理文件名爲t.bat，內容爲:
@echo off
type %1
type %2
那麼運行C:>t a.txt b.txt
%1 : 表示a.txt
%2 : 表示b.txt
於是上面的命令將順序地顯示a.txt和b.txt文件的內容。
==== 注 ===============
參數在批處理中也作爲變量處理, 所以同樣使用百分號作爲引導符, 其後跟0-9中的一個數字構成參數引用符. 引用符和參數之間 (例如上文中的 %1 與 a: ) 的關係類似於變量指針與變量值的關係. 當我們要引用第十一個或更多個參數時, 就必須移動DOS 的參數起始指針. shift 命令正充當了這個移動指針的角色, 它將參數的起始指針移動到下一個參數, 類似C 語言中的指針操作. 圖示如下:
初始狀態, cmd 爲命令名, 可以用 %0 引用
cmd arg1 arg2 arg3 arg4 arg5 arg6 arg7 arg8 arg9 arg10
^ ^ ^ ^ ^ ^ ^ ^ ^ ^
| | | | | | | | | |
%0 %1 %2 %3 %4 %5 %6 %7 %8 %9
經過1次shift後, cmd 將無法被引用
cmd arg1 arg2 arg3 arg4 arg5 arg6 arg7 arg8 arg9 arg10
^ ^ ^ ^ ^ ^ ^ ^ ^ ^
| | | | | | | | | |
%0 %1 %2 %3 %4 %5 %6 %7 %8 %9
經過2次shift後, arg1也被廢棄, %9指向爲空, 沒有引用意義
cmd arg1 arg2 arg3 arg4 arg5 arg6 arg7 arg8 arg9 arg10
^ ^ ^ ^ ^ ^ ^ ^ ^
| | | | | | | | |
%0 %1 %2 %3 %4 %5 %6 %7 %8
遺憾的是, win9x 和DOS下均不支持 shift 的逆操作. 只有在 nt 內核命令行環境下, shift 才支持 /n 參數, 可以以第一參數爲基準返復移動起始指針.
=================
特殊命令
if goto choice for是批處理文件中比較高級的命令，如果這幾個你用得很熟練，你就是批處理文件的專家啦。
一、if 是條件語句，用來判斷是否符合規定的條件，從而決定執行不同的命令。 有三種格式:
1、if [not] "參數" == "字符串" 待執行的命令
參數如果等於(not表示不等，下同)指定的字符串，則條件成立，運行命令，否則運行下一句。
例：if "%1"=="a" format a:
====
if 的命令行幫助中關於此點的描述爲:
IF [NOT] string1==string2 command
在此有以下幾點需要注意:
1. 包含字符串的雙引號不是語法所必須的, 而只是習慣上使用的一種"防空"字符
2. string1 未必是參數, 它也可以是環境變量, 循環變量以及其他字符串常量或變量
3. command 不是語法所必須的, string2 後跟一個空格就可以構成一個有效的命令行
=============================
2、if [not] exist [路徑]文件名 待執行的命令
如果有指定的文件，則條件成立，運行命令，否則運行下一句。
如: if exist c:config.sys type c:config.sys
表示如果存在c:config.sys文件，則顯示它的內容。
****** 注 ********
也可以使用以下的用法:
if exist command
device 是指DOS系統中已加載的設備, 在win98下通常有:
AUX, PRN, CON, NUL
COM1, COM2, COM3, COM4
LPT1, LPT2, LPT3, LPT4
XMSXXXX0, EMMXXXX0
A: B: C: ...,
CLOCK$, CONFIG$, DblBuff$, IFS$HLP$
具體的內容會因硬軟件環境的不同而略有差異, 使用這些設備名稱時, 需要保證以下三點:
1. 該設備確實存在(由軟件虛擬的設備除外)
2. 該設備驅動程序已加載(aux, prn等標準設備由系統缺省定義)
3. 該設備已準備好(主要是指a: b: ..., com1..., lpt1...等)
可通過命令 mem/d | find "device" /i 來檢閱你的系統中所加載的設備
另外, 在DOS系統中, 設備也被認爲是一種特殊的文件, 而文件也可以稱作字符設備; 因爲設備(device)與文件都是使用句柄(handle)來管理的, 句柄就是名字, 類似於文件名, 只不過句柄不是應用於磁盤管理, 而是應用於內存管理而已, 所謂設備加載也即指在內存中爲其分配可引用的句柄.
==================================
3、if errorlevel <數字> 待執行的命令
很多DOS程序在運行結束後會返回一個數字值用來表示程序運行的結果(或者狀態)，通過if errorlevel命令可以判斷程序的返回值，根據不同的返回值來決定執行不同的命令(返回值必須按照從大到小的順序排列)。如果返回值等於指定的數字，則條件成立，運行命令，否則運行下一句。
如if errorlevel 2 goto x2
==== 注 ===========
返回值從大到小的順序排列不是必須的, 而只是執行命令爲 goto 時的習慣用法, 當使用 set 作爲執行命令時, 通常會從小到大順序排列, 比如需將返回碼置入環境變量, 就需使用以下的順序形式:
if errorlevel 1 set el=1
if errorlevel 2 set el=2
if errorlevel 3 set el=3
if errorlevel 4 set el=4
if errorlevel 5 set el=5
...
當然, 也可以使用以下循環來替代, 原理是一致的:
for %%e in (1 2 3 4 5 6 7 8...) do if errorlevel %%e set el=%%e
更高效簡潔的用法, 可以參考我寫的另一篇關於獲取 errorlevel 的文章
出現此種現象的原因是, if errorlevel 比較返回碼的判斷條件並非等於, 而是大於等於. 由於 goto 的跳轉特性, 由小到大排序會導致在較小的返回碼處就跳出; 而由於 set命令的 "重複" 賦值特性, 由大到小排序會導致較小的返回碼 "覆蓋" 較大的返回碼.
另外, 雖然 if errorlevel=<數字> command 也是有效的命令行, 但也只是 command.com 解釋命令行時將 = 作爲命令行切分符而忽略掉罷了
===========================
二、goto 批處理文件運行到這裏將跳到goto所指定的標號(標號即label，標號用:後跟標準字符串來定義)處，goto語句一般與if配合使用，根據不同的條件來執行不同的命令組。
如:
goto end
:end
echo this is the end
標號用":字符串"來定義，標號所在行不被執行。
==== willsort 編注
label 常被譯爲 "標籤" , 但是這並不具有廣泛的約定性.
goto 與 : 聯用可實現執行中途的跳轉, 再結合 if 可實現執行過程的條件分支, 多個 if 即可實現命令的分組, 類似 C 中 switch case 結構或者 Basic 中的 select case 結構, 大規模且結構化的命令分組即可實現高級語言中的函數功能. 以下是批處理和C/Basic在語法結構上的對照:
Batch C / Basic
goto&: goto&:
goto&:&if if{}&else{} / if&elseif&endif
goto&:&if... switch&case / select case
goto&:&if&set&envar... function() / function(),sub()
==================================
三、choice 使用此命令可以讓用戶輸入一個字符（用於選擇），從而根據用戶的選擇返回不同的errorlevel，然後於if errorlevel配合，根據用戶的選擇運行不同的命令。
注意：choice命令爲DOS或者Windows系統提供的外部命令，不同版本的choice命令語法會稍有不同，請用choice /?查看用法。
choice的命令語法（該語法爲Windows 2003中choice命令的語法，其它版本的choice的命令語法與此大同小異）：
CHOICE [/C choices] [/N] [/CS] [/T timeout /D choice] [/M text]
描述:
該工具允許用戶從選擇列表選擇一個項目並返回所選項目的索引。
參數列表:
/C choices 指定要創建的選項列表。默認列表是 "YN"。
/N 在提示符中隱藏選項列表。提示前面的消息得到顯示，
選項依舊處於啓用狀態。
/CS 允許選擇分大小寫的選項。在默認情況下，這個工具
是不分大小寫的。
/T timeout 做出默認選擇之前，暫停的秒數。可接受的值是從 0
到 9999。如果指定了 0，就不會有暫停，默認選項
會得到選擇。
/D choice 在 nnnn 秒之後指定默認選項。字符必須在用 /C 選
項指定的一組選擇中; 同時，必須用 /T 指定 nnnn。
/M text 指定提示之前要顯示的消息。如果沒有指定，工具只
顯示提示。
/? 顯示幫助消息。
注意:
ERRORLEVEL 環境變量被設置爲從選擇集選擇的鍵索引。列出的第一個選
擇返回 1，第二個選擇返回 2，等等。如果用戶按的鍵不是有效的選擇，
該工具會發出警告響聲。如果該工具檢測到錯誤狀態，它會返回 255 的
ERRORLEVEL 值。如果用戶按 Ctrl+Break 或 Ctrl+C 鍵，該工具會返回 0
的 ERRORLEVEL 值。在一個批程序中使用 ERRORLEVEL 參數時，將參數降
序排列。
示例:
CHOICE /?
CHOICE /C YNC /M "確認請按 Y，否請按 N，或者取消請按 C。"
CHOICE /T 10 /C ync /CS /D y
CHOICE /C ab /M "選項 1 請選擇 a，選項 2 請選擇 b。"
CHOICE /C ab /N /M "選項 1 請選擇 a，選項 2 請選擇 b。"
==== willsort 編注 ===============================
我列出win98下choice的用法幫助, 已資區分
Waits for the user to choose one of a set of choices.
等待用戶選擇一組待選字符中的一個
CHOICE [/C[:]choices] [/N] [/S] [/T[:]c,nn] [text]
/C[:]choices Specifies allowable keys. Default is YN
指定允許的按鍵(待選字符), 默認爲YN
/N Do not display choices and ? at end of prompt string.
不顯示提示字符串中的問號和待選字符
/S Treat choice keys as case sensitive.
處理待選字符時大小寫敏感
/T[:]c,nn Default choice to c after nn seconds
在 nn 秒後默認選擇 c
text Prompt string to display
要顯示的提示字符串
ERRORLEVEL is set to offset of key user presses in choices.
ERRORLEVEL 被設置爲用戶鍵入的字符在待選字符中的偏移值
如果我運行命令：CHOICE /C YNC /M "確認請按 Y，否請按 N，或者取消請按 C。"
屏幕上會顯示：
確認請按 Y，否請按 N，或者取消請按 C。 [Y,N,C]?
例：test.bat的內容如下（注意，用if errorlevel判斷返回值時，要按返回值從高到低排列）:
@echo off
choice /C dme /M "defrag,mem,end"
if errorlevel 3 goto end
if errorlevel 2 goto mem
if errorlevel 1 goto defrag
:defrag
c:dosdefrag
goto end
:mem
mem
goto end
:end
echo good bye
此批處理運行後，將顯示"defrag,mem,end[D,M,E]?" ，用戶可選擇d m e ，然後if語句根據用戶的選擇作出判斷，d表示執行標號爲defrag的程序段，m表示執行標號爲mem的程序段，e表示執行標號爲end的程序段，每個程序段最後都以goto end將程序跳到end標號處，然後程序將顯示good bye，批處理運行結束。
四、for 循環命令，只要條件符合，它將多次執行同一命令。
語法：
對一組文件中的每一個文件執行某個特定命令。
FOR %%variable IN (set) DO command [command-parameters]
%%variable 指定一個單一字母可替換的參數。
(set) 指定一個或一組文件。可以使用通配符。
command 指定對每個文件執行的命令。
command-parameters
爲特定命令指定參數或命令行開關。
例如一個批處理文件中有一行:
for %%c in (*.bat *.txt) do type %%c
則該命令行會顯示當前目錄下所有以bat和txt爲擴展名的文件的內容。
==== willsort 編注 =====================================================
需要指出的是, 當()中的字符串並非單個或多個文件名時, 它將單純被當作字符串替換, 這個特性再加上()中可以嵌入多個字符串的特性, 很明顯 for 可以被看作一種遍歷型循環.
當然, 在 nt/2000/xp/2003 系列的命令行環境中, for 被賦予了更多的特性, 使之可以分析命令輸出或者文件中的字符串, 也有很多開關被用於擴展了文件替換功能.
========================================================================
批處理示例
1. IF-EXIST
1) 首先用記事本在C:建立一個test1.bat批處理文件，文件內容如下：
@echo off
IF EXIST AUTOEXEC.BAT TYPE AUTOEXEC.BAT
IF NOT EXIST AUTOEXEC.BAT ECHO AUTOEXEC.BAT does not exist
然後運行它：
C:>TEST1.BAT
如果C:存在AUTOEXEC.BAT文件，那麼它的內容就會被顯示出來，如果不存在，批處理就會提示你該文件不存在。
2) 接着再建立一個test2.bat文件，內容如下：
@ECHO OFF
IF EXIST \%1 TYPE \%1
IF NOT EXIST \%1 ECHO \%1 does not exist
執行:
C:>TEST2 AUTOEXEC.BAT
該命令運行結果同上。
說明：
(1) IF EXIST 是用來測試文件是否存在的，格式爲
IF EXIST [路徑+文件名] 命令
(2) test2.bat文件中的%1是參數，DOS允許傳遞9個批參數信息給批處理文件，分別爲%1~%9(%0表示test2命令本身) ，這有點象編程中的實參和形參的關係，%1是形參，AUTOEXEC.BAT是實參。
==== willsort 編注 =====================================================
DOS沒有 "允許傳遞9個批參數信息" 的限制, 參數的個數只會受到命令行長度和所調用命令處理能力的限制. 但是, 我們在批處理程序中, 在同一時刻只能同時引用10個參數, 因爲 DOS只給出了 %0~%9這十個參數引用符.
========================================================================
3) 更進一步的，建立一個名爲TEST3.BAT的文件，內容如下：
@echo off
IF "%1" == "A" ECHO XIAO
IF "%2" == "B" ECHO TIAN
IF "%3" == "C" ECHO XIN
如果運行：
C:>TEST3 A B C
屏幕上會顯示:
XIAO
TIAN
XIN
如果運行：
C:>TEST3 A B
屏幕上會顯示
XIAO
TIAN
在這個命令執行過程中，DOS會將一個空字符串指定給參數%3。
2、IF-ERRORLEVEL
建立TEST4.BAT，內容如下：
@ECHO OFF
XCOPY C:AUTOEXEC.BAT D:
IF ERRORLEVEL 1 ECHO 文件拷貝失敗
IF ERRORLEVEL 0 ECHO 成功拷貝文件
然後執行文件:
C:>TEST4
如果文件拷貝成功，屏幕就會顯示"成功拷貝文件"，否則就會顯示"文件拷貝失敗"。
IF ERRORLEVEL 是用來測試它的上一個DOS命令的返回值的，注意只是上一個命令的返回值，而且返回值必須依照從大到小次序順序判斷。
因此下面的批處理文件是錯誤的：
@ECHO OFF
XCOPY C:AUTOEXEC.BAT D:
IF ERRORLEVEL 0 ECHO 成功拷貝文件
IF ERRORLEVEL 1 ECHO 未找到拷貝文件
IF ERRORLEVEL 2 ECHO 用戶通過ctrl-c中止拷貝操作
IF ERRORLEVEL 3 ECHO 預置錯誤阻止文件拷貝操作
IF ERRORLEVEL 4 ECHO 拷貝過程中寫盤錯誤
無論拷貝是否成功，後面的：
未找到拷貝文件
用戶通過ctrl-c中止拷貝操作
預置錯誤阻止文件拷貝操作
拷貝過程中寫盤錯誤
都將顯示出來。
以下就是幾個常用命令的返回值及其代表的意義：
backup
0 備份成功
1 未找到備份文件
2 文件共享衝突阻止備份完成
3 用戶用ctrl-c中止備份
4 由於致命的錯誤使備份操作中止
diskcomp
0 盤比較相同
1 盤比較不同
2 用戶通過ctrl-c中止比較操作
3 由於致命的錯誤使比較操作中止
4 預置錯誤中止比較
diskcopy
0 盤拷貝操作成功
1 非致命盤讀/寫錯
2 用戶通過ctrl-c結束拷貝操作
3 因致命的處理錯誤使盤拷貝中止
4 預置錯誤阻止拷貝操作
format
0 格式化成功
3 用戶通過ctrl-c中止格式化處理
4 因致命的處理錯誤使格式化中止
5 在提示"proceed with format（y/n）?"下用戶鍵入n結束
xcopy
0 成功拷貝文件
1 未找到拷貝文件
2 用戶通過ctrl-c中止拷貝操作
4 預置錯誤阻止文件拷貝操作
5 拷貝過程中寫盤錯誤
chkdsk
0 未找到錯誤
255 找到一個或多個錯誤
choice
0 用戶按下ctrl+c/break
1 用戶按下第一個鍵
255 檢測到命令行中的錯誤條件
其它 用戶按下的有效字符在列表中的位置
defrag
0 碎片壓縮成功
1 出現內部錯誤
2 磁盤上沒有空簇。要運行DEFRAG，至少要有一個空簇
3 用戶用Ctrl+C退出了DEFRAG
4 出現一般性錯誤
5 DEFRAG在讀簇時遇到錯誤
6 DEFRAG在寫簇時遇到錯誤
7 分配空間有錯
8 內存錯
9 沒有足夠空間來壓縮磁盤碎片
deltree
0 成功地刪除一個目錄
diskcomp
0 兩盤相同
1 發現不同
2 按CTRL+C 終止了比較
3 出現嚴重錯誤
4 出現初始化錯誤
find
0 查找成功且至少找到了一個匹配的字符串
1 查找成功但沒找到匹配的字符串
2 查找中出現了錯誤
keyb
0 鍵盤定義文件裝入成功
1 使用了非法的鍵盤代碼，字符集或語法
2 鍵盤定義文件壞或未找到
4 鍵盤、監視器通訊時出錯
5 要求的字符集未準備好
move
0 成功地移動了指定的文件
1 發生了錯誤
msav /N
86 檢查到了病毒
replace
0 REPLACE成功地替換或加入了文件
1 MS-DOS版本和REPLACE不兼容
2 REPLACE找不到源文件
3 REPLACE找不到源路徑或目標路徑
5 不能存取要替換的文件
8 內存不夠無法執行REPLACE
11 命令行句法錯誤
restore
0 RESTORE成功地恢復了文件
1 RESTORE找不到要恢復的文件
3 用戶按CTRL+C終止恢復過程
4 RESTORE因錯誤而終止
scandisk
0 ScanDisk在它檢查的驅動器上未檢測到任何錯誤
1 由於命令行的語法不對，不能運行ScanDisk
2 由於內存用盡或發生內部錯誤，ScanDisk意外終止
3 用戶讓ScanDisk中途退出
4 進行盤面掃描時，用戶決定提前退出
254 ScanDisk找到磁盤故障並已全部校正
255 ScanDisk找到磁盤故障，但未能全部校正
setver
0 SETVER成功地完成了任務
1 用戶指定了一個無效的命令開關
2 用戶指定了一個非法的文件名
3 沒有足夠的系統內存來運行命令
4 用戶指定了一個非法的版本號格式
5 SETVER在版本表中未找到指定的項
6 SETVER未找到SETVER.EXE文件
7 用戶指定了一個非法的驅動器
8 用戶指定了太多的命令行參數
9 SETVER檢測到丟失了命令行參數
10 在讀SETVER.EXE文件時，SETVER檢測到發生錯誤
11 SETVER.EXE文件損壞
12 指定的SETVER.EXE文件不支持版本表
13 版本表中沒有足夠的空間存放新的項
14 在寫SETVER.EXE文件時SETVER檢測到發生錯誤
========================================================================
3、IF STRING1 == STRING2
建立TEST5.BAT，文件內容如下：
@echo off
IF "%1" == "A" FORMAT A:
執行：
C:>TEST5 A
屏幕上就出現是否將A:盤格式化的內容。
注意：爲了防止參數爲空的情況，一般會將字符串用雙引號（或者其它符號，注意不能使用保留符號）括起來。
如：if [%1]==[A] 或者 if %1*==A*
5、GOTO
建立TEST6.BAT，文件內容如下：
@ECHO OFF
IF EXIST C:AUTOEXEC.BAT GOTO _COPY
GOTO _DONE
:_COPY
COPY C:AUTOEXEC.BAT D:
:_DONE
注意：
(1) 標號前是ASCII字符的冒號":"，冒號與標號之間不能有空格。
(2) 標號的命名規則與文件名的命名規則相同。
(3) DOS支持最長八位字符的標號，當無法區別兩個標號時，將跳轉至最近的一個標號。
==== willsort 編注 =====================================================
1)標號也稱作標籤(label)
2)標籤不能以大多數的非字母數字字符開始, 而文件名中則可以使用很多
3)當無法區別兩個標籤時, 將跳轉至位置最靠前的標籤
========================================================================
6、FOR
建立C:TEST7.BAT，文件內容如下：
@ECHO OFF
FOR %%C IN (*.BAT *.TXT *.SYS) DO TYPE %%C
運行：
C:>TEST7
執行以後，屏幕上會將C:盤根目錄下所有以BAT、TXT、SYS爲擴展名的文件內容顯示出來（不包括隱藏文件）。
-
爲了說明截取變量中字符串的問題曾經舉過如下這個例子:
@echo off
set str=123456789
echo 第一個字符爲：%str:~0,1%
echo 頭兩個字符爲：%str:~0,2%
echo 頭5個字符爲：%str:~0,5%
echo 去掉最後一個字符後的字符串爲：%str:~0,-1%
echo 去掉最後3個字符後的字符串爲：%str:~0,-3%
echo 第4個字符爲：%str:~3,1%
echo 第4個及其之後的3個字符爲：%str:~3,4%
echo 最後一個字符爲：%str:~-1%
echo 最後一個字符爲：%str:~-1,1%
echo 最後一個字符爲：%str:~-1,2%
echo 倒數第4個字符爲：%str:~-4,1%
echo 倒數第4個及其之後的字符爲：%str:~-4%
echo 倒數第4個及其之後的1個字符爲：%str:~-4,2%
echo 倒數第4個及其之後的2個字符爲：%str:~-4,3%
pause
爲了說明這個問題,我在這裏把批處理取字符,做下進一步的解釋,希望對新手有所啓發
如下:
echo %var:~n,k%
我們在這裏對每個參數做個說明:"%var",即我們要從中要截取字符的字符串." ~ "取字
符標誌符(我是這麼理解的),"n" 我們將其理解爲指針,"k"我們將其理解爲偏移地址.(注
:指針和偏移地址都是從零開始數的)
我們還是用namejm版主的例子做下說明:
@echo off
set str=123456789
rem 定義一個str字符串爲123456789
echo 第一個字符爲：%str:~0,1%
rem 指針爲0,偏移地址爲1,即從第0位開始,取1位
echo 頭兩個字符爲：%str:~0,2%
rem 指針爲0,偏移地址爲2,即從第0位開始,取2位
echo 頭5個字符爲：%str:~0,5%
rem 指針爲0,偏移地址爲5,即從第0位開始,取5位
echo 去掉最後一個字符後的字符串爲：%str:~0,-1%
rem 當"k"爲負值時,我們可以這樣理解:從指針開始處開始取其後面所有字符,然後減去
後面"abs(k)位"..所以這個句字我們可以做如下解釋:從第0位開始取其全部字符
爲:123456789然後從後面減去abs(k)位,所以最後結果爲:12345678
echo 去掉最後3個字符後的字符串爲：%str:~0,-3%
rem 該句解釋同上↑
echo 最後一個字符爲：%str:~-1%
rem 參數"n,"和"k"都可以爲缺省,缺省"n,"時可以理解爲:從abs(k)位開始取其全部
echo 倒數第4個及其之後的字符爲：%str:~-4%
rem 解釋同上↑
echo 最後一個字符爲：%str:~-1,1%
rem n爲負值時,表示從後面開始截取字符,取k位(此時n應從1開始數)
echo 最後一個字符爲：%str:~-1,2%
rem 解釋同上↑
echo 倒數第4個字符爲：%str:~-4,1%
rem 解釋同上↑
echo 倒數第4個及其之後的1個字符爲：%str:~-4,2%
rem 解釋同上↑
echo 倒數第4個及其之後的2個字符爲：%str:~-4,3%
rem 解釋同上↑
pause
