Esp8266(NodeMCU)使用MQTT連接巴法雲服務器

  使用MQTT連接巴法雲服務器https://cloud.bemfa.com/,並且使用DS13B20溫度傳感器上傳溫度數據。需要下載安裝MQTT.fx。MQTT下載地址http://mqttfx.org/下載後直接安裝。

完整工程文件下載鏈接https://download.csdn.net/download/weixin_45488643/12533250

註冊巴法雲賬號

  首先註冊巴法雲賬號，在創建一個主題。巴法論壇http://bbs.bemfa.com/conversations/all註冊賬號登陸，在控制檯，可以看到用戶私鑰，唯一識別碼，創建一個主題。

控制檯界面：

Esp8266代碼

#include <ESP8266WiFi.h>//默認，加載WIFI頭文件
#include "PubSubClient.h"//默認，加載MQTT庫文件
#include <OneWire.h>
#include "DallasTemperature.h"
 
#define ONE_WIRE_BUS D2  //DS18B20接口，D3口
 
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);



const char* ssid = "tsy_B5AC58";//修改，你的路由去WIFI名字
const char* password = "19980208";//你的WIFI密碼
const char* mqtt_server = "bemfa.com";//默認，MQTT服務器
const int mqtt_server_port = 9501;//默認，MQTT服務器
#define ID_MQTT  "5bXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX"     //Client ID  修改成自己的,巴法雲用戶私鑰


WiFiClient espClient;
PubSubClient client(espClient);
long lastMsg = 0;
char msg[50];



void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Attempt to connect
    if (client.connect(ID_MQTT)) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}


void setup() {

  sensors.begin();
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server,mqtt_server_port);
  client.setCallback(callback);
}
void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  
  long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;

    sensors.requestTemperatures();
    float temp = sensors.getTempCByIndex(0);
    //snprintf(msg,6,"%.2f",temp); //讀取字符並保存在msg
    dtostrf(temp,2,2,msg); // 要轉換的float或者double值，轉換後整數部分長度，轉換後小數部分長度。保存到該char數組中。
    Serial.println(msg);
    client.publish("DS18b20",msg);//修改DS18b20爲你的主題名
  }
}

MQTT連接界面

  打開MQTT軟件，創建連接

測試

串口數據與巴法雲服務器數對比：
MQTT接收數據：

同過MQTT發送數據到巴法雲服務器：

代碼參考巴法雲論壇。