在数据库运维中,偶尔会碰到需要手动修改lob字段的情况。对于大对象的处理,
并不能直接用update或者insert普通dml操作。通过查找并测试,确认下面方法可行,
并且不会产生乱码。
(仅供参考)
######sql处理lob字段数据#######
--数据库服务器上创建目录,或者使用现有目录
create directory DUMP_DIR as '/data/dump_dir'
--将待处理文件如lob.txt上传到directory目录
--测试表
create table clobtest(col1 cLOB);
--使用dbms_lob.loadfromfile,这个方法网上很多例子,但是实际使用时会产生乱码。
declare
a_clob CLOB;
bfile_name BFILE := BFILENAME('DUMP_DIR','lob.txt');
begin
insert into clobtest values (empty_clob()) returning col1 into a_clob;
dbms_lob.fileopen(bfile_name);
dbms_lob.loadfromfile(a_clob, bfile_name, dbms_lob.getlength(bfile_name));
dbms_lob.fileclose(bfile_name);
commit;
end;
/
--使用DBMS_LOB.LOADCLOBFROMFILE插入clob字段值正常
declare
v_clob CLOB;
bfile_name BFILE := BFILENAME('DUMP_DIR','lob.txt');
dest_offset number :=1;
source_offset number :=1;
src_csid number :=NLS_CHARSET_ID('UTF8');
lang_ctx integer :=DBMS_LOB.DEFAULT_LANG_CTX;
warn integer;
begin
insert into clobtest values (empty_clob()) returning col1 into v_clob;
dbms_lob.fileopen(bfile_name);
DBMS_LOB.LOADCLOBFROMFILE(v_clob,bfile_name,DBMS_LOB.LOBMAXSIZE,dest_offset,source_offset,src_csid,lang_ctx,warn);
dbms_lob.fileclose(bfile_name);
commit;
end;
/
--update CLOB 使用DBMS_LOB.LOADCLOBFROMFILE更新clob字段值正常
declare
v_clob CLOB;
bfile_name BFILE := BFILENAME('DUMP_DIR','lob.txt');
dest_offset number :=1;
source_offset number :=1;
src_csid number :=NLS_CHARSET_ID('UTF8');
lang_ctx integer :=DBMS_LOB.DEFAULT_LANG_CTX;
warn integer;
begin
update clobtest set col1=empty_clob() where rownum=1 returning col1 into v_clob;
dbms_lob.fileopen(bfile_name);
DBMS_LOB.LOADCLOBFROMFILE(v_clob,bfile_name,DBMS_LOB.LOBMAXSIZE,dest_offset,source_offset,src_csid,lang_ctx,warn);
dbms_lob.fileclose(bfile_name);
commit;
end;
/