使用批處理簡化Windows IP設置過程（更新最終版）

    做爲一位系統集成工程師，尤其在新項目部署時，需要和一堆硬件設備打交道——服務器，存儲，網絡設備，操作系統都會有自己的IP地址段，而這時候只能通過筆記本直連進行調試配置，使用Windows界面來設置IP操作太繁瑣，會浪費大量的APM，正好趁着新年第一天上班，研究了下如何通過腳本配置ip。

(本文調試環境爲win7簡體中文旗艦版)

核心命令：

netsh interface ip set address 網絡適配器名稱 static IP MASK GATEWAY

netsh interface ip set address 本地連接 static 192.168.0.50 255.255.255.0 192.168.0.1

批處理腳本：（基於百度文庫文章微調）

@echo off
cls
color 0A
echo IP地址更改小工具
set IP=192.168.70.180
set MASK=255.255.255.0
set GATEWAY=0.0.0.0
set NAME="本地連接"

echo.
echo 自動更改IP      請按 1
echo.
echo 更改IP          請按 2
echo.
echo 添加IP          請按 3
echo.
echo 恢復自動獲取    請按 4

set /p KEY= [您的選擇是：]
if %KEY% == 1 goto Default
if %KEY% == 2 goto Static
if %KEY% == 3 goto Add
if %KEY% == 4 goto DHCP
 
:Static
ECHO 您選擇了手工修改設置。
ECHO.
echo 默認IP地址是%IP%，回車輸入默認地址
set /p IP= [請輸入IP地址:]
echo.
echo 默認MASK是%MASK%，回車輸入默認值
set /p MASK= [請輸入 子網掩碼 地址:]
echo.
echo 默認GATEWAY是%GATEWAY%，回車輸入默認值
set /p GATEWAY= [請輸入 網關 地址:]
echo.
echo 正在自動更改IP......
netsh interface ip set address %NAME% static %IP% %MASK% %GATEWAY%
echo IP地址/子網掩碼/網關設置完成
pause
goto :eof

:Default
echo 正在自動更改IP......
netsh interface ip set address %NAME% static %IP% %MASK% %GATEWAY%
echo IP地址/子網掩碼/網關設置完成
pause
goto :eof

:Add
ECHO 您選擇了添加IP設置。
ECHO.
echo 默認IP地址是%IP%，回車輸入默認地址
set /p IP= [請輸入IP地址:]
echo.
echo 默認MASK是%MASK%，回車輸入默認值
set /p MASK= [請輸入 子網掩碼 地址:]
echo.
echo 正在添加IP......
netsh interface ip add address %NAME% %IP% %MASK%
echo IP地址/子網掩碼/網關設置完成
pause
goto :eof

:DHCP
echo 正在改爲自動獲取....
netsh interface ip set address %NAME% source=dhcp
netsh interface ip set dns %NAME% source=dhcp
pause
goto :eof

1、習慣開着cmd的同學可以把bat文件放到c:\windows\system32下，這樣在任何路徑都可以調用了。

2、注意，在本地連接網口down的情況下，從靜態ip變爲DHCP看不出效果，插上網線就生效了