'=================================================================================
' 名稱：Tomcat5.5.20 + jdk1.5.0_06 + struts1.2 系統環境變量設置程序
' 功能：本程序自動設置 TOMCAT_HOME, CATALINA_HOME, JAVA_HOME, CLASSPATH, PATH等環
' 境變量如果您以前已經設置過相關環境變量，本程序將覆蓋相關設置，如果用到了
' Struts，將將相關文件複製到 %TOMCAT_HOME%\Common\lib 下面。
' 作者：HLDGAOFENG
' 日期：2008-09-17
'=================================================================================
' 修改這兩個常量爲你自己的路徑，如果爲空，將在運行時提示你選擇路徑。
' --------------------------------------------------------------------------------
' TOMCAT HOME
Const TOMCAT_HOME = ""
' JDK HOME
Const JAVA_HOME = ""
' --------------------------------------------------------------------------------
' 定義相關變量
Dim sTomcatHome
Dim sJavaHome
Dim sClassPath
Dim sPath
' 創建 Shell 對象，以便操作系統環境變量
Dim wsh, envSystem, shell, selFolder, selFolderItem
Set wsh = WScript.CreateObject("WScript.Shell")
Set envSystem = wsh.Environment("system")
Set shell = CreateObject("Shell.Application")
' 如果沒有指定 TOMCAT_HOME 則彈出瀏覽目錄窗口讓用戶選擇一個
If TOMCAT_HOME = "" Then
Set selFolder = shell.BrowseForFolder(0, "請選擇 TOMCAT_HOME 目錄：" & _
vbCrLf & "如：C:\apache-tomcat-5.5.20", 0, ssfDRIVES)
If selFolder Is Nothing Then WScript.Quit
Set selFolderItem = selFolder.Self
sTomcatHome = selFolderItem.Path
Else
sTomcatHome = TOMCAT_HOME
End If
' 如果沒有指定 JAVA_HOME 則彈出瀏覽目錄窗口讓用戶選擇一個
If JAVA_HOME = "" Then
Set selFolder = shell.BrowseForFolder(0, "請選擇 JAVA_HOME 目錄：" & _
vbCrLf & "如：C:\Program Files\Java\jdk1.5.0_06", 0, ssfDRIVES)
If selFolder Is Nothing Then WScript.Quit
Set selFolderItem = selFolder.Self
sJavaHome = selFolderItem.Path
Else
sJavaHome = JAVA_HOME
End If
' CLASS_PATH 一般配置。(*)我不太清楚要用到struts的其它包，如果用到，自己將相關包加到裏面吧。
' .;d:\struts\commons-logging.jar;d:\struts\antlr.jar;d:\struts\jakarta-oro.jar;d:\struts\commons-digester.jar;D:\struts\commons-validator.jar;D:\struts\struts.jar;D:\struts\commons-beanutils.jar
sClassPath = ".;" & _
"%JAVA_HOME%\lib\tools.jar;" & _
"%JAVA_HOME%\lib\dt.jar;" & _
"%JAVA_HOME%\lib\mysql-connector-java-3.0.14-production-bin.jar;" & _
"%CATALINA_HOME%\common\lib\servlet-api.jar;" & _
"%CATALINA_HOME%\common\lib\struts.jar;"
' 得到原來的 path 系統環境變量，再加上 %CATALINA_HOME%\common\lib;%JAVA_HOME%\bin;
sPath = envSystem("PATH")
If InStr(1, LCase(sPath), "%catalina_home%\common\lib") < 1 Then
sPath = "%CATALINA_HOME%\common\lib;" & sPath
End If
If InStr(1, LCase(sPath), "%java_home%\bin") < 1 Then
sPath = "%JAVA_HOME%\bin;" & sPath
End If
' 再次請用戶確認之後再進行修改
If MsgBox("正準備將您的 JAVA_HOME 系統環境變量設置爲：" & vbCrlf & _
sJavaHome & vbCrlf & vbCrlf & _
"正準備將您的 CATALINA_HOME,TOMCAT_HOME 系統環境變量設置爲：" & vbCrlf & _
sTomcatHome & vbCrlf & vbCrlf & _
"正準備將您的 CLASSPATH 系統環境變量設置爲：" & vbCrlf & _
sClassPath & vbCrlf & vbCrlf & _
"正準備將您的 PATH 系統環境變量設置爲：" & vbCrlf & _
sPath & vbCrlf & vbCrlf & _
"您確定要繼續嗎？", vbYesNo + vbQuestion + vbDefaultButton2, "收集信息完成，正準備設置環境變量……") <> vbYes Then
WScript.Quit
End If
' 設置系統環境變量
envSystem("TOMCAT_HOME") = sTomcatHome
envSystem("CATALINA_HOME") = sTomcatHome
envSystem("JAVA_HOME") = sJavaHome
envSystem("CLASSPATH") = sClassPath
envSystem("PATH") = sPath
MsgBox "環境變量已經設置成功!", vbinformation
set wsh = nothing