Windows 下 自動 設置IP 的 批處理腳本

從網上找到的，自己又修改了下，可以設置靜態IP 或動態IP。

@echo off

set name="無線網絡連接"

::請根據您的參數修改以下數據

::設置 IP地址
set ipaddress=18.1.16.169

::設置 子掩碼
set mask=255.255.252.0

::設置 網關
set gateway=18.1.19.254

::設置 首選DNS服務器
set dns1=18.0.0.1

::設置 備用DNS服務器
set dns2=61.177.7.1

::請根據您的參數修改以上數據

set /p type=請選擇設置方式，1: 靜態，2: 動態：
if /i %type%==1 goto :STATIC_IP
if /i %type%==2 goto :DHCP_IP

:STATIC_IP
echo 正在進行靜態IP設置，請稍等...

netsh interface ip set address name=%name% source=static addr=%ipaddress% mask=%mask%
echo. IP地址 = %ipaddress% .完成設置
echo. 子掩碼 = %mask% .完成設置

netsh interface ip set address name=%name% gateway=%gateway% gwmetric=1 >nul
echo. 網關 = %gateway% .完成設置

netsh interface ip set dns name=%name% source=static addr=%dns1% register=PRIMARY >nul
echo. 首選DNS = %dns1% .完成設置

netsh interface ip add dns name=%name% addr=%dns2% index=2 >nul
echo. 備用DNS = %dns2% .完成設置

goto :SETEND

:DHCP_IP
echo 正在進行動態IP設置，請稍等...

netsh interface ip set address name=%name% source=dhcp
netsh interface ip set dns name=%name% source=dhcp register=PRIMARY
netsh interface ip set wins name=%name% source=dhcp

goto :SETEND

:SETEND
echo. ===============IP設置完成================
echo. =========================================
echo. == 以下測試網絡是否正常
echo. == 若出現如下形式：
echo. == "Reply from %gateway%: bytes=32 time<1ms TTL=64"
echo. == 則網絡正常，否則網絡不正常！
echo. =========================================
ping %gateway% -n 1

pause