Doevents用法

VB6.0
Windows98
我要實現一個類似Windows複製(移動)文件時的提示窗體,耗時很長,且要求中斷後能繼續未完成的操作,不知使用DoEvents從長循環中跳出後,程序將從何處開始繼續執行,是否是從DoEvents所在的Sub開始?(倔小孩)

事實上僅使用DoEvents，並不意味着從長循環中跳出。DoEvents只是允許用戶選擇其他按鈕而已，不中斷循環，不管用戶如何操作，都繼續執行 DoEvents後面的語句，即使用戶按下了中斷按鈕，你的循環仍然在繼續，甚至你關閉了窗體，程序仍然繼續在後臺運行。正確的中斷處理是這樣的：
1、建立一個全局或窗體變量bRun。
2、在啓動循環前設置bRun爲True。
bRun = True
While bRun And (....)
....
DoEvents
Wend
...
3、在中斷按鈕Click事件中加入代碼：
bRun = False
4、在Form_Unload事件中加入代碼：
bRun = False
這樣一旦用戶按下了中斷按鈕，bRun = False，循環的條件就不滿足了，所以退出循環，執行後續語句。你也可以採用下面的方式：
bRun = True
While ....
If Not bRun Then
Exit Sub
End If
....
DoEvents
Wend
...

郭勇的意見：
《解析 事件，Doevents,閒置循環和控時循環中的難點問題》
Visualbasic6.0 代碼
copyright guoyong in cqums(2004-2-26)
關鍵問題歸於doevents 函數
DoEvents函數的功能是：轉讓控制權，以便讓操作系統處理其它的事件。
問:爲什麼要用doevents?
A.在需要用某一循環處理相當耗時或者很快速的代碼時,就需要用到它,以便用戶能在起處理過程中能做其他事情,即程序能被控制,而不是無響應狀態
B.vb6.0中多線程vb代碼極度不穩定,而且無法調試,所以vb中的多線程用的很少(注:是指vb的代碼在多線程中運行時不穩定)
C.timer控件可以起到後臺運行作用,但其是通過事件控制,一是不穩定,二是速度太慢,如果想用其處理高速又耗系統的代碼更本不能達到預期的效果

下面將其某些用法和難點簡介如下:

(注: '** 後面的代碼表示如果在該處用了這個語句
以下代碼中用到了一些api函數,請用vb附帶的api瀏覽器查閱)

一. 基本用法:
1.窗體啓動時如果要處理的事務太多或者用sleep函數暫停,造成其很久都不能出現時怎麼辦?
例如代碼:
Private Sub Form_Load()
Show
'**DoEvents
Sleep 5000
End Sub
通常容易想到在sleep前加個show,但還是不能達到預想的效果,窗體雖然出來了,但好象只達到了一半,如果加上第3句,將看到效果大不相同

2.如果有個很耗時的循環導致程序不響應,怎麼辦?
例如:
Dim L As Long
For L = 1 To 1000000
'** DoEvents
Next L
如果無'**,在循環過程中程序無法處理事件,對於用戶來說是不響應,無法控制的
3.想在循環中看到處理過程?
同樣:
Dim L As Long
For L = 1 To 10000
'** DoEvents
Text1.Text=Cstr(l)
Next L
無'** 時將無法看到text1中的變化,而只在循環結束時看到最後結果
4.怎樣中止循環?
如果有:
Private Sub Command3_Click()
Dim L As Long
Do
L = L + 1
Debug.Print L
DoEvents
Loop
End Sub
會發現當關閉窗口後,debug中的數據仍然在變化,說明並沒結束
需要如下:
Dim IsExit As Boolean
Private Sub Command1_Click()
Dim L As Long
IsExit = False
Do While DoEvents
If IsExit = True Then Exit Do
L = L + 1
Loop

End Sub

Private Sub Command2_Click()''或者在form_unload模塊中等等
IsExit = True
End Sub
其中 isexit是全局變量
<>有些人喜歡用end語句來結束程序,小程序固然可以,但當太大,或者調用了某些特殊的api函數後可能導致預想不到的錯誤,如果裝載了許多東西在程序結束時不處理將卸載很慢,而且這種做法也極不符合正規軟件的要求...總之end語句毛病很多,此不詳談,建議少使用甚至不使用

二. 其基本用法大概就這些,現在解析其中的一些[難點]

1.爲什麼還是不能結束?
代碼如下:
Dim IsExit As Boolean
Private Sub Command1_Click()
Dim L As Long
IsExit = False
Do
If IsExit = True Then Exit Do '句0
DoEvents '** 句1
Text1.Text = CStr(L) '** 句2
L = L + 1
Loop
End Sub

Private Sub Form_Load()
Static N As Long
N = N + 1
MsgBox N
End Sub

Private Sub Form_Unload(Cancel As Integer)
IsExit = True
End Sub

運行結果:啓動時msg顯示1,點擊command1,text1在變化
此時再點form右上角的小差(關閉窗體),發現vb運行控制上的按扭並沒變化,說明程序還在運行.如果編譯成程序後運行,按下ctrl+del+alt也可發現它還沒結束.
通過讀代碼,並沒發現錯誤，怎麼回事?

