delphi調用chrome內核進行瀏覽

       隨着Chrome瀏覽器的使用範圍越來越多，而且Chrome不挑食，基本上什麼系統都可以跑，而且速度那是飛快，所以C/S程序調用第三方的B/S程序或者網頁時都考慮使用支持最新H5技術的內核，而Delphi的瀏覽控件那真心是不支持很多新的東西，而且還是微軟的內核，各種的水士不符，沒有辦法只能想其他辦法。

      經過尋找最終發現CEF4delphi項目，CEF4Delphi 是由 SalvadorDíazFau 創建的一個開源項目，用於在基於Delphi的應用程序中嵌入基於Chromium的瀏覽器。CEF4Delphi 基於Henri Gourvest 公司的 DCEF3。DCEF3的原始許可證仍適用於CEF4Delphi。閱讀任何* .pas文件的第一行中的許可條款。

      控件的下載地址：https://github.com/salvadordf/CEF4Delphi/archive/master.zip

      軟件編譯後的運行環境下載：http://opensource.spotify.com/cefbuilds/index.html

說明一下運行環境，由於是調用的Chrome內核，所以就有一堆的dll文件要與Chrome進行交互，程序編譯後如果沒有這些文件支持，就會如下的提示

    

除了準備以上的材料以外，安裝最新版的Chrom也是必須的，這樣我們就可以開始進入調用的過程了

1.安裝控件

將下載下來的CEF4Delphi-master.zip文件解壓到Delphi目錄下，例如：

然後將程序的source路徑加入到library路徑中，同時要注意32位、64位的問題

打開控件的安裝文件

然後編譯安裝，我們的控件部分就安裝成功了

然後就可以打開DEMO進行學習使用了，

這裏面有幾點要注意，就是這個控件的項目文件與普通的項目文件是有區別的

program Project2;


uses
  {$IFDEF DELPHI16_UP}
  Vcl.Forms,
  WinApi.Windows,
  System.SysUtils,
  {$ELSE}
  Forms,
  Windows,
  SysUtils,
  {$ENDIF }
  uCEFApplication,
  uCEFWorkScheduler,
  Unit2 in 'Unit2.pas' {SimpleExternalPumpBrowserFrm};


{$R *.res}


begin
   GlobalCEFWorkScheduler := TCEFWorkScheduler.Create(nil);


  GlobalCEFApp                           := TCefApplication.Create;
  GlobalCEFApp.FlashEnabled              := False;
  GlobalCEFApp.FastUnload                := True;
  GlobalCEFApp.ExternalMessagePump       := True;
  GlobalCEFApp.MultiThreadedMessageLoop  := False;
  GlobalCEFApp.OnScheduleMessagePumpWork := GlobalCEFApp_OnScheduleMessagePumpWork;


  if GlobalCEFApp.StartMainProcess then
    begin
      Application.Initialize;
      {$IFDEF DELPHI11_UP}
      Application.MainFormOnTaskbar := True;
      {$ENDIF}
      Application.CreateForm(TSimpleExternalPumpBrowserFrm, SimpleExternalPumpBrowserFrm);
      Application.Run;


      // The form needs to be destroyed *BEFORE* stopping the scheduler.
      SimpleExternalPumpBrowserFrm.Free;


      GlobalCEFWorkScheduler.StopScheduler;
    end;


  FreeAndNil(GlobalCEFApp);
  FreeAndNil(GlobalCEFWorkScheduler);






end.

而且每個pas文件裏面也是有一些自己的特點的，所以要注意在使用的時候要保證格式的正確

即每個單元開始的位置加入了  {$I cef.inc}，在本地程序編譯的時候也要把這個文件加在pas文件所在的目錄

unit Unit2;

{$I cef.inc}

interface

uses
  {$IFDEF DELPHI16_UP}
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.ExtCtrls,
  {$ELSE}
  Windows, Messages, SysUtils, Variants, Classes, Graphics,
  Controls, Forms, Dialogs, StdCtrls, ExtCtrls,
  {$ENDIF}
  uCEFChromium, uCEFWindowParent, uCEFTypes, uCEFConstants, uCEFInterfaces, uCEFWorkScheduler,
  uCEFChromiumWindow;

type
  TSimpleExternalPumpBrowserFrm = class(TForm)
    AddressPnl: TPanel;
    GoBtn: TButton;
    Timer1: TTimer;
    URLCbx: TComboBox;
    ChromiumWindow1: TChromiumWindow;

    procedure GoBtnClick(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);

    procedure FormCreate(Sender: TObject);
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);

    // These 3 TChromiumWindow events are called in the main app thread, so you can do whatever you want with the GUI.
    procedure ChromiumWindow1AfterCreated(Sender: TObject);
    procedure ChromiumWindow1BeforeClose(Sender: TObject);
    procedure ChromiumWindow1Close(Sender: TObject);
    procedure Chromium_OnBeforePopup(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame; const targetUrl, targetFrameName: ustring; targetDisposition: TCefWindowOpenDisposition; userGesture: Boolean; var popupFeatures: TCefPopupFeatures; var windowInfo: TCefWindowInfo; var client: ICefClient; var settings: TCefBrowserSettings; var noJavascriptAccess: Boolean; out Result: Boolean);

  protected
    FCanClose : boolean;
    FClosing  : boolean;

    procedure WMMove(var aMessage : TWMMove); message WM_MOVE;
    procedure WMMoving(var aMessage : TMessage); message WM_MOVING;
    procedure WMEnterMenuLoop(var aMessage: TMessage); message WM_ENTERMENULOOP;
    procedure WMExitMenuLoop(var aMessage: TMessage); message WM_EXITMENULOOP;
  end;

