王爽《彙編語言》實驗七：將data段數據按格式寫到table段中

 

assume cs:codesg,ds:data,ss:stack,es:table
data segment
  db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
  db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
  db '1993','1994','1995'

  dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
  dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000
  dd 5937000

  dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
  dw 11542,14430,15257,17800
data ends
table segment
  db 21 dup('year summ ne ?? ')
table ends
stack segment
  db 16 dup(?)
stack ends
codesg segment
start:mov ax,data
      mov ds,ax
      mov ax,table
      mov es,ax
      mov ax,stack
      mov ss,ax
      mov sp,10h
      mov bx,0
      mov di,0
      mov cx,21
   s1:push cx
      mov cx,4
   s2:mov al,ds:[si]
      mov es:[bx+di],al
      mov al,ds:[54h+si]
      mov es:[bx+5h+di],al
      inc si
      inc di
      loop s2
      mov di,0
      add bx,10h
      pop cx
      loop s1

      mov si,0
      mov bx,0
      mov cx,21
   s3:mov ax,ds:[0a8h+si]
      mov es:[bx+0ah],ax
      add si,2
      add bx,10h
      loop s3

      mov bx,0
      mov cx,21
   s4:mov ax,es:[bx+5h]
      mov dx,es:[bx+7h]
      div word ptr es:[bx+0ah]
      mov es:[bx+0dh],ax
      add bx,10h
      loop s4

      mov ax,4c00h
      int 21h
codesg ends
end  start