客戶端快速域遷移

寫了一個Windows batch腳本來實現把客戶端機器從一個域中退出，再加入一個新域。這個腳本適合用在公司合併的情況下，比如A公司被B公司收購了，所有A公司的客戶端機器必須加入B公司的域。

使用步驟：

1）將Domain_Migration文件夾拷貝至c:\。

2)  運行ClickMe.bat腳本，並按照提示選擇XP或者Win7系統，接下來輸入新域中用戶的密碼（這裏假設新域中的用戶名和舊域中的用戶名相同）。

3）如果希望保留之前用戶的配置文件，腳本運行完自動重啓之後，在C:\Domain_Migration中運行MoveProfile.bat腳本。

@echo off

REM ***choose XP or 7***
:START
SET /P OS_type=Please choose your OS: 1 for winXP, 2 for win7, q for quit:
IF "%OS_type%"=="q" GoTo EOF
IF "%OS_type%"=="1" echo You chosed winxp! & copy "c:\Domain_Migration\xp\netdom.exe" "c:\windows\system32\" /y & GoTo NEXT
IF "%OS_type%"=="2" (echo You chosed win7! & copy "c:\Domain_Migration\win7\netdom.exe" "c:\windows\system32\" /y & copy "c:\Domain_Migration\win7\netdom.exe.mui" "C:\Windows\System32\en-US\" /y & GoTo NEXT) ELSE (echo ERROR & GoTo START)

:NEXT
copy "c:\Domain_Migration\xcopy.exe" "c:\windows\system32\" /y
REM ***build the MoveProfile.bat***
cd c:\Domain_Migration\
echo cd %%USERPROFILE%% > MoveProfile.bat
echo xcopy "%USERPROFILE%\*" . /e /i /y >> MoveProfile.bat

REM ***build default username & domain***
echo Windows Registry Editor Version 5.00 > DefaultDomain.reg
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon] >> DefaultDomain.reg
echo "DefaultDomainName"="[NEW_DOMAIN_NAME]" >> DefaultDomain.reg
echo "DefaultUserName"="%USERNAME%" >> DefaultDomain.reg

REM ***import the reg file ***
reg import DefaultDomain.reg

SET /a counter=0

:FALSE
REM ***join [NEW_DOMAIN_NAME] domain***
echo -------------------------------------------------------------------------------
SET /a counter=%counter%+1
IF %Counter% GTR 3 (echo You have typed the wrong password 3 times, to avoid to be locked please try it again later. & pause & goto EOF) ELSE (echo ATTENTION: You are using the new domain account! & netdom move %COMPUTERNAME% /Domain:[NEW_DOMAIN_NAME] /UserD:[NEW_DOMAIN_NAME]\%USERNAME% /PasswordD:*)

IF %ERRORLEVEL%==0 GoTo TRUE
IF NOT %ERRORLEVEL%==0 GoTo FALSE

:TRUE
REM ***add [NEW_DOMAIN_NAME] user to local admin***
net localgroup administrators [NEW_DOMAIN_NAME]\%USERNAME% /add
echo Rebooting....
IF "%OS_type%"=="1" shutdown -r -f -t 10
IF "%OS_type%"=="2" shutdown /r /f /t 10

:EOF
exit