var
  SimpleExternalPumpBrowserFrm : TSimpleExternalPumpBrowserFrm;
  GlobalCEFWorkScheduler : TCEFWorkScheduler = nil;

procedure GlobalCEFApp_OnScheduleMessagePumpWork(const aDelayMS : int64);

implementation

{$R *.dfm}

uses
  uCEFApplication;

// This demo has a simple browser with a TChromiumWindow using the "External message pump" mode
// to schedule the cef_do_message_loop_work calls thanks to the TCEFWorkScheduler class.

// It was necessary to destroy the browser with the following destruction sequence :
// 1. The FormCloseQuery event sets CanClose to False and calls TChromiumWindow.CloseBrowser, which triggers the TChromiumWindow.OnClose event.
// 2. The TChromiumWindow.OnClose event calls TChromiumWindow.DestroyChildWindow which triggers the TChromiumWindow.OnBeforeClose event.
// 3. TChromiumWindow.OnBeforeClose sets FCanClose to True and closes the form.

procedure GlobalCEFApp_OnScheduleMessagePumpWork(const aDelayMS : int64);
begin
  if (GlobalCEFWorkScheduler <> nil) then GlobalCEFWorkScheduler.ScheduleMessagePumpWork(aDelayMS);
end;

procedure TSimpleExternalPumpBrowserFrm.FormCreate(Sender: TObject);
begin
  FCanClose := False;
  FClosing  := False;
end;

procedure TSimpleExternalPumpBrowserFrm.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
  CanClose := FCanClose;

  if not(FClosing) then
    begin
      FClosing           := True;
      Visible            := False;
      AddressPnl.Enabled := False;
      ChromiumWindow1.CloseBrowser(True);
    end;
end;

procedure TSimpleExternalPumpBrowserFrm.FormShow(Sender: TObject);
begin
  // For simplicity, this demo blocks all popup windows and new tabs
  ChromiumWindow1.ChromiumBrowser.OnBeforePopup := Chromium_OnBeforePopup;

  // GlobalCEFApp.GlobalContextInitialized has to be TRUE before creating any browser
  // If it's not initialized yet, we use a simple timer to create the browser later.
  if not(ChromiumWindow1.CreateBrowser) then Timer1.Enabled := True;
end;

procedure TSimpleExternalPumpBrowserFrm.Chromium_OnBeforePopup(Sender: TObject;
  const browser: ICefBrowser; const frame: ICefFrame; const targetUrl,
  targetFrameName: ustring; targetDisposition: TCefWindowOpenDisposition;
  userGesture: Boolean; var popupFeatures: TCefPopupFeatures;
  var windowInfo: TCefWindowInfo; var client: ICefClient;
  var settings: TCefBrowserSettings; var noJavascriptAccess: Boolean;
  out Result: Boolean);
begin
  // For simplicity, this demo blocks all popup windows and new tabs
  Result := (targetDisposition in [WOD_NEW_FOREGROUND_TAB, WOD_NEW_BACKGROUND_TAB, WOD_NEW_POPUP, WOD_NEW_WINDOW]);
end;

procedure TSimpleExternalPumpBrowserFrm.ChromiumWindow1AfterCreated(Sender: TObject);
begin
  Caption            := 'Simple External Pump Browser';
  AddressPnl.Enabled := True;
  GoBtn.Click;
end;

procedure TSimpleExternalPumpBrowserFrm.ChromiumWindow1BeforeClose(Sender: TObject);
begin
  FCanClose := True;
  Close;
end;

procedure TSimpleExternalPumpBrowserFrm.ChromiumWindow1Close(Sender: TObject);
begin
  // DestroyChildWindow will destroy the child window created by CEF at the top of the Z order.
  ChromiumWindow1.DestroyChildWindow;
end;

procedure TSimpleExternalPumpBrowserFrm.GoBtnClick(Sender: TObject);
begin
  ChromiumWindow1.LoadURL(URLCbx.Text);
end;

procedure TSimpleExternalPumpBrowserFrm.Timer1Timer(Sender: TObject);
begin
  Timer1.Enabled := False;
  if not(ChromiumWindow1.CreateBrowser) and not(ChromiumWindow1.Initialized) then
    Timer1.Enabled := True;
end;

procedure TSimpleExternalPumpBrowserFrm.WMMove(var aMessage : TWMMove);
begin
  inherited;

  if (ChromiumWindow1 <> nil) then ChromiumWindow1.NotifyMoveOrResizeStarted;
end;

procedure TSimpleExternalPumpBrowserFrm.WMMoving(var aMessage : TMessage);
begin
  inherited;

  if (ChromiumWindow1 <> nil) then ChromiumWindow1.NotifyMoveOrResizeStarted;
end;

procedure TSimpleExternalPumpBrowserFrm.WMEnterMenuLoop(var aMessage: TMessage);
begin
  inherited;

  if (aMessage.wParam = 0) and (GlobalCEFApp <> nil) then GlobalCEFApp.OsmodalLoop := True;
end;

procedure TSimpleExternalPumpBrowserFrm.WMExitMenuLoop(var aMessage: TMessage);
begin
  inherited;

  if (aMessage.wParam = 0) and (GlobalCEFApp <> nil) then GlobalCEFApp.OsmodalLoop := False;
end;

end.

將編譯後的程序放到運行環境中

最終程序的運行情況如下：

瀏覽本地文件