第 9 课：编写您自己的类

 

第 9 课：编写您自己的类

在几乎每个 JavaFX Script 应用程序中，您都需要编写一个或多个类。在某些情况下，您需要从头编写类；在其他情况下，您需要扩展现有类的行为。本课首先展示您以前看到过的 Customer 类的完整脚本。此外提供了一个抽象类 Account。随后，您将会看到如何扩展该类以创建 SavingsAccount 和 CheckingAccount 类。

 

目录

 

-	Customer 示例
-	从其他类继承

 

Customer 示例

在编写脚本中，您学习了如何使用对象。但是，请回想一下，我们首先要求您下载多个 .class 文件，这样编译器将知道如何创建 Address 和 Customer 对象。以下示例重新访问这些代码，此外添加了缺少的类定义以便对所有的内容进行编译。

def customer = Customer {
     firstName: "John";
     lastName: "Doe";
     phoneNum: "[phone]"
     address: Address {
          street: "1 Main Street";
          city: "Santa Clara";
          state: "CA";
          zip: "95050";
     }
}

customer.printName();
customer.printPhoneNum();
customer.printAddress();

class Address {
     var street: String;
     var city: String;
     var state: String;
     var zip: String;
}

class Customer {
     var firstName: String;
     var lastName: String;
     var phoneNum: String;
     var address: Address;

    function printName() {
        println("Name: {firstName} {lastName}");
    }

    function printPhoneNum(){
        println("Phone: {phoneNum}");
    }

    function printAddress(){
        println("Street: {address.street}");
        println("City: {address.city}");
        println("State: {address.state}");
        println("Zip: {address.zip}");
    }
}

 

由于您已经了解了变量和函数，因此应该对该示例比较熟悉。Address 类声明了 street、city、state 和 zip 实例变量，这些变量均为 String 类型；Customer 类也声明了几个实例变量以及用来输出这些变量的值的函数。由于这些变量和函数是在类中声明的，因此您创建的任何 Address 和 Customer 对象都可以使用它们。

从其他类继承

您还可以编写从其他类继承变量和函数的类。例如，设想您在银行有一个储蓄账户和一个支票账户。每个账户都有账号和余额。您可以查询余额、存款或取款。我们可以通过创建一个用来提供最常用的变量和函数的 Account 基类来对以上情况进行建模：

abstract class Account {

     var accountNum: Integer;
     var balance: Number;

     function getBalance(): Number {
          return balance;
     }

     function deposit(amount: Number): Void {
          balance += amount;
     }

     function withdraw(amount: Number): Void {
          balance -= amount;
     }
}

 

我们已经将该类标记为 abstract，这意味着不能直接创建 Account 对象（此设计的目的在于使您只能创建储蓄账户或支票账户）。

accountNum 和 balance 变量用来存放账号和当前余额。其余函数提供基本行为：获得余额、存款或取款。

然后，我们可以定义一个使用 extends 关键字来继承这些变量和函数的 SavingsAccount 类：

class SavingsAccount extends Account {

     var minBalance = 100.00;
     var penalty = 5.00;

     function checkMinBalance() : Void {
          if(balance < minBalance){
               balance -= penalty;
          }
     }
}

 

由于 SavingsAccount 是 Account 的子类，因此它将自动包含 Account 的所有实例变量和函数。这样就可以使 SavingsAccount 源代码将重点放在它与其父类之间的区别（要求储蓄账户所有者必须至少保持 100 美元的余额才能避免受罚）上。

类似地，我们可以定义一个也对 Account 进行扩展的 CheckingAccount 类：

class CheckingAccount extends Account {

     var hasOverDraftProtection: Boolean;

override function withdraw(amount: Number) : Void {
          if(balance-amount<0 and hasOverDraftProtection){

               // code to borrow money from an overdraft account would go here

          } else {
               balance -= amount; // may result in negative account balance!
          }
     }
}

 

该类与 Account 的区别在于，它定义了一个用来跟踪账户所有者是否有透支保护（如果取款（例如写支票）导致余额小于零，则透支保护将激活以确保支票不会被退回）的变量。请注意，在这种情况下，我们将更改所继承的 withdraw 函数的行为。这就是所谓的函数覆盖（由 override 关键字指示）。