第十八課
18、Oracle Scheduler調度
作業job
程序program
調度schedule
鏈chain
窗口window
作業類
CJQ0進程:作業隊列協調器
Jnnn進程:運行作業
參數:job_queue_processes
創建作業:
18.1 調度schedule
–基於時間的調度
BEGIN
sys.dbms_scheduler.create_job(job_name => '"OUZY"."JOB1"'
,job_type => 'PLSQL_BLOCK'
,job_action => 'insert into t2 values(sysdate);'
,repeat_interval => 'FREQ=SECONDLY;INTERVAL=10'
,start_date => systimestamp at TIME ZONE
'Asia/Shanghai'
,job_class => '"DEFAULT_JOB_CLASS"'
,auto_drop => FALSE
,enabled => TRUE);
END;
作業的命令類型:
程序、匿名PL/SQL塊、存儲過程、可執行文件、鏈
創建程序program:
–創建程序program1
BEGIN
dbms_scheduler.create_program(program_name => '"OUZY"."PROGRAM1"'
,program_action => 'insert into tbs(name,dt) values(''program1'',sysdate);'
,program_type => 'PLSQL_BLOCK'
,enabled => TRUE);
從作業中抽取作業內容,就可以在多個作業中調用,而不必重複定義。
創建調度:
BEGIN
dbms_scheduler.create_schedule(repeat_interval => 'FREQ=SECONDLY;INTERVAL=10'
,start_date => systimestamp at TIME ZONE
'Asia/Shanghai'
,schedule_name => '"OUZY"."SCHEDULE1"');
END;
創建一個job(使用程序和調度):
BEGIN
dbms_scheduler.create_job(job_name => '"OUZY"."JOB2"'
,program_name => '"OUZY"."PROGRAM1"'
,schedule_name => '"OUZY"."SCHEDULE1"'
,job_class => '"DEFAULT_JOB_CLASS"'
,auto_drop => TRUE
,enabled => TRUE);
END;
18.2 作業鏈
鏈是爲達到組合目標而鏈接在一起的一系列已命名的程序。
運行程序A 然後運行程序B,如果程序A 和程序B 成功完成,則只運行程序C,否則運行程序D。
要啓動一個鏈,必須創建一個作業。
–創建測試表
create table tbs(name varchar2(20),dt date);
–創建程序program1
BEGIN
dbms_scheduler.create_program(program_name => '"OUZY"."PROGRAM1"'
,program_action => 'insert into tbs(name,dt) values(''program1'',sysdate);'
,program_type => 'PLSQL_BLOCK'
,enabled => TRUE);
END;
–創建程序program2
BEGIN
dbms_scheduler.create_program(program_name => '"OUZY"."PROGRAM2"'
,program_action => 'insert into tbs(name,dt) values(''program2'',sysdate);'
,program_type => 'PLSQL_BLOCK'
,enabled => TRUE);
END;
–創建程序program3
BEGIN
dbms_scheduler.create_program(program_name => '"OUZY"."PROGRAM3"'
,program_action => 'insert into tbs(name,dt) values(''program3'',sysdate);'
,program_type => 'PLSQL_BLOCK'
,number_of_arguments => 0
,comments => ''
,enabled => TRUE);
END;
–創建作業鏈
BEGIN
dbms_scheduler.create_chain(chain_name => '"OUZY"."CHAIN1"');
dbms_scheduler.define_chain_step(chain_name => '"OUZY"."CHAIN1"'
,step_name => '"STEP1"'
,program_name => '"OUZY"."PROGRAM1"');
dbms_scheduler.define_chain_step(chain_name => '"OUZY"."CHAIN1"'
,step_name => '"STEP2"'
,program_name => '"OUZY"."PROGRAM2"');
dbms_scheduler.define_chain_step(chain_name => '"OUZY"."CHAIN1"'
,step_name => '"STEP3"'
,program_name => '"OUZY"."PROGRAM3"');
dbms_scheduler.define_chain_rule(chain_name => '"OUZY"."CHAIN1"'
,condition => 'TRUE'
,rule_name => 'RULE001'
,action => 'start step1');
dbms_scheduler.define_chain_rule(chain_name => '"OUZY"."CHAIN1"'
,condition => 'step1 succeeded'
,rule_name => 'RULE002'
,action => 'start step2');
dbms_scheduler.define_chain_rule(chain_name => '"OUZY"."CHAIN1"'
,condition => 'step1 failed'
,rule_name => 'RULE003'
,action => 'start step3');
dbms_scheduler.define_chain_rule(chain_name => '"OUZY"."CHAIN1"'
,condition => 'step2 completed'
,rule_name => 'RULE004'
,action => 'END');
dbms_scheduler.define_chain_rule(chain_name => '"OUZY"."CHAIN1"'
,condition => 'step3 completed'
,rule_name => 'RULE005'
,action => 'END');
dbms_scheduler.enable('"OUZY"."CHAIN1"');
END;
–創建job
BEGIN
dbms_scheduler.create_job(job_name => '"OUZY"."JOB1"'
,job_type => 'CHAIN'
,job_action => '"OUZY"."CHAIN1"'
,repeat_interval => 'FREQ=SECONDLY;INTERVAL=10'
,start_date => systimestamp at TIME ZONE
'Asia/Shanghai'
,job_class => '"DEFAULT_JOB_CLASS"'
,auto_drop => TRUE
,enabled => TRUE);
END;
18.3 窗口
窗口和資源計劃相關聯,都到窗口時間,特定資源計劃被激活,可以控制job的資源使用。
儘量避免窗口重疊。
BEGIN
dbms_scheduler.create_window(window_name => '"WINDOW_TEST"'
,resource_plan => 'DEFAULT_PLAN'
,start_date => systimestamp at TIME ZONE
'Asia/Shanghai'
,duration => numtodsinterval(240, 'minute')
,repeat_interval => 'FREQ=DAILY;BYHOUR=2;BYMINUTE=30;BYSECOND=30'
,end_date => NULL
,window_priority => 'LOW'
,comments => '');
END;
BEGIN
dbms_scheduler.create_job(job_name => '"OUZY"."JOB1"'
,program_name => '"OUZY"."PROGRAM1"'
,schedule_name => '"SYS"."WINDOW_TEST"'
,job_class => '"DEFAULT_JOB_CLASS"'
,auto_drop => TRUE
,enabled => FALSE);
dbms_scheduler.set_attribute(NAME => '"OUZY"."JOB1"'
,attribute => 'stop_on_window_close'
,VALUE => FALSE);
dbms_scheduler.enable('"OUZY"."JOB1"');
END;
–強制打開窗口
BEGIN
dbms_scheduler.open_window(window_name => 'WINDOW_TEST'
,duration => '0 1:00:00'
,force => TRUE);
END;
資源計劃激活,作業運行。
–關閉窗口
BEGIN
dbms_scheduler.close_window(window_name => 'WINDOW_TEST');
END;
作業類:
作業可以被指派一個類,類可以鏈接一個資源計劃。
默認作業類: DEFAULT_JOB_CLASS
select * from dba_scheduler_jobs;
select * from dba_scheduler_schedules;
select * from dba_scheduler_programs;
select * from dba_scheduler_running_jobs;
select * from dba_scheduler_job_log;
select * from dba_scheduler_job_run_details;