關鍵在於 句2 訪問了控件的屬性
代碼運行路徑:當在doevents 時,程序釋放控制權,可以接收事件消息,form-unload事件只能從此處產生,假設此時關閉form ,unload事件發生,即doevents後就運行unload代碼,得到isexit=t,並且form卸載,代碼返回到doevents 之後,運行 句2.注意現在form 已經卸載了,text1從哪裏來呢?
於是form重新裝載,代碼跳到form_load模塊運行,所以在關閉窗體後可以看到msg 顯示2,此模塊運行完後再繼續句2後面的代碼,當下次循環遇到 句0時退出循環
另:既然退出了循環,怎麼還不能結束?
vb程序規定(其實其他的windows語言一樣):窗體卸載時並不是立即卸載其模塊代碼,而只先卸載窗體中的控件和一些屬性值,程序中最後一個窗體卸載時才完全卸載.
在這個單窗體程序中,form卸載時因爲循環的控制無法卸載代碼,失去了卸載代碼的機會,導致再也不能卸載(因爲沒卸載代碼,所以運行的 句2 是並不會出錯)
另:既然再次運行了form_load代碼,怎麼看不見窗體?
因爲程序啓動時窗體的到顯示的消息,而只運行此模塊並沒有(如果在msgbox n語句前加上show,就可以看到它了)
如何解決?
通過以上分析,應該很簡單,把句1 和句2調換一下就可以了,關鍵:
<仔細分析代碼是如何運行的,避免在form已經卸載了情況下訪問控件>

2.用了doevents速度太慢了怎麼辦?
doevents的代價是速度變慢,但要程序響應又不得不用
其實doevents語句允許任何應用程序執行相關事件，而不僅僅是你自己的程序,所以變得很慢.
可以讓它響應本程序事件動作,需要用到api函數GetInputState
例如用: If GetInputState() Then DoEvents '來代替doevents可使循環運行更快

3.既要同時響應事件又要控件不變化,怎麼辦?
例如在一個長的循環中向listview控件中添加記錄,無doevents時程序無響應,但有它時控件又閃的厲害
解決辦法:a.不一定每次循環都doevents,可以在適當時間時才用,至少沒那麼閃
b.應用api函數 ValidateRect 功能是使指定的矩型區域生效,通知Windows不對指定的區域進行重畫另:InvalidateRect 功能相反,同時需要用到函數 GetClientRect 取得指定對象的矩形區域應用*rect函數指定listview的矩形區不重畫,即可避免閃爍(但還是要注意恢復重畫,否則看不見了真實效果)

4.控時循環和變速齒輪
請看下面的代碼:
Option Explicit
Private Declare Function timeGetTime Lib "winmm.dll" () As Long
Dim IsExit As Boolean
Private Sub Command1_Click()
Dim L As Long
Dim Kt As Long
IsExit = False
Do
Kt = timeGetTime()
'do something
L = L + 1
Text1.Text = L
'DoEvents '句 1
While timeGetTime - Kt < 50 '句 2
'While Abs(timeGetTime - Kt) < 50 '句 3
'While Abs(timeGetTime - Kt) And (Not IsExit) < 50 '句 4

DoEvents '句 5
Wend
'DoEvents '句 6
If IsExit Then Exit Do
Loop
End Sub

Private Sub Form_Unload(Cancel As Integer)
IsExit = True
End Sub
其中可用的代碼(除去加"'" 號的代碼)就是通常的控時循環代碼
運行代碼並不會出現錯誤,但在循環過程,請開啓變速齒輪看看
當關閉齒輪時,將發現text1.text停止了,別慌,等一段時間它又會繼續(這要看你設定的時間,這裏是50毫秒,如果設定的太長text1.text將半天都沒變化,這是怎麼回事?
變速齒輪在啓動時將hook.dll映射到你的程序地址運行,更改了timegettime()函數獲取的時間
如果在句2和句3間插入debug.print timegettime,timegettime-kt 將發現,在關閉齒輪的瞬間後者變成了負值,timegettime變小了,所以才造成需要等很久
如果是編寫遊戲,而用戶開了齒輪,那可就慘了

解決方案:
a.用句3代替句2,這個方法最簡便,雖然不符實,但不會出問題,建議使用
b.不要句5,換用句6(這樣就能達到效果嗎?) 因爲齒輪還是從doevents語句運行時才能插的進來,所以只要kt=timegettime 和 timegettime之間沒有doevents就不會出錯
ab.兩種方法都有些小問題,但無大礙,有興趣者請自己分析

5.程序怎麼"死了"?
這只是一些人編寫時沒注意到的小問題,提醒一下:
同樣用上面的代碼,如果設定的時間太短,以至在代碼運行到句2時已經超時了,句5將不能運行了,當然程序就死了哦,以防萬一,加上句1,所以此時也只能用a方案來解決齒輪的問題了
有必要用句4代替句3 嗎? 除非你設定的時間太長,人家想關閉你的程序要等上好半天

好了,也差不多,該收工了,如果有什麼忘了說,你又想知道的話,可以來和我一起探討
若有什麼錯了的請指正,謝謝!
希望你能把程序寫的更好!