第十五章 Caché 函數大全 $FACTOR 函數 第十五章 Caché 函數大全 $FACTOR 函數 大綱 描述 參數 示例

第十五章 Caché 函數大全 $FACTOR 函數

將整數轉換爲$BIT位字符串。

大綱

$FACTOR(num,scale)

參數

• num 計算結果爲數字的表達式。 num在位串轉換之前轉換爲正整數。負數將轉換爲正數（其絕對值）。小數舍入爲整數。
• scale 可選-整數，用作整數的十進制冪（科學計數法）乘數。默認值爲0。

描述

$FACTOR返回與提供的整數的二進制表示形式相對應的$BIT格式位串。它執行以下操作：

• 如果指定負數，則$FACTOR取數字的絕對值。
• 如果指定小數位數，則$FACTOR將整數乘以10 **小數位數。
• 如果指定小數，則$FACTOR會將其四捨五入爲整數。四捨五入時，Caché將小數.5舍入到下一個最大整數。
• $FACTOR將整數轉換爲其二進制表示形式。
• $FACTOR將此二進制數轉換爲$BIT編碼的二進制格式。

返回的二進制字符串指定從位置1(位置1的位置)的最低有效位開始的位位置。這對應於各種$BIT函數使用的位串。

參數

num

數字(或計算結果爲數字的表達式)。$factor應用Scale參數(如果提供)，通過四捨五入將此數字轉換爲整數，然後返回相應的位串。Num可以是正數，也可以是負數。如果num是混合數字字符串(例如“7wwarves”或“5.6.8”)，$factor將轉換字符串的數字部分(在我們的示例中爲7和5.6)，直到遇到非數字字符。如果num爲零、四捨五入爲零、空字符串(“”)或非數字字符串，則$factor返回空字符串。$DOUBLE值INF、-INF和NaN返回空字符串。

scale

一個整數，它指定要應用於Num的科學計數法指數。例如，如果比例爲2，則比例表示10指數2或100。該比例值乘以Num。例如，$factor(7，2)返回與整數700對應的位串。此乘法是在將num舍入爲整數之前完成的。默認情況下，比例爲0。

示例

下面的示例顯示了從整數1到9到位串的轉換：

/// d ##class(PHA.TEST.Function).FACTOR()
ClassMethod FACTOR()
{
    SET x=1
    WHILE x<10 {
    WRITE !,x,"="
        FOR i=1:1:8 {
            WRITE $BIT($FACTOR(x),i) 
        }
        SET x=x+1 
    }
}

DHC-APP>d ##class(PHA.TEST.Function).FACTOR()
 
1=10000000
2=01000000
3=11000000
4=00100000
5=10100000
6=01100000
7=11100000
8=00010000
9=10010000

下面的示例顯示$FACTOR將負數和小數轉換爲正整數：

/// d ##class(PHA.TEST.Function).FACTOR1()
ClassMethod FACTOR1()
{
    FOR i=1:1:8 {WRITE $BIT($FACTOR(17),i)}
    WRITE " 正整數",!
    FOR i=1:1:8 {WRITE $BIT($FACTOR(-17),i)}
    WRITE " 負整數 (絕對值)",!
    FOR i=1:1:8 {WRITE $BIT($FACTOR(16.5),i)}
    WRITE " 正小數（四捨五入）",!
    FOR i=1:1:8 {WRITE $BIT($FACTOR(-16.5),i)}
    WRITE " 負小數（四捨五入）",!
    FOR i=1:1:8 {WRITE $BIT($FACTOR(-16.4),i)}
    WRITE " 負小數（四捨五入）"
}

DHC-APP>d ##class(PHA.TEST.Function).FACTOR1()
10001000 正整數
10001000 負整數 (絕對值)
10001000 正小數（四捨五入）
10001000 負小數（四捨五入）
00001000 負小數（四捨五入）

以下示例顯示了在指定scale參數時返回的位串：

/// d ##class(PHA.TEST.Function).FACTOR2()
ClassMethod FACTOR2()
{
    SET x=2.7
    WRITE !,x," scaled then rounded to an integer:",!!
    FOR i=1:1:12 {
        WRITE $BIT($FACTOR(x),i) 
    }
    WRITE " binary = ",$NORMALIZE(x,0)," decimal",!
    SET scale=1
    SET y=x*(10**scale)
    FOR i=1:1:12 {
        WRITE $BIT($FACTOR(x,scale),i) 
    }
    WRITE " binary = ",$NORMALIZE(y,0)," decimal",!
    SET scale=2
    SET y=x*(10**scale)
    FOR i=1:1:12 {
        WRITE $BIT($FACTOR(x,scale),i) 
    }
    WRITE " binary = ",$NORMALIZE(y,0)," decimal"
}

DHC-APP>d ##class(PHA.TEST.Function).FACTOR2()
 
2.7 scaled then rounded to an integer:
 
110000000000 binary = 3 decimal
110110000000 binary = 27 decimal
011100001000 binary = 270 decimal