pl/sql編程/存儲過程/存儲函數/觸發器

pl/sql編程語言
pl/sql編程語言是對sql語言的擴展，使得sql語言具有過程化編程的特性。
pl/sql編程語言比一般的過程化編程語言，更加靈活高效。
pl/sql編程語言主要用來編寫存儲過程和存儲函數等。
結構：

declare
--變量聲明區域
begin
--邏輯操作區域
end；
--可以把整個結構理解爲java中的main方法

實例

---聲明方法
---賦值操作可以使用:=也可以使用into查詢語句賦值
declare
--變量聲明區域
    i number(2) := 10;
    s varchar2(10) := '小明';
    ena emp.ename%type;---引用型變量
    emprow emp%rowtype;---記錄型變量
begin
    dbms_output.put_line(i);--類似與控制檯輸出
    dbms_output.put_line(s);
    select ename into ena from emp where empno = 7788;--將查詢到的數據通過into賦值到ena
    dbms_output.put_line(ena);
    select * into emprow from emp where empno = 7788;
    dbms_output.put_line(emprow.ename || '的工作爲：' || emprow.job);
end;

pl/sql中的if判斷
—輸入小於18的數字，輸出未成年
—輸入大於18小於40的數字，輸出中年人
—輸入大於40的數字，輸出老年人

declare
  i number(3) := ⅈ--從控制檯接收數據
begin
  if i<18 then
    dbms_output.put_line('未成年');
  elsif i<40 then
    dbms_output.put_line('中年人');
  else
    dbms_output.put_line('老年人');
  end if;
end;

pl/sql中的loop循環

---用三種方式輸出1到10是個數字
---while循環
declare
  i number(2) := 1;
begin
  while i<11 loop
     dbms_output.put_line(i);
     i := i+1;
  end loop;  
end;
---exit循環
declare
  i number(2) := 1;
begin
  loop
    exit when i>10;
    dbms_output.put_line(i);
    i := i+1;
  end loop;
end;
---for循環
declare

begin
  for i in 1..10 loop
     dbms_output.put_line(i);  
  end loop;
end;

遊標

---遊標：可以存放多個對象，多行記錄。
---輸出emp表中所有員工的姓名
declare
  cursor c1 is select * from emp;
  emprow emp%rowtype;
begin
  open c1;
     loop
         fetch c1 into emprow;
         exit when c1%notfound;
         dbms_output.put_line(emprow.ename);
     end loop;
  close c1;
end;

-----給指定部門員工漲工資
declare
  cursor c2(eno emp.deptno%type) 
  is select empno from emp where deptno = eno;
  en emp.empno%type;
begin
  open c2(10);
     loop
        fetch c2 into en;
        exit when c2%notfound;
        update emp set sal=sal+100 where empno=en;
        commit;
     end loop;  
  close c2;
end;

遊標的另一種遍歷數據的方式

存儲過程
–存儲過程：存儲過程就是提前已經編譯好的一段pl/sql語言，放置在數據庫端
or replace 譯爲如果本次創建的存儲過程/存儲函數/視圖。。。。。存在的話就替換它如果不存在就新建一個

---可以直接被調用。這一段pl/sql一般都是固定步驟的業務。
----給指定員工漲100塊錢
create or replace procedure p1(eno emp.empno%type)
is
begin
   update emp set sal=sal+100 where empno = eno;
   commit;
end;

select * from emp where empno = 7788;
----測試p1
declare

begin
  p1(7788);
end;

----通過存儲函數實現計算指定員工的年薪
----存儲過程和存儲函數的參數都不能帶長度
----存儲函數的返回值類型不能帶長度
create or replace function f_yearsal(eno emp.empno%type) return number
is
  s number(10);     
begin
  select sal*12+nvl(comm, 0) into s from emp where empno = eno;
  return s;
end;

----測試f_yearsal
----存儲函數在調用的時候，返回值需要接收。
declare
  s number(10); 
begin
  s := f_yearsal(7788);
  dbms_output.put_line(s);
end;

---out類型參數如何使用
---使用存儲過程來算年薪
create or replace procedure p_yearsal(eno emp.empno%type, yearsal out number)
is
   s number(10);
   c emp.comm%type;
begin
   select sal*12, nvl(comm, 0) into s, c from emp where empno = eno;
   yearsal := s+c;
end;

---測試p_yearsal
declare
  yearsal number(10);
begin
  p_yearsal(7788, yearsal);
  dbms_output.put_line(yearsal);
end;

in和out類型參數的區別是什麼？
凡是涉及到into查詢語句賦值或者:=賦值操作的參數，都必須使用out來修飾。

存儲過程和存儲函數的區別
語法區別：關鍵字不一樣，
存儲函數比存儲過程多了兩個return。
本質區別：存儲函數有返回值，而存儲過程沒有返回值。
如果存儲過程想實現有返回值的業務，我們就必須使用out類型的參數。
即便是存儲過程使用了out類型的參數，起本質也不是真的有了返回值，
而是在存儲過程內部給out類型參數賦值，在執行完畢後，我們直接拿到輸出類型參數的值。
自定義函數

----我們可以使用存儲函數有返回值的特性，來自定義函數。
----而存儲過程不能用來自定義函數。
----案例需求：查詢出員工姓名，員工所在部門名稱。
----案例準備工作：把scott用戶下的dept表複製到當前用戶下。
create table dept as select * from scott.dept;
----使用傳統方式來實現案例需求
select e.ename, d.dname
from emp e, dept d
where e.deptno=d.deptno;
----使用存儲函數來實現提供一個部門編號，輸出一個部門名稱。
create or replace function fdna(dno dept.deptno%type) return dept.dname%type
is
  dna dept.dname%type;
begin
  select dname into dna from dept where deptno = dno;
  return dna;
end;
---使用fdna存儲函數來實現案例需求：查詢出員工姓名，員工所在部門名稱。
select e.ename, fdna(e.deptno)
from emp e;

觸發器
—觸發器，就是制定一個規則，在我們做增刪改操作的時候，
----只要滿足該規則，自動觸發，無需調用。
----語句級觸發器：不包含有for each row的觸發器。
----行級觸發器：包含有for each row的就是行級觸發器。
-----------加for each row是爲了使用:old或者:new對象或者一行記錄。
語句級觸發器

----插入一條記錄，輸出一個新員工入職
create or replace trigger t1
after  --觸發時間（dml語句執行前觸發還是執行後觸發 after：執行後觸發 before：執行前觸發）
insert --操作類型（例如：update delcet）
on person --觸發器所在的表
declare

begin
  dbms_output.put_line('一個新員工入職');
end;
---觸發t1
insert into person values (1, '小紅');
commit;
select * from person;

行級別觸發器

---不能給員工降薪
---raise_application_error(-20001~-20999之間, '錯誤提示信息');
create or replace trigger t2
before
update  --觸發事件可以是一個或多個，如果多個觸發事件使用or鏈接
on emp
for each row  --行級觸發器標識
--when           --觸發條件如果不寫此句就默認爲每次執行觸發事件都觸發此觸發器
declare

begin
  if :old.sal>:new.sal then
     raise_application_error(-20001, '不能給員工降薪');
  end if;
end;
----觸發t2
select * from emp where empno = 7788;
update emp set sal=sal-1 where empno = 7788;
commit;

語句級觸發器與行級別觸發器的區別
語法上：行級別觸發器要比語句級觸發器多出 for each row 語句
操作上：行級別觸發器可以操作old和new而語句級觸發器則不能