APDL：
/filename,barplate
/title,Impact Of A Bar Into A Plate
/PREP7
/view,,1,2,3
/plopts,info,1
/pbc,all,1
/pnum,mat,1
/num,1
ET,1,SOLID164
! --- Enter Ceramic Material Properties For Bar
mpmod,1,1
mp,ex,1,330e9
mp,nuxy,1,.24
mp,dens,1,8400
! --- Enter Aluminum Material Properties For Plate Using GUI (Later) ...
! --- Create and Mesh Bar
block,-.1,.1,1,5,-.2,.2
desize,4
mat,1
vmesh,1
cm,nbar,node
cm,ebar,elem
! --- Define Initial Velocity of Bar
edivelo,nbar,,-500.0
! --- Create and Mesh Plate
block,-2,2,.75,.95,-1,1
desize,6
mat,2
vmesh,2
esel,s,mat,,2
nsle
cm,nplate,node
cm,eplate,elem
nsel,all
esel,all
! --- Apply Constraints To Bottom Perimeter of Plate
nsel,s,loc,y,.75
nsel,u,loc,x,-1.99,1.99
d,all,ux,0,,,,uy,uz
nsel,s,loc,y,.75
nsel,u,loc,z,-0.99,0.99
d,all,ux,0,,,,uy,uz
! --- Generate Eroding Surface-To-Surface Contact Between Bar and Plate
edcgen,ests,nbar,nplate,,,,,,1,1,1 ! Set V1=V2=V3=1
edcontact,1.0,,,,,,2,,0 ! SFSI, ORIE, and PENCHK explicitly set
! --- Create node and elem components for POST26
nsel,s,loc,x,-0.4,0.4
nsel,r,loc,z,-0.5,0.5
nsel,r,loc,y,0,2
esln
nsle
cm,elems,elem
cm,nodes,node
nsel,all
esel,all
eplot
fini
/solu
time,.0007 ! Endtime
edrst,10 ! Time Increment For Results Output
edhtime,100
edhist,nodes
edhist,elems
eplot
save
/eof ! The following is from going through the exercise ...
FINISH
/PREP7
!*
!*
MPMO,2,19
UIMP,2,DENS, , ,7860,
UIMP,2,EX, , ,100e9,
UIMP,2,NUXY, , ,0.34,
TB,PLAW,2, , ,1
TBDAT,1,289e6,
TBDAT,2,500e6,
TBDAT,3,0,
TBDAT,4,40,
TBDAT,5,5,
TBDAT,6,0.125,
!*
SAVE
FINISH
/SOLU
/STAT,SOLU
SOLVE
/INPUT,animacro,inp,,, 0
! FINISH
! /EXIT,NOSAV
/eof ! Read in "animacro.inp" (below) after the solution is done ...
/title, This macro unselects failed elements for the animation
fini
/post1 ! general post-processor
/dscale,,1 ! displacement magnification set to "true"
nsel,all
esel,all
eplot
*create,danim.mac ! create macro to animate eroding contact
/seg,delet
/seg,multi
/edge,,1
*do,i,arg1,arg2,arg3 ! use these substeps for animation
set,1,i
etab,erase
etab,eptoeqv,epto,eqv ! fill element table with strain data
esel,s,etab,eptoeqv,0.0,0.11 ! only total strain output documented
nsle ! nodes attached to selected elements
plesol,epto,eqv ! plot equivalent total strain
*enddo
/seg,off
anim,5,1,0.5 ! do not show animation in reverse
*end
/edge,,0
danim,1,11,1 ! assumes that there are at least 11 substeps of data ...
/eof
*msg,ui
An animation macro called "danim.mac" now exists in this directory. %/&
%/&
To run it, just type: danim,arg1,arg2,arg3 %/&
%/&
where %/&
%/&
arg1=first substep, arg2=last substep, and arg3=substep increment
作者：XuJC