oracle實現find_in_set函數

CREATE OR REPLACE FUNCTION FIND_IN_SET(piv_str1 varchar2, piv_str2 varchar2, p_sep varchar2 := ',')    
RETURN NUMBER IS      
  l_idx    number:=0; -- 用於計算piv_str2中分隔符的位置  
  str      varchar2(500);  -- 根據分隔符截取的子字符串  
  piv_str  varchar2(500) := piv_str2; -- 將piv_str2賦值給piv_str  
  res      number:=0; -- 返回結果  
  loopIndex number:=0;
BEGIN  
-- 如果piv_str中沒有分割符，直接判斷piv_str1和piv_str是否相等，相等 res=1  
IF instr(piv_str, p_sep, 1) = 0 THEN  
   IF piv_str = piv_str1 THEN   
      res:= 1;  
   END IF;  
ELSE  
-- 循環按分隔符截取piv_str  
LOOP  
    l_idx := instr(piv_str,p_sep);  
     loopIndex:=loopIndex+1;
-- 當piv_str中還有分隔符時  
      IF l_idx > 0 THEN  
   -- 截取第一個分隔符前的字段str  
         str:= substr(piv_str,1,l_idx-1);  
   -- 判斷 str 和piv_str1 是否相等，相等 res=1 並結束循環判斷  
         IF str = piv_str1 THEN   
           res:= loopIndex;  
           EXIT;  
         END IF;  
        piv_str := substr(piv_str,l_idx+length(p_sep));  
      ELSE  
   -- 當截取後的piv_str 中不存在分割符時，判斷piv_str和piv_str1是否相等，相等 res=1  
        IF piv_str = piv_str1 THEN   
           res:= loopIndex;  
        END IF;  
        -- 無論最後是否相等，都跳出循環  
        EXIT;  
      END IF;  
END LOOP;  
-- 結束循環  
END IF;  
-- 返回res  
RETURN res;  
END FIND_IN_SET;

使用方法

select find_in_set('2','12,3,5,6,7',',') from dual;