案例來自於《CMOS_analog Circuit Design》-Allen
一、基本構型
希望確定各晶體管的尺寸以達到如下要求:
基本參數 |
電平參數 |
頻率參數 |
L=1μm |
共模電平ICMR=−1 to 2V |
相位裕度60°,增益Av>5000 |
CL=10pF |
Pdiss≤2mW |
壓擺率SR>10V/μs |
VDD=−VSS=2.5V |
Vout=±2V |
帶寬增益積GB=5MHz |
另外器件參數kn′=110μA/V2,kp′=50μA/V2,VT=0.7±0.15V。
二、設計過程:
(1) 滿足相位裕度條件,確定米勒電容Cc
因爲已知負載電容CL=10pF,考慮到二級運放有一個隱含條件:第二級放大的跨導是第一級的10倍,即gm6=10 gm1,這樣考慮零點後,要達到60°的裕度,第二極點要大於單位增益帶寬GB的2.2倍(不考慮零點是3=1.73倍)。根據這個條件可以確定Cc,它太小不能滿足裕度要求,太大會衰減過快,不滿足帶寬要求。
w2≥2.2GB→CLgm6≥2.2Ccgm1→Cc≥0.22CL=2.2pF
不妨取Cc=3pF。
(2)滿足壓擺率,確定偏置電流I5
SR=CcI5→I5=SR×Cc=30μA
(3)滿足帶寬增益積,確定gm1,gm6
gm1gm6=GB×Cc=(5×106)(2π)(3×10−12)=94.25μS=10gm1=942.5μS
(4) 滿足輸入共模電平,確定(W/L)1,2,(W/L)3,4,(W/L)5
由M1的跨導可以很容易得到:
(W/L)1,2=2kn′I1gm12=2∗110∗15(94.25)2=2.79≈3
輸入共模電平最大值爲2V,要保證M3管飽和,考慮到PMOS和NMOS閾值電壓偏離的最壞情況,當VTn=0.55,VTp=0.85時,M3的過驅電壓最小,需要的寬長比最大,以保證最壞情況下也飽和。
(W/L)3,4=kp′(VDD−Vinmax+VTnmin−VTpmax)22∗0.5I5=50×10−6(2.5−2+0.55−0.85)230×10−6=15
輸入共模電平最小爲-1V,要保證M5管飽和,考慮到NMOS閾值電壓偏離的最壞情況,當VTn=0.85時,M5的過驅電壓最小,需要的寬長比最大,以保證最壞情況下也飽和。
Vov5min(W/L)5=Vinmin−Vss−VTnmax−Vov1=−1−(−2.5)−0.85−110×10−6×330×10−6=0.35V=kn′Vov5min22I5=110×10−6(0.35)22(30×10−6)=4.49≈4.5
(5)確定(W/L)6,I6,(W/L)7
有個很關鍵的一點,當共模輸入時,Vg6=Vd4=Vd3,也就是三個PMOS管過驅電壓一致,容易求出gm4=2I4kp′(W/L)4=2∗15∗50∗15=150μS,結合gm6=942.5μS,(W/L)4=15,可得:
(W/L)6I6(W/L)7=(W/L)4×gm4gm6≈94=I4×(W/L)4(W/L)6≈95μA=(W/L)5×I5I6≈14
(6)檢查輸出電壓、功耗、增益是否達標
Vov6Vov7PdissAv=2I6/β6=2∗95/(50∗94)≈0.2<0.5=2I7/β7=2∗95/(110∗14)≈0.35<0.5=5∗(30+95)=0.625<2mW=Av1∗AV2=(gm1∗ro1)(gm6∗ro6)=(15∗(0.04+0.05)94.25)(95∗(0.04+0.05)942.5)=69.8∗110=7678>5000
三、結果及半定量分析
輸出的波動幅度時4V,M2 漏極波動約40mV(A2≈100),輸入兩端相等時Vd2=2.5−0.7−0.2=1.6V,線性條件下,輸入的最大差模電壓約0.6mV(A1≈70)。
四、Hspice 模擬結果
1、網表
* 二級運放Hspice 網表描述
*晶體管參數
M1 4 2 3 3 MN l=1u w=3u
M2 5 1 3 3 MN l=1u w=3u
M3 4 4 8 8 MP l=1u w=15u
M4 5 4 8 8 MP l=1u w=15u
M5 3 7 9 9 MN l=1u w=4.5u
M6 6 5 8 8 MP l=1u w=94u
M7 6 7 9 9 MN l=1u w=14u
M8 7 7 9 9 MN l=1u w=4.5u
Cc 6 5 3p
.model mn nmos level=1 vto=0.7 kp=110u lambda=0.04
.model mp pmos level=1 vto=-0.7 kp=50u lambda=0.05
*電源、輸入及外部負載
Ibias 8 7 30u
VDD 8 0 2.5
VSS 9 0 -2.5
vin1 2 0 1 ac 1
vin2 1 0 1
CL 6 0 10p
*靜態工作點
.op
*零極點
.pz v(6) vin1
*交流分析
.ac dec 10 1 100meg
.print ac v(6) vp(6)
.end
2、靜態電壓和晶體管參數如圖:
可以看出,管子都處於飽和狀態,計算時忽略了溝道調製效應,實際的漏源電流會更大。因爲NMOS的lambda小於PMOS,所以節點6處的電壓大於0,爲995.5796m。節點4的電壓與之前分析一致,爲1.6V。
3、零極點
紅框中是主要的極點和零點,單位是赫茲。單位增益帶寬GB=5MHz,p2≈5∗3=15MHz,與16.2相近。主極點爲GB/A=651Hz,與579相近。零點約爲GB十倍,也相近。
4、波特圖
數據點顯示單位帶寬增益爲5MHz,相位裕度爲67.5°,還是比較符合預期的。