SAP的一個類cl_salv_events_table提供了幾個常用的事件，包括鏈接點擊，雙擊，功能觸發之前和觸發之後，頁眉頁腳（其中頁眉頁腳暫時測試不成功，以後再試）。跟其他事件相比，類CL_SALV_EVENTS_TABLE提供了這幾個常用的事件已經和ALV結合在一起，所以我們只要實現這幾個事件的處理方法就可以了。
1. 首先我們要定義好事件的處理方法。
CLASS-METHODS: on_user_command FOR EVENT added_function OF cl_salv_events_table
IMPORTING e_salv_function,
on_double_click FOR EVENT double_click OF cl_salv_events_table
IMPORTING row column,
on_link_click FOR EVENT link_click OF cl_salv_events_table
IMPORTING row column,
on_before_salv_function FOR EVENT before_salv_function OF cl_salv_events_table
IMPORTING e_salv_function,
on_after_salv_function FOR EVENT after_salv_function OF cl_salv_events_table
IMPORTING e_salv_function.
2. 實現事件的處理方法。
*單擊新增功能按鈕事件處理方法
METHOD on_user_command.
CONCATENATE 'Function Code is '
e_salv_function
INTO g_string SEPARATED BY space.
MESSAGE i000(0k) WITH g_string.
ENDMETHOD. "on_user_command
*雙擊事件處理方法
METHOD on_double_click.
g_string = row.
CONCATENATE 'DOUBLE CLICK'
'ROW'
g_string
'COLUMN'
column
INTO g_string SEPARATED BY space.
MESSAGE i000(0k) WITH g_string.
ENDMETHOD. "on_double_click
*單擊事件處理方法
METHOD on_link_click.
g_string = row.
CONCATENATE 'LICK CLICK'
'ROW'
g_string
'COLUMN'
column
INTO g_string SEPARATED BY space.
MESSAGE i000(0k) WITH g_string.
ENDMETHOD. "on_link_click
*觸發事件之前
METHOD on_before_salv_function.
CONCATENATE 'Before Function '
e_salv_function
INTO g_string SEPARATED BY space.
MESSAGE i000(0k) WITH g_string.
ENDMETHOD. "on_before_salv_function
*觸發事件之後
METHOD on_after_salv_function.
CONCATENATE 'After Function '
e_salv_function
INTO g_string SEPARATED BY space.
MESSAGE i000(0k) WITH g_string.
ENDMETHOD. "on_after_salv_function
3. 取得ALV事件的實例
lr_events = gr_table->get_event( ).
4. 註冊事件的處理方法
SET HANDLER lcl_handle_events=>on_user_command FOR lr_events.
SET HANDLER lcl_handle_events=>on_double_click FOR lr_events.
SET HANDLER lcl_handle_events=>on_link_click FOR lr_events.
SET HANDLER lcl_handle_events=>on_before_salv_function FOR lr_events.
SET HANDLER lcl_handle_events=>on_after_salv_function FOR lr_events.
下面是效果圖
下面是程序的所有代碼:
REPORT y_xin_002.
INCLUDE <icon>.
*變量定義
TYPES: BEGIN OF gs_spfli,
mandt TYPE spfli-mandt,
carrid TYPE spfli-carrid,
connid TYPE spfli-connid,
countryfr TYPE spfli-countryfr,
cityfrom TYPE spfli-cityfrom,
airpfrom TYPE spfli-airpfrom,
countryto TYPE spfli-countryto,
cityto TYPE spfli-cityto,
airpto TYPE spfli-airpto,
fltime TYPE spfli-fltime,
deptime TYPE spfli-deptime,
arrtime TYPE spfli-arrtime,
distance TYPE spfli-distance,
distid TYPE spfli-distid,
fltype TYPE spfli-fltype,
period TYPE spfli-period,
hotspot TYPE icon_d,
END OF gs_spfli.
TYPES ty_spfli TYPE gs_spfli OCCURS 0.
*----------------------------------------------------------------------*
* CLASS lcl_handle_events DEFINITION
*----------------------------------------------------------------------*
* 事件操作類（定義）
*----------------------------------------------------------------------*
CLASS lcl_handle_events DEFINITION.
PUBLIC SECTION.
CLASS-METHODS: on_user_command FOR EVENT added_function OF cl_salv_events_table
IMPORTING e_salv_function,
on_double_click FOR EVENT double_click OF cl_salv_events_table
IMPORTING row column,
on_link_click FOR EVENT link_click OF cl_salv_events_table
IMPORTING row column,
on_before_salv_function FOR EVENT before_salv_function OF cl_salv_events_table
IMPORTING e_salv_function,
on_after_salv_function FOR EVENT after_salv_function OF cl_salv_events_table
IMPORTING e_salv_function.
PRIVATE SECTION.
CLASS-DATA: g_string TYPE string.
ENDCLASS. "lcl_handle_events DEFINITION
*----------------------------------------------------------------------*
* CLASS lcl_handle_events IMPLEMENTATION
*----------------------------------------------------------------------*
* 事件操作類（實現）
*----------------------------------------------------------------------*
CLASS lcl_handle_events IMPLEMENTATION.
*單擊新增功能按鈕事件處理方法
METHOD on_user_command.
CONCATENATE 'Function Code is '
e_salv_function
INTO g_string SEPARATED BY space.
MESSAGE i000(0k) WITH g_string.
ENDMETHOD. "on_user_command
*雙擊事件處理方法
METHOD on_double_click.
g_string = row.
CONCATENATE 'DOUBLE CLICK'
'ROW'
g_string
'COLUMN'
column
INTO g_string SEPARATED BY space.
MESSAGE i000(0k) WITH g_string.
ENDMETHOD. "on_double_click
*單擊事件處理方法
METHOD on_link_click.
g_string = row.
CONCATENATE 'LICK CLICK'
'ROW'
g_string
'COLUMN'
column
INTO g_string SEPARATED BY space.
MESSAGE i000(0k) WITH g_string.
ENDMETHOD. "on_link_click
*觸發事件之前
METHOD on_before_salv_function.
CONCATENATE 'Before Function '
e_salv_function
INTO g_string SEPARATED BY space.
MESSAGE i000(0k) WITH g_string.
ENDMETHOD. "on_before_salv_function
*觸發事件之後
METHOD on_after_salv_function.
CONCATENATE 'After Function '
e_salv_function
INTO g_string SEPARATED BY space.
MESSAGE i000(0k) WITH g_string.
ENDMETHOD. "on_after_salv_function
ENDCLASS. "lcl_handle_events IMPLEMENTATION
*----------------------------------------------------------------------*
* CLASS lcl_alv DEFINITION
*----------------------------------------------------------------------*
* ALV操作類（定義）
*----------------------------------------------------------------------*
CLASS lcl_alv DEFINITION.
PUBLIC SECTION.
METHODS: getdata "取得要顯示的數據
RETURNING value(lt_tab) TYPE ty_spfli,
alv_full "全屏Grid列表處理方法
IMPORTING value(lt_tab) TYPE ty_spfli.
PRIVATE SECTION.
DATA: gr_table TYPE REF TO cl_salv_table.
ENDCLASS. "lcl_alv DEFINITION
*----------------------------------------------------------------------*
* CLASS lcl_alv IMPLEMENTATION
*----------------------------------------------------------------------*
* ALV操作類（實現）
*----------------------------------------------------------------------*
CLASS lcl_alv IMPLEMENTATION.
*取得要顯示的數據
METHOD getdata.
SELECT * INTO CORRESPONDING FIELDS OF TABLE lt_tab FROM spfli.
FIELD-SYMBOLS <fs_spfli> TYPE gs_spfli.
LOOP AT lt_tab ASSIGNING <fs_spfli>.
<fs_spfli>-hotspot = icon_overview.
ENDLOOP.
ENDMETHOD. "getdata
*輸出全屏網格列表的方法
METHOD alv_full.
DATA: lr_functions TYPE REF TO cl_salv_functions_list,
lr_events TYPE REF TO cl_salv_events_table,
lr_columns TYPE REF TO cl_salv_columns_table,
lr_column TYPE REF TO cl_salv_column_table,
lr_content TYPE REF TO cl_salv_form_element.
"創建實例
TRY.
cl_salv_table=>factory(
IMPORTING
r_salv_table = gr_table
CHANGING
t_table = lt_tab
).
CATCH cx_salv_msg.
ENDTRY.
"設置GUI Status
gr_table->set_screen_status(
report = sy-repid
pfstatus = 'SALV_STANDARD'
set_functions = gr_table->c_functions_all
).
"設置熱點
lr_columns = gr_table->get_columns( ).
TRY.
lr_column ?= lr_columns->get_column( 'HOTSPOT' ).
lr_column->set_cell_type( if_salv_c_cell_type=>hotspot ).
lr_column->set_long_text( 'HOTSPOT' ).
CATCH cx_salv_not_found.
ENDTRY.
"註冊事件
lr_events = gr_table->get_event( ).
SET HANDLER lcl_handle_events=>on_user_command FOR lr_events.
SET HANDLER lcl_handle_events=>on_double_click FOR lr_events.
SET HANDLER lcl_handle_events=>on_link_click FOR lr_events.
SET HANDLER lcl_handle_events=>on_before_salv_function FOR lr_events.
SET HANDLER lcl_handle_events=>on_after_salv_function FOR lr_events.
"顯示列表
gr_table->display( ).
ENDMETHOD. "alv_full
ENDCLASS. "lcl_alv IMPLEMENTATION
*&---------------------------------------------------------------------*
*& Form f_main
*&---------------------------------------------------------------------*
* 整合數據，執行
*----------------------------------------------------------------------*
FORM f_main.
DATA: lt_tab TYPE ty_spfli,
lr_alv TYPE REF TO lcl_alv.
CREATE OBJECT lr_alv.
"取得要顯示的數據
lt_tab = lr_alv->getdata( ).
lr_alv->alv_full( lt_tab ).
ENDFORM. "f_main
*執行動作
START-OF-SELECTION.
PERFORM f_main.