SQL Server 學習筆記④ 查詢某個數據所在數據庫表中的哪個字段上出現過的存儲過程

--2005查找某數據庫中的列是否存在某個值
create proc spFind_Column_In_DB
(
	@type int,--類型：1爲文字類型、2爲數值類型
	@str nvarchar(100)--需要搜索的名字
)
as
	--創建臨時表存放結果
	create table #tbl(PK int identity primary key ,tbl sysname,col sysname)
	declare @tbl nvarchar(300),@col sysname,@sql nvarchar(1000)
	if @type=1 
	begin
		declare curTable cursor fast_forward
		for 
			select '['+SCHEMA_NAME(SCHEMA_ID)+'].['+o.name+']' tableName,'['+c.name+']' columnName from sys.columns c inner join sys.objects o on c.object_id=o.object_id
			where o.type_desc='user_table' and user_type_id in (167,175,231,239,35,99)
 	end
	else
	begin 
		declare curTable cursor fast_forward
		for 
		select '['+SCHEMA_NAME(SCHEMA_ID)+'].['+o.name+']' tableName,'['+c.name+']' columnName from sys.columns c inner join sys.objects o on c.object_id=o.object_id
			where o.type_desc='user_table' and user_type_id in (56,48,52,59,60,62,106,108,122)
	end
	open curtable
	fetch next from curtable into @tbl,@col
	while @@FETCH_STATUS=0
	begin
		set @sql='if exists (select * from '+@tbl+' where '
		if @type=1
		begin
			set @sql =@sql + @col + ' like ''%'+@str +'%'')'
		end
		else 
		begin
			set @sql =@sql +@col + ' in ('+@str+'))'
		end

		set @sql = @sql +' INSERT #TBL(tbl,col) VALUES('''+@tbl+''','''+@col+''')'
		--print @sql
		exec (@sql)
		fetch next from curtable into @tbl,@col
	end
	close curtable 
	deallocate curtable
	select * from #tbl

--使用例子，查詢庫中存在aaa這個值的列：
--exec  spFind_Column_In_DB  1,'aaa'

由於使用了遊標，使得查詢速度非常之慢~所以不是萬不得已，儘量不要使用！