關於ASP的(VBScript)類

 

首先ASP的(VBScript)類是由事件和方法（它們就是構成類的成員了）構成的，如果大家還沒有接觸過，可以先看看下面的說明（哈哈，我是現學現賣，說得不好請見諒）


在 Class 塊中，成員通過相應的聲明語句被聲明爲 Private(私有成員，只能在類內部調用) 或 Public(公有成員，可以在類內外部調用) 。被聲明爲 Private 的將只在 Class 塊內是可見的。被聲明爲 Public 不僅在 Class 塊的內部是可見的，對 Class 塊之外的代碼也是可見的。沒有使用 Private 或 Public 明確聲明的被默認爲 Public。在類的塊內部被聲明爲 Public 的過程（Sub 或 Function）將成爲類的方法。Public 變量將成爲類的屬性，同使用 Property Get、Property Let 和 Property Set 顯式聲明的屬性一樣。類的缺省屬性和方法是在它們的聲明部分用 Default 關鍵字指定的。


請大家內心看完藍色的部分，下面我們來看一個例子

<script language=vbscript runat=server>

Class myClass
'//----聲明（聲明就是定義）myClass類的類內部（私有的[Private]）變量
Private strAuthor
Private strVersion
Private strExample

'//---------------------------定義類的事件-------------------------------//
'//----Class_Initialize()是類的初始化事件，只要一開始使用該類，首先會觸發該部分的執行，下面我們會在該成員中初始化該類的作者和版本以及在屏幕上顯示一下該類已經開始了

Private Sub Class_Initialize()
strAuthor = "思源"
strVersion = "1.0"
Response.Write "<br>myClass開始了<br>"
End Sub
'//----Class_Terminate()是類的結束事件，只要一退出該類，就會觸發該事件，下面我們會該事件中設定退出該類時會在屏幕上顯示該類已結束了。

Private Sub Class_Terminate()
Response.Write "<br>myClass結束了<br>"
End Sub

'//---------------------------用戶自己定義的方法-------------------------------//

'//----該方法返回一個版本信息

Public Sub Information()
Response.Write "<br>Coding By <a href='mailto:[email protected]'>Maxid_Zen</a> @ <a href='http://www.design60s.com'>www.design60s.com</a>.<br>"
End Sub

'//---------------------------定義類的輸出屬性-------------------------------//

'//----定類的屬性，該屬性是讓用戶初始化strExapmle變量

Public Property Let setExapmle(ByVal strVar)
strExapmle = strVar
End Property

'//---------------------------定義類的輸出屬性-------------------------------//

'//----定義類的屬性，該屬性是返回一個版本號

Public Property Get Version
Version = strVersion
End Property

'//----定義類的屬性，該屬性是返回該類的作者號

Public Property Get Author
Author = strAuthor
End Property

'//----定義類的屬性，該屬性是返回一個版本號

Public Property Get Exapmle
Exapmle = strExapmle
End Property

End Class

</script>
<%

'//-------這裏是使用該類的例子

Dim oneNewClass

Set oneNewClass = New myClass

Response.Write "作者：" & oneNewClass.Author & "<br>"
Response.Write "版本：" & oneNewClass.Version & "<br>"

oneNewClass.setExapmle = "這是一個簡單類的例子"

Response.Write "用戶自定義：" & oneNewClass.Exapmle & "<br>"

oneNewClass.Information

Set oneNewClass = Nothing

%>