flex中dictionary跟Object的區別與遍歷

 AS3中Object和 Dictionary都可以用來保存key-value形式的數據，Dictionary類和Object唯一的區別在於：Dictionary對象可以使用非字符串作爲鍵值對的鍵。例如：

var obj:Object = new Object();
obj["name"] ="name"; // key 字符串"name"
obj[1] = 1; // key是1 (被轉換成字符串"1")
obj[new Object()] ="object"; // key是new Object()，被轉傳成字符串"[object Object]"
for (var key:String in obj) {
        trace(key+":"+obj[key]); // 輸出 1:1 [object Object]:object name:name
}

也就是說，無論用什麼類型的變量作爲鍵，Object都將key轉換成字符串。同時，如果你使用了不同的對象作爲鍵，都會被轉換成字符串"[object Object]"作爲鍵，因此而指向了同一個數據。例如：

var a:Object = new Object();
var b:Object = new Object();
var obj:Object = new Object();
obj[a] = 1; // obj["[object Object]"] = 1;
obj[b] = 2; // obj["[object Object]"] = 2;
for (var key:String in obj) {
       trace(key+":"+obj[key]); // traces: [object Object]:2
}

Dictionary類將沒有這個限制，你可以將鍵設置成任何一種數據類型。例如：

 

var a:Object = new Object();
var b:Object = new Object();
var dict:Dictionary = new Dictionary();
dict[a] = 1; // dict[a] = 1;
dict[b] = 2; // dict[b] = 2;
for (var key:* in dict) {
       trace(key+":"+dict[key]); // traces: [object Object]:2 [object Object]:1
}

 

注意：

1、雖然在trace的時候，輸出的還是[object Object]，但是這個結果是對象的toString的結果。在Dictionary對象中，代表的是不同的對象引用。

2、這裏的key的類型是*。這是很重要的，因爲dict對象中的鍵可能是任何數據類型的。

 

 

3、Object的鍵必須是字符串，或表示字符串的表達式(變量或函數)，若不是字符串的表達式，則將調用toString()方法，將其轉化爲字符串；

4、與Object不同的是，Dictionary使用的鍵是對象的引用，而不是字符串，且非原始對象鍵調用之前是通過全等運算符(===)來進行判斷，並不會將數據類型強制轉換之後再進行判斷。