第 4 章 數據庫基礎2: 添加自定義數據
在這一章中，我們將創建一個新的字典對象，它用來表示我們僱員就職的 ‘Acme 公司‘（呵呵，當然是虛構的一家公司）的部門。這個“部門”字典對象將包含一個表示部門經理的記錄。我們還會加入代碼到僱員創建過程，這個過程會加入一個索引到僱員工作的部門。
我們要說明的是如何在DWG文件中創建自定義數據，包括“每個圖形”的自定義數據和“每個實體”的自定義數據。“每個圖形”的自定義數據是指只在整個圖形中加入一次的數據，它表示對象可以引用的單一類型或特性。“每個實體”的自定義數據是指是爲特定的對象或數據庫中的實體加入的數據。
在下面的示例中，我們將加入“每個圖形”的自定義數據到命名對象字典(簡稱NOD)。NOD存在於每一個DWG文件中。“每個實體”的自定義數據加入到一個名爲“擴展字典”的字典（可選）中，它表示每一個僱員。每一個由DBObject派生的對象都擁有存儲自定義數據的擴展字典。而在我們的示例中將包含這種自定義數據如名字、薪水和部門。
因此這一章的重點是字典對象和擴展記錄（XRecord），它們是我們用來表示自定義數據的容器。
首先讓我們來創建表示公司的條目。在本章的前幾個步驟中，我們將創建如下所示的部門層次結構：
NOD－命名對象字典
ACME_DIVISION－自定義公司字典
銷售(Sales) －部門字典
部門經理－部門條目
請打開Lab4文件夾下的Lab4工程，或接着Lab3的代碼。
1) 我們首先要做的是定義一個新的函數，它用來在命名對象字典(NOD)中創建公司字典對象。爲這個函數取名爲
CreateDivision(),，並使用命令屬性來定義CREATEDIVISION命令。
下面是這個函數的代碼，它的形式非常簡單，只是用來在NOD中創建一個ACME_DIVISION（用來表示公司）
<CommandMethod("CREATEDIVISION")> _
Public Function CreateDivision()
Dim db = HostApplicationServices.WorkingDatabase
Dim trans As Transaction = db.TransactionManager.StartTransaction()
Try
'首先，獲取NOD……
Dim NOD As DBDictionary = trans.GetObject(db.NamedObjectsDictionaryId, OpenMode.ForWrite, False)
'定義一個公司級別的字典
Dim acmeDict As DBDictionary
Try
'如果ACME_DIVISION不存在，則轉到catch塊，這裏什麼也不做
acmeDict = trans.GetObject(NOD.GetAt("ACME_DIVISION"), OpenMode.ForRead)
Catch
'如果ACME_DIVISION不存在，則創建它並把它加入到NOD中……
acmeDict = New DBDictionary()
NOD.SetAt("ACME_DIVISION", acmeDict)
trans.AddNewlyCreatedDBObject(acmeDict, True)
End Try
trans.Commit()
Finally
trans.Dispose()
End Try
End Function
請仔細閱讀一下上面的代碼塊的結構，可以通過註釋來了解相關的細節。特別要注意的是我們是如何用一個try-catch塊來處理ACME_DIVISION是否存在？如果ACME_DIVISION字典不存在，GetObject()將會拋出異常，catch塊被執行，它會創建一個新的字典。
運行這個函數來看它是否可行。可以使用數據庫查看工具來檢查字典是否已被加入（建議使用ARX SDK的ArxDbg工具）
2) 接下來，我們要在ACME_DIVISION字典中加入銷售(Sales)條目。銷售(Sales)條目同樣也是一個字典。由於銷售(Sales)與ACME_DIVISION字典的關係如同ACME_DIVISION字典與NOD，所以代碼是類似的。定義下面的代碼部分在ACME_DIVISION字典中創建一個名爲’Sales’的字典。
代碼提示：
Code hint:
Dim divDict As DBDictionary
Try
divDict = trans.GetObject(acmeDict.GetAt("Sales"), OpenMode.ForWrite)
Catch
…
運行函數來看‘Sales’條目是否已加入到ACME_DIVISION字典。
3) 現在我們要在這個字典中加入一個特殊的記錄，它可以包含任意的自定義數據。我們要加入的數據類型爲擴展記錄（XRecord），它可以包含任何東西，因此我們可以讓它包含ResultBuffer類的對象（就是有些人可能非常熟悉的‘resbuf’）。ResultBuffer可以存儲不同類型的預定義數據。擴展記錄存儲任意數目的ResultBuffer關係列表，因此可能會很大。下表是可以包含在ResultBuffer中一些數據類型（位於Database類的DxfCode枚舉中）：
|
Start |
0 |
|
|
Text |
1 |
|
|
XRefPath |
1 |
|
|
ShapeName |
2 |
|
|
BlockName |
2 |
|
|
AttributeTag |
2 |
|
|
SymbolTableName |
2 |
|
|
MstyleName |
2 |
|
|
SymTableRecName |
2 |
|
|
AttributePrompt |
3 |
|
|
DimStyleName |
3 |
|
|
LinetypeProse |
3 |
|
|
TextFontFile |
3 |
|
在下面的代碼部分，我們將創建只包含一個ResultBuffer的擴展記錄。這個ResultBuffer包含一個單一的的字符串值，它表示’Sales’部門的部門經理的名字。我們使用和加入字典一樣的方法加入擴展記錄。唯一的區別是擴展記錄與字典的不同：
mgrXRec = New Xrecord()
mgrXRec.Data = New ResultBuffer(New TypedValue(DxfCode.Text, "Randolph P. Brokwell"))
請看一下我們是怎樣使用new來創建一個新的擴展記錄。但我們也使用了New來創建一個ResultBuffer，傳入的參數是一個名爲‘TypedValue’的對象。‘TypedValue’對象和C++中resbuf的成員‘restype’是類似的。這個對象一般表示一個特定類型的DXF值，我們使用它來組裝諸如擴展數據或擴展記錄之類的通用數據容器。在這裏，我們簡單地使用DxfCode.Text鍵值和“Randolph P. Brokwell”數據值來定義一個TypedValue，然後把它作爲單一的參數傳入ResultBuffer構造函數(由new來調用)中。
XRecord的’Data’屬性實際上正是擴展記錄鏈的第一個ResultBuffer，我們使用它來表示擴展記錄鏈是從什麼地方開始的。
所以接下來的代碼塊看起來和前面兩個非常相似：
Dim mgrXRec As Xrecord
Try
mgrXRec = trans.GetObject(divDict.GetAt("Department Manager"), OpenMode.ForWrite)
Catch
mgrXRec = New Xrecord()
mgrXRec.Data = New ResultBuffer(New TypedValue(DxfCode.Text, "Randolph P. Brokwell"))
divDict.SetAt("Department Manager", mgrXRec)
trans.AddNewlyCreatedDBObject(mgrXRec, True)
End Try
運行函數並使用數據庫查看工具來確定部門經理已被加入到’Sales’字典。
4) 我們已經定義了公司字典，現在我們要把每個僱員的數據加入到前一章定義的塊索引中。我們要加入的數據是：名字、薪水和僱員所屬的部門。要加入這些數據，我們要同前幾個步驟一樣使用擴展記錄。因爲我們要加入三個條目，所以我們要使擴展記錄可以把這些數據聯繫在一起。
一般來說，擴展記錄只能存在於字典中。而我們要爲每個僱員加入這些數據（就是本章開頭所講的“每個圖形”的自定義數據和“每個實體”的自定義數據），那應該怎麼做呢？答案就是：每一個對象或AutoCAD中的實體實際上都有一個名爲’擴展字典（Extension Dictionary）’的可選字典。我們可以把擴展記錄直接加入到這個字典中。
請回到我們在上一章創建的CreateEmployee()函數。這個函數是我們創建塊索引的地方。
讓我們像前面的步驟一樣來創建一個新的擴展記錄。因爲我們要加入3個條目，因此我們既可以使用ResultBuffer的Add方法（它會在擴展記錄鏈中加入一個鏈接），也可以利用ResultBuffer的構造函數（它的一種構造函數可以輸入可變數量的參數）。
無論用哪一種方法，請在CreateEmployee()函數中使用ResultBuffer來創建一個新的XRecord，ResultBuffer包括以下的類型和值：
Text – “Earnest Shackleton” (或是你選擇的其它僱員的名字)
Real – 72000 或者更多的薪水J
Text – “Sales” 僱員所在的部門
5) 要把上面的擴展記錄加入到塊索引，我們必須把它加入到擴展字典。通常這個字典是不存在的，除非它被明確地創建，塊索引就是這種情況。要給一個對象創建擴展字典，你要調用它的成員‘CreateExtensionDictionary()’。這個函數不返回任何值，所以要訪問它創建的擴展字典，你還得使用對象的‘ExtensionDictionary’屬性。你可以使用類似於以下的代碼來創建並訪問擴展字典：
br.CreateExtensionDictionary()
Dim brExtDict As DBDictionary = trans.GetObject(br.ExtensionDictionary(), OpenMode.ForWrite, False)
由於擴展字典也是字典，我們可以和第3步一樣在擴展字典中加入擴展記錄。請完成有關的代碼來創建和訪問塊索引的擴展字典，加入你在第4步中創建的擴展記錄，然後把擴展記錄加入到事務處理。
6) 返回到NOD……因爲在NOD中創建公司字典只需要一次（就像創建Employee塊一樣），因此我們應該把CreateDivision函數的命令屬性去掉，而在CreateEmployeeDefinition()中調用這個函數。請自己完成這些改變。當所有這些都做完後，當CREATE命令第一次運行的時候，所有的函數都會被調用。
7) 下面的步驟和上面的無關。我們將創建一個函數來遍歷模型空間，以用來查找加入的Employee對象（這裏其實是塊索引）的數目。在VB.NET 或C#中，我們可以把模型空間塊表記錄（ModelSpace BlockTableRecord）當作一個集合，這樣就可以使用For Each(C#是foreach)來遍歷它。請仔細研究一下下面的代碼片斷：
Dim id As ObjectId ‘首先，定義一個For循環要使用的ObjectId變量。
For Each id In btr
Dim ent As Entity = trans.GetObject(id, OpenMode.ForRead, False) '打開當前的對象!
一旦我們獲得模型空間對象，你們就可以定義一個ObjectId變量，然後把它用於For Each循環(C#是foreach)。
現在，我們需要使用一些方法來篩選僱員。我們知道模型空間中的對象都是實體，但不全是僱員。我們需要使用一些方法來加以區分。在這裏，我們可以使用VB.NET的TypeOf關鍵字並用CType進行類型轉換（C#是GetType函數和typeof）：
If TypeOf ent Is BlockReference Then
Dim br As BlockReference = CType(ent, BlockReference)
…
上面講的概念對於AutoCAD編程是很重要的，因爲容器對象經常包含不同類型的對象。你會在AutoCAD程序的開發中經常碰到這種類型轉化。
請定義一個名爲EmployeeCount()的函數，函數的結構如上所示，它用來統計模型空間中的塊索引的數目。這個函數不會輸出任何東西，但你可以使用逐步調試程序來查看整數變量的增加（每發現一個塊索引對象）。
8) 接下來，爲了把結果輸出到命令行，我們需要使用Application.DocumentManager.MdiActiveDocument.Editor對象的服務。要使用它，請加入下面的代碼：
Imports Autodesk.AutoCAD.EditorInput
Imports Autodesk.AutoCAD.ApplicationServices
在函數的內部：
Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor
最後，在循環的後面確定找到了多少個塊索引：
ed.WriteMessage("Employees Found: {0}" + ControlChars.Lf, nEmployeeCount.ToString())
End of Lab 4:
第四章結束
下面的代碼片斷演示了怎樣獲取Employee對象的所有內容，包括ACME_DIVISION字典中的部門經理的名字。這部分要在後面的章節中使用，但因爲它和本章有關，因此我們把它放在本章作介紹。如果有時間的話，請閱讀一下其中的代碼來看看它是怎麼使用的。它可以被直接放到你的類中並可以運行。命令的名字是PRINTOUTEMPLOYEE。ListEmployee()函數接收一個ObjectId參數，它通過一個ref類型的字符串數組返回值（包含相應的僱員數據）。調用它的PrintoutEmployee()函數只是用來在命令行中輸出這些數據。
'我們需要一個遍歷並顯示所有僱員數據的命令。
Public Shared Sub ListEmployee(ByVal employeeId As ObjectId, ByRef saEmployeeList() As String)
Dim nEmployeeDataCount As Integer
Dim db = HostApplicationServices.WorkingDatabase
Dim trans As Transaction = db.TransactionManager.StartTransaction() '開始事務處理。
Try
Dim ent As Entity = trans.GetObject(employeeId, OpenMode.ForRead, False) '打開當前對象!
If TypeOf ent Is BlockReference Then
'不是所有的塊索引都有僱員數據，所以我們要處理錯誤
Dim bHasOurDict As Boolean = True
Dim EmployeeXRec As Xrecord
Try
Dim br As BlockReference = CType(ent, BlockReference)
Dim extDict As DBDictionary = trans.GetObject(br.ExtensionDictionary(), OpenMode.ForRead, False)
EmployeeXRec = trans.GetObject(extDict.GetAt("EmployeeData"), OpenMode.ForRead, False)
Catch
bHasOurDict = False '出現了錯誤……字典或擴展記錄不能訪問
End Try
If bHasOurDict Then '如果獲得擴展字典，而又有擴展記錄……
'調整僱員列表的大小來使得它能放三個條目...
ReDim Preserve saEmployeeList(saEmployeeList.GetUpperBound(0) + 4)
'加入僱員的名字
Dim resBuf As TypedValue = EmployeeXRec.Data.AsArray(0)
saEmployeeList.SetValue(String.Format("{0}" + ControlChars.Lf, resBuf.Value), nEmployeeDataCount)
nEmployeeDataCount += 1
'加入僱員的薪水
resBuf = EmployeeXRec.Data.AsArray(1)
saEmployeeList.SetValue(String.Format("{0}" + ControlChars.Lf, resBuf.Value), nEmployeeDataCount)
nEmployeeDataCount += 1
'加入僱員所在的部門
resBuf = EmployeeXRec.Data.AsArray(2)
Dim str As String = resBuf.Value()
saEmployeeList.SetValue(String.Format("{0}" + ControlChars.Lf, resBuf.Value), nEmployeeDataCount)
nEmployeeDataCount += 1
'現在，讓我們從公司字典中獲取老闆的名字
'在NOD中找到.
Dim NOD As DBDictionary = trans.GetObject(db.NamedObjectsDictionaryId, OpenMode.ForRead, False)
Dim acmeDict As DBDictionary = trans.GetObject(NOD.GetAt("ACME_DIVISION"), OpenMode.ForRead)
'注意我們直接使用擴展數據...
Dim salesDict As DBDictionary = trans.GetObject(acmeDict.GetAt(EmployeeXRec.Data.AsArray(2).Value), OpenMode.ForRead)
Dim salesXRec As Xrecord = trans.GetObject(salesDict.GetAt("Department Manager"), OpenMode.ForRead)
'最後，把僱員的數據輸出到命令行
resBuf = salesXRec.Data.AsArray(0)
saEmployeeList.SetValue(String.Format("{0}" + ControlChars.Lf, resBuf.Value), nEmployeeDataCount)
nEmployeeDataCount += 1
End If
End If
trans.Commit()
Finally
trans.Dispose()
End Try
End Sub
<CommandMethod("PRINTOUTEMPLOYEE")> _
Public Shared Function PrintoutEmployee()
Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor
Dim nEmployeeCount As Integer = 0
Dim nEmployeeDataCount As Integer
'聲明我們將在下面使用的工具...
Dim db = HostApplicationServices.WorkingDatabase
Dim trans As Transaction = db.TransactionManager.StartTransaction() 'Start the transaction.
Try
'首先，獲取塊表和模型空間塊表記錄
Dim bt As BlockTable = trans.GetObject(HostApplicationServices.WorkingDatabase.BlockTableId, OpenMode.ForRead)
Dim btr As BlockTableRecord = trans.GetObject(bt(btr.ModelSpace), OpenMode.ForRead)
'現在，我們需要把內容輸出到命令行。這裏可以有一個對象幫助我們：
'下面的部分，我們將遍歷模型空間:
Dim id As ObjectId ' – 首先，定義一個ObjectId對象，用於For循環。
For Each id In btr
Dim ent As Entity = trans.GetObject(id, OpenMode.ForRead, False) '打開當前對象!
If TypeOf ent Is BlockReference Then
Dim saEmployeeList(-1) As String '這是正確的...它被重新定義。
ListEmployee(id, saEmployeeList)
Dim sEmployeeData As String
If (saEmployeeList.Length = 4) Then
ed.WriteMessage("Employee Name: {0}", saEmployeeList(0))
ed.WriteMessage("Employee Salary: {0}", saEmployeeList(1))
ed.WriteMessage("Employee Division: {0}", saEmployeeList(2))
ed.WriteMessage("Division Manager: {0}", saEmployeeList(3))
End If
End If
Next
Finally
End Try
End Function