cocos2d-x學習筆記（十）android自動化打包bat腳本

1、先按照cocos2d-x的環境配置要求（ant等）安裝好，然後在安卓目錄下proj.android新建build.bat，腳本如下：

@echo off
echo 準備開始 
echo 設置路徑
set ROOT_PATH="F:\test"
set PROJECT_PATH="%ROOT_PATH%\proj.android"
set RESOURCES_PATH="%ROOT_PATH%\Resources"
set COCOS2DX_PATH="%ROOT_PATH%\cocos2d\cocos\platform\android\java"
set TODAY=%date:~0,4%%date:~5,2%%date:~8,2%
set FINISHDIR="F:\test2\%TODAY%"
echo 刪除android工程assets文件夾
echo #####################################################
if exist %PROJECT_PATH%\assets ( 
     del /q /f %PROJECT_PATH%\assets
     dir %PROJECT_PATH%\assets /ad /b /s >del.txt
     for /f %%i in (del.txt) do rd %%i /s /q
)
echo 刪除完畢
echo #####################################################
echo 拷貝最新的resource資源到android工程assets文件夾下
echo #####################################################
ping -n 3 127.0.0.1>nul
call xcopy  %RESOURCES_PATH% %PROJECT_PATH%\assets /e /y 
echo 拷貝完畢
echo #####################################################
echo ndk編譯SO文件
echo #####################################################
ping -n 3 127.0.0.1>nul
pushd %PROJECT_PATH%
call ndk-build -j4 NDK_DEBUG=0
echo 編譯完畢
popd
echo ####################################################################################################################
echo 更新android工程
echo #################################################################################################################### 
ping -n 3 127.0.0.1>nul
pushd %COCOS2DX_PATH%  
call android update project --name TestGame -t 1 -p %PROJECT_PATH%
popd
echo 更新完畢
echo #####################################################
echo 刪除bin文件夾
echo #####################################################
ping -n 3 127.0.0.1>nul
if exist %PROJECT_PATH%\bin ( 
    del /q /f %PROJECT_PATH%\bin
)
echo 刪除完畢
echo #####################################################
pushd %PROJECT_PATH%
echo 生成release 版本APK
echo #####################################################
ping -n 3 127.0.0.1>nul
call ant release  
popd
echo 生成Release完畢
echo #####################################################
echo 複製apk到指定目錄
echo #####################################################
if not exist %FINISHDIR% ( 
     md %FINISHDIR%
)
copy "%PROJECT_PATH%\bin\TestGame-release.apk" %FINISHDIR%
echo #####################################################
echo 執行完成！！！ 
pause

2、設置簽名信息，打開ant.properties添加如下：

key.store=E:/cocos/test.keystore
#keystore的密碼 
key.store.password=123456
#alias名 
key.alias=androiddebugkey
#alias密碼 
key.alias.password=123456