MSSQL查找進程造成死鎖_把這個進程殺掉

 create   proc   [dbo].[sp_lockinfo] 
  @kill_lock_spid   bit=0,             --是否殺掉阻塞的進程,1   殺掉,   0   僅顯示 
  @show_spid_if_nolock   bit=0,   --如果沒有阻塞的進程,是否顯示正常進程信息,1   顯示,0   不顯示 
  @dbname   sysname=''                     --如果爲空,則查詢所有的庫,如果爲null,則查詢當前庫,否則查詢指定庫 
  as 
  set   nocount   on 
  declare   @count   int,@s   nvarchar(2000),@dbid   int 
  if   @dbname=''   set   @dbid=db_id()   else   set   @dbid=db_id(@dbname) 
  
  select   id=identity(int,1,1),標誌, 
  進程ID=spid,線程ID=kpid,塊進程ID=blocked,數據庫ID=dbid, 
  數據庫名=db_name(dbid),用戶ID=uid,用戶名=loginame,累計CPU時間=cpu, 
  登陸時間=login_time,打開事務數=open_tran, 進程狀態=status, 
  工作站名=hostname,應用程序名=program_name,工作站進程ID=hostprocess, 
  域名=nt_domain,網卡地址=net_address 
  into   #t   from( 
  select   標誌='阻塞的進程', 
  spid,kpid,a.blocked,dbid,uid,loginame,cpu,login_time,open_tran, 
  status,hostname,program_name,hostprocess,nt_domain,net_address, 
  s1=a.spid,s2=0 
  from   master..sysprocesses   a   join   ( 
  select   blocked   from   master..sysprocesses   
  where   blocked>0 
  and(@dbid   is   null   or   dbid=@dbid) 
  group   by   blocked 
  )b   on   a.spid=b.blocked   
  where   a.blocked=0 
  and(@dbid   is   null   or   dbid=@dbid) 
  union   all 
  select   '|_犧牲品_>', 
  spid,kpid,blocked,dbid,uid,loginame,cpu,login_time,open_tran, 
  status,hostname,program_name,hostprocess,nt_domain,net_address, 
  s1=blocked,s2=spid 
  from   master..sysprocesses   a   
  where   blocked<>0 
  and(@dbid   is   null   or   dbid=@dbid) 
  )a   order   by   s1,s2 
  
  select   @count=@@rowcount 
  
  if   @count=0   and   @show_spid_if_nolock=1 
  begin 
  insert   #t 
  select   標誌='正常的進程', 
  spid,kpid,blocked,dbid,db_name(dbid),uid,loginame,cpu,login_time, 
  open_tran,status,hostname,program_name,hostprocess,nt_domain,net_address 
  from   master..sysprocesses 
  where   @dbid   is   null   or   dbid=@dbid 
  order   by   spid 
  set   @count=@@rowcount 
  end 
  
  if   @count>0 
  begin 
  create   table   #t1(id   int   identity(1,1),a   nvarchar(30),b   Int,EventInfo   nvarchar(255)) 
  declare   tb   cursor   local 
  for 
  select   N'insert   #t1   exec(''dbcc   inputbuffer('+rtrim(進程ID)+')'') 
  if   @@rowcount=0   insert   #t1(a)   values(null) 
  '+case   when   @kill_lock_spid=1   and   標誌=N'阻塞的進程' 
  then   'kill   '+rtrim(進程ID)   else   ''   end 
  from   #t 
  open   tb 
  fetch   tb   into   @s 
  while   @@fetch_status=0 
  begin 
  exec(@s) 
  fetch   tb   into   @s 
  end 
  close   tb 
  deallocate   tb 
  select   a.*,進程的SQL語句=b.EventInfo 
  from   #t   a   join   #t1   b   on   a.id=b.id 
  order   by   a.ID 
  end 
  set   nocount   off