今天小編就爲大家分享一篇關於易語言調用whois實現域名批量查詢與註冊的代碼，小編覺得內容挺不錯的，現在分享給大家，具有很好的參考價值，需要的朋友一起跟隨小編來看看吧
域名批量查詢註冊與whois查詢的代碼
此功能需要加載精易模塊5.6
.版本 2
.支持庫 EThread
.程序集 窗口程序集_啓動窗口
.子程序 _批量查詢_被單擊
啓動線程 (&查詢是否可以註冊, , )
.子程序 查詢是否可以註冊
.局部變量 xml, 文本型
.局部變量 域名數組, 文本型, , "0"
.局部變量 計次, 整數型
批量查詢.禁止 ＝ 真
批量查詢.標題 ＝ “正在查詢...”
域名數組 ＝ 分割文本 (刪首尾空 (批量域名.內容), #換行符, )
結果.內容 ＝ “”
可以註冊.內容 ＝ “”
.計次循環首 (取數組成員數 (域名數組), 計次)
xml ＝ 到文本 (網頁_訪問 (“http://panda.www.net.cn/cgi-bin/check.cgi?area_domain=” ＋ 域名數組 [計次], , , , , , , , , ))
.如果 (文本_取出中間文本 (xml, “<returncode>”, “<”, , ) ≠ “200”)
結果.加入文本 (域名數組 [計次] ＋ “ ---查詢失敗” ＋ #換行符)
.否則
.如果真 (文本_取出中間文本 (xml, “<original>”, “ :”, , ) ＝ “210”)
結果.加入文本 (域名數組 [計次] ＋ “ ---可以註冊” ＋ #換行符)
可以註冊.加入文本 (域名數組 [計次] ＋ #換行符)
.如果真結束
.如果真 (文本_取出中間文本 (xml, “<original>”, “ :”, , ) ＝ “211”)
結果.加入文本 (域名數組 [計次] ＋ “ ---已經註冊” ＋ #換行符)
.如果真結束
.如果真 (文本_取出中間文本 (xml, “<original>”, “ :”, , ) ＝ “212”)
結果.加入文本 (域名數組 [計次] ＋ “ ---域名格式錯誤” ＋ #換行符)
.如果真結束
.如果真 (文本_取出中間文本 (xml, “<original>”, “ :”, , ) ＝ “213 ”)
結果.加入文本 (域名數組 [計次] ＋ “ ---查詢超時” ＋ #換行符)
.如果真結束
.如果結束
處理事件 ()
.計次循環尾 ()
批量查詢.禁止 ＝ 假
批量查詢.標題 ＝ “批量查詢 域名是否可以註冊”
.子程序 _whois查詢_被單擊
啓動線程 (&查詢whois, , )
.子程序 查詢whois
.局部變量 html, 文本型
.局部變量 正則, 正則表達式類
.局部變量 計次, 整數型
.局部變量 text, 文本型
.局部變量 源碼, 文本型
源碼 ＝ 編碼_utf8到gb2312 (到文本 (網頁_訪問 (“https://whois.22.cn/” ＋ 域名.內容, , , , , , , , , )))
html ＝ 文本_取出中間文本 (源碼, “</em></li>”, “</ul>”, , )
whois結果.內容 ＝ “”
正則.創建 (“<span>(.*?)</span>(.*?)<”, html, , , , )
.計次循環首 (正則.取匹配數量 (), 計次)
text ＝ text ＋ 正則.取子匹配文本 (計次, 1, ) ＋ “：” ＋ 正則.取子匹配文本 (計次, 2, ) ＋ #換行符
處理事件 ()
.計次循環尾 ()
whois結果.內容 ＝ text
查詢原始whois (源碼)
.子程序 查詢原始whois
.參數 源碼, 文本型
.局部變量 正則, 正則表達式類
.局部變量 計次, 整數型
.局部變量 text, 文本型
.局部變量 html, 文本型
html ＝ 文本_取出中間文本 (源碼, “whoisInfo” ＋ #引號 ＋ “>”, “</div>”, , )
正則.創建 (“(.*?)<br />”, 子文本替換 (html, “ ”, “”, , , 真), , , , )
.計次循環首 (正則.取匹配數量 (), 計次)
text ＝ text ＋ 正則.取子匹配文本 (計次, 1, ) ＋ #換行符
處理事件 ()
.計次循環尾 ()
whois原始內容.內容 ＝ text
運行結果：
總結
以上就是這篇文章的全部內容了，希望本文的內容對大家的學習或者工作具有一定的參考學習價值，謝謝大家對神馬文庫的支持。如果你想了解更多相關內容請查看下面相關鏈接