ByVal和ByRef的區別

                                     

ByVal 傳送參數內存的一個拷貝給被調用者。也就是說，棧中壓入的直接就是所傳的值。

ByRef 傳送參數內存的實際地址給被調用者。也就是說，棧中壓入的是實際內容的地址。被調用者可以直接更改該地址中的內容。

ByVal是傳遞值 源數據不會被修改
你可以把這個值當作自己的局部變量來使用

ByRef是傳遞地址 ， 源數據可能被修改
你對這個變量的操作將對你傳入的那個變量產生影響，就像指針的感覺

 

實例：

sub Add1(ByVal no as int32)
    no=no+100
end sub

sub Add2(ByRef no as int32)
    no=no+100
end sub

private sub button1_click(sender as object,e as eventargs)handles button1.click
    dim a as int32
    a=100
    Add1(a)
    msgbox ("a的值爲：" & a)     '顯示：a的值爲100

    Add2(a)
    msgbox ("a的值爲：" & a)     '顯示：a的值爲200,因爲Add2中的參數no爲ByRef,即
                                 '按地址傳遞，因此在Add2中對no進行修改後，將會導致
                                 '源參數a的值也被修改。
End Sub

——————————————————————————————————————

3、ByVal和ByRef
    ByVal傳遞的參數值，而ByRef傳遞的參數的地址。在這裏，我們不用去區別傳指針/傳地址/傳引用的不同，在VB裏，它們根本就是一個東西的三種不同說法，即使VB的文檔裏也有地方在混用這些術語（但在C++裏的確要區分指針和引用）
    初次接觸上面的程序二SwapPtr的朋友，一定要搞清在裏面的CopyMemory調用中，在什麼地方要加ByVal，什麼地方不加（不加ByVal就是使用VB缺省的ByRef）
    準確的理解傳值和傳地址（指針）的區別，是在VB里正確使用指針的基礎。
    現在一個最簡單的實驗來看這個問題，如下面的程序三：
【程序三】：'體會ByVal和ByRef
    Sub TestCopyMemory()
        Dim k As Long
        k = 5
Note:   CopyMemory ByVal VarPtr(k), 40000, 4
        Debug.Print k
    End Sub
    上面標號Note處的語句的目的，是將k賦值爲40000，等同於語句k=40000，你可以在"立即"窗口試驗一下，會發現k的值的確成了40000。
    實際上上面這個語句，翻譯成白話:
 -----------------------------------------------------------------
 就是從保存常數40000的臨時變量處拷貝4個字節到變量k所在的內存中。
 -----------------------------------------------------------------
    現在我們來改變一個Note處的語句，若改成下面的語句：
Note2:   CopyMemory ByVal VarPtr(k), ByVal 40000, 4
    這句話的意思就成了，從地址40000拷貝4個字節到變量k所在的內存中。由於地址40000所在的內存我們無權訪問，操作系統會給我們一個Access Violation內存越權訪問錯誤，告訴我們"試圖讀取位置0x00009c40處內存時出錯，該內存不能爲'Read'"。
    我們再改成如下的語句看看。
Note3:   CopyMemory VarPtr(k), 40000, 4
    這句話的意思就成了，從保存常數40000的臨時變量處拷貝4個字節到到保存變量k所在內存地址值的臨時變量處。這不會出出內存越權訪問錯誤，但k的值並沒有變。
    我們可以把程序改改以更清楚的休現這種區別，如下面的程序四：
【程序四】：'看看我們的東西被拷貝到哪兒去了
    Sub TestCopyMemory()
        Dim i As Long, k As Long
        k = 5
        i = VarPtr(k)
NOTE4:  CopyMemory i, 40000, 4
        Debug.Print k
        Debug.Print i
        i = VarPtr(k)
NOTE5:  CopyMemory ByVal i, 40000, 4
        Debug.Print k
    End Sub

程序輸出：
5
40000
40000
    由於NOTE4處使用缺省的ByRef，傳遞的是i的地址（也就是指向i的指針），所以常量40000拷貝到了變量i裏，因此i的值成了40000，而k的值卻沒有變化。但是，在NOTE4前有：i=VarPtr(k)，本意是要把i本身做爲一個指針來使用。這時，我們必須如NOTE5那樣用ByVal來傳遞指針i，由於i是指向變量k的指針，所以最後常量40000被拷貝了變量k裏。