管理員權限執行批處理和執行regsvr32註冊dll、OCX、AX等控件

參考：https://www.cnblogs.com/tail-f/p/6723199.html

 公司軟件部署經常需要註冊.com組件，之前的bat批處理需要右鍵管理員權限運行才行。這裏發佈一小段命令可以免去這個步驟。

@echo off
color 0

REM ________________________________________________________________

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

if '%errorlevel%' NEQ '0' (

    echo 請求管理員權限...

    goto UACPrompt

) else ( goto gotAdmin )

:UACPrompt

    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"

    echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"

    exit /B

:gotAdmin

    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )

    pushd "%CD%"

    CD /D "%~dp0"

REM ________________________________________________________________

echo=  
echo=    
echo 管理員權限已獲取，正在執行COM註冊******
echo=
regsvr32 LAVAudio.dll /s
echo 完成LAVAudio.dll註冊
regsvr32 LAVSplitter.dll /s
echo 完成LAVSplitter.dll註冊
regsvr32 LAVVideo.dll /s
echo 完成LAVVideo.dll註冊
echo=
echo .AX組件註冊完成。
ping -n 3 127.0.0.1>nul

此批處理文件必須和.dll文件放在同一個目錄執行。

 

%cd%         獲取當前執行批處理的cmd目錄（權限不同目錄不同），管理員權限運行目錄則爲system32

%~dp0        獲取當前目錄路徑

%windir%    獲取windows目錄路徑

%~d0          獲取當前盤符

%~sdp0       獲取當前盤符和路徑的短文件名格式

%~f0           獲取此批處理的路徑