ARM彙編筆記（2）——函數調用規則

（本文所介紹的各個約定與32位arm Linux系統C語言toolchain一致）

1. 棧
棧保存着函數調用中的參數，寄存器上下文，局部變量。ARM中函數返回地址是寄存器上下文的一部分（lr），無需單列。
棧由高地址向低地址增長，也就是說push會導致棧頂指針指向較低的地址，而pop則相反。
同時約定了棧頂指針指向的是入棧的最後一個值的位置，而非下一個入棧位置。

2. 控制轉移和寄存器上下文
高級語言的函數調用在arm彙編中通過bl和bxl指令來實現。
bl和bxl在執行時只做了兩件事：1）pc值存入lr；2）更新pc。因此，諸如寄存器上下文保存和恢復等操作必須由被調用者完成。
被調用函數保存寄存器上下文時，只需保存自己將要使用的寄存器的值即可。r0~r3無需作爲上下文進行保存。這裏要注意的是如果被調用者同時也調用了其他函數的話必須保存lr（返回地址），因爲lr將在內部的調用中被改寫。
在函數返回時，如果lr被保存，將該值從內存中讀出賦給pc即可；否則當前lr即爲返回地址，直接bx lr。

3. 參數傳遞
參數的前4個字（32*4 bits）通過寄存器r0~r3來傳遞，多出的內容從棧上傳遞。對於小於一個字長度的參數（如char, short類型）也當作一個字來傳。C語言中arm與x86相同，參數都是按照由右向左的順序壓棧，參數的退棧由調用者負責。

4. 返回值
對於返回值，如果大小在一個字以內直接存入r0即可。
若返回值大小大於一個字長度（比如一個結構體），則該函數實際上會被改寫，例如：

typedef struct {
    int v1;
    int v2;
} data_t;

data_t test(int a, int b) {
    data_t r;
    r.v1 = a+b;
    r.v2 = a-b;
    return r;
}

test函數會在編譯器內部被改寫成：

void test(data_t *r, int a, int b) {
    r->v1 = a+b;
    r->v2 = a-b;
}

調用者的代碼也會在編譯器內部做相應調整。
這樣一來，在彙編層，調用者會把分配好的data_t指針賦值給r0，然後再把a和b賦值給r1和r2。至於返回值，可以認爲是void，也可以認爲直接將data_t的指針返回了。

5. 實例

5.1 最簡單的函數

int test(int a, int b) {
    return a + b;
}

彙編爲

test:
add r0, r0, r1     ;test沒有調用其它函數，所以不用保存lr的上下文
bx  lr             ;返回

5.2 調用其它函數

int test(int a, int b) {
    return a + b;
}

int test2(int a, int b, int c, int d) {
    int e = test(a+b, c-d);
    return a + b + e;
}

彙編爲

test:
add r0, r0, r1
bx  lr

test2:
push   {r4, r5, lr}   ;保存寄存器上下文
mov    r4, r0         ;r4 = a
mov    r5, r1         ;r5 = b
add    r0, r0, r1     ;r0 = a + b
sub    r1, r2, r3     ;r1 = c - d
bl     test           ;調用test
mov    r2, r0         ;r2 = e
add    r0, r4, r5     ;r0 = a + b
add    r0, r0, r2     ;r0 = a + b + e
pop    {r4, r5, pc}   ;恢復寄存器上下文並返回

5.3 帶有多於4個字的參數的函數及其調用

int test(int a, int b, int c, int d,
         int e, int f) {
    return a+b+c+d+e+f;
}

int test2() {
    return test(1,2,3,4,5,6);
}

彙編爲

test:
add   r0, r0, r1     ;r0 = a+b
add   r0, r0, r2     ;r0 = a+b+c
add   r0, r0, r3     ;r0 = a+b+c+d
ldr   r1, [sp, #0]   ;r1 = e
ldr   r2, [sp, #4]   ;r2 = f
add   r0, r0, r1     ;r0 = a+b+c+d+e
add   r0, r0, r2     ;r0 = a+b+c+d+e+f
bx    lr             ;返回

test2:
push  {lr}           ;保存寄存器上下文
mov   r0, #5         ;r0 = 5
mov   r1, #6         ;r1 = 6
push  {r1, r0}       ;壓棧，6在高地址5在低地址
mov   r0, #1         ;r0 = 1
mov   r1, #2         ;r1 = 2
mov   r2, #3         ;r2 = 3
mov   r3, #4         ;r3 = 4
bl    test           ;調用test
add   sp, sp, #8     ;退棧，釋放之前爲參數5和6分配的空間
pop   {pc}           ;恢復寄存器上下文並返回

5.4 結構體作爲參數和返回值

typedef struct {
    int a;
    int b;
} data_t;

data_t test(data_t c) {
    return (data_t){c.a + c.b, c.a - c.b};
}

int test2(int a, int b) {
    data_t x = {a, b};
    data_t y = test(x);
    return y.a + y.b;
}

彙編爲（經過一定優化）

test:
add   r3, r1, r2       ;r3 = c.a + c.b
str   r3, [r0]         ;r0->a = c.a + c.b
sub   r3, r1, r2       ;r3 = c.a - c.b
str   r3, [r0, #4]     ;r0->b = c.a - c.b
bx    lr               ;返回

test2:
push  {lr}             ;保存寄存器上下文
push  {r1, r0}         ;x = {a, b}
sub   sp, sp, #8       ;y = {    }
mov   r0, sp           ;r0 = &y
ldr   r1, [sp, #8]     ;r1 = x.a
ldr   r2, [sp, #12]    ;r2 = x.b
bl    test             ;調用test
ldr   r1, [r0]         ;r1 = y.a
ldr   r2, [r0, #4]     ;r2 = y.b
add   r0, r1, r2       ;r0 = y.a + y.b
add   sp, sp, #16      ;退棧，釋放x和y的空間
pop   {pc}             ;恢復寄存器上下文並返回