各种格式图片文件头标识分析

各种格式图片文件头标识分析

图片的格式很多，一个图片文件的后缀名并不能说明这个图片的真正格式什么，那么如何获取图片的格式呢？我想到了几个简单但有效的方法，那就是读取图片文件的文件头标识。我们知道各种格式的图片的文件头标识识不同的，因此我们可以通过判断文件头的标识来识别图片格式。
     我对各种格式的图片文件头标识进行了分析，不仅查找资料，也用十六进制编辑器察看过图片的文件头，以下是我收集、分析的结果，供大家参考。

1.JPEG
- 文件头标识 (2 bytes): $ff, $d8 (SOI) (JPEG 文件标识)
- 文件结束标识 (2 bytes): $ff, $d9 (EOI)

2.TGA
- 未压缩的前5字节    00 00 02 00 00
- RLE压缩的前5字节   00 00 10 00 00

3.PNG
- 文件头标识 (8 bytes)   89 50 4E 47 0D 0A 1A 0A

4.GIF
- 文件头标识 (6 bytes)   47 49 46 38 39(37) 61
                                     G    I    F     8    9 (7)     a

5.BMP
- 文件头标识 (2 bytes)   42 4D
                                     B    M

6.PCX
- 文件头标识 (1 bytes)   0A

7.TIFF
- 文件头标识 (2 bytes)   4D 4D 或 49 49

8.ICO
- 文件头标识 (8 bytes)   00 00 01 00 01 00 20 20

9.CUR
- 文件头标识 (8 bytes)   00 00 02 00 01 00 20 20

10.IFF
- 文件头标识 (4 bytes)   46 4F 52 4D
                                     F    O   R    M

11.ANI
- 文件头标识 (4 bytes)   52 49 46 46
                                    R     I     F    F

     根据这些文件头标识的收集，我可以写一个识别图像格式的模块了。但是在写这个模块之前可以对收集到的文件头标识进行优化，使得程序中字符串比对次数尽量的少。
1.JPEG我们知需要比对文件头的$ff, $d8这两个字符，而不用读取最后的两个结束标识了。
2.TGA，ICO，CUR只需比对第三个与第五个字符即可。
3.PNG比对[89][50]这两个字符。
4.GIF比对[47][49][46]与第五个字符。

     到这里，我想代码是不难写的，但是为了方便大家我还是把代码贴出来了，如果这代码写的不好，可以与我讨论。您可采用下面的代码，但请保留版权，谢谢！

模块代码如下：

'枚举图片格式种类
Public Enum ImageForm
   [BMP] = 0
   [JPEG] = 1
   [GIF87] = 2
   [GIF89] = 3
   [PNG] = 4
   [TGA Normal] = 5 'TGA未压缩
   [TGA RLE] = 6     'TGA经过RLE压缩后的
   [PCX] = 7
   [TIFF] = 8
   [ICO] = 9
   [CUR] = 10
   [IFF] = 11
   [ANI] = 12
   [Other] = 13
   [FileError] = 14
End Enum


'-----------------------------------------------------------------------
'-----------------------------------------------------------------------
'--   标题：获取图片的格式
'--   作者：BEAR-BEN
'--   制作日期：2007-8-5
'--   支持的格式：BMP,JPEG,GIF,PNG,TGA,PCX,TIFF,
'                             ICO,CUR,IFF,ANI 共11种格式
'--   版本：1.0
'--   使用者请保留版权，谢谢！
'-----------------------------------------------------------------------
'-----------------------------------------------------------------------
Public Function GetImageFileForm(ImageFilePath As String) As ImageForm
Dim FileHeader(5) As Byte, FileNumber As Integer

   GetImageFileForm = FileError

   If Dir(ImageFilePath) <> "" Then    '判断图片文件是否存在
     FileNumber = FreeFile
     Open ImageFilePath For Binary As #FileNumber
       Get FileNumber, , FileHeader()   '二进制流读取图片前5个字符
     Close FileNumber
    
     GetImageFileForm = Other
    
    
    '文件头标识识别
     If (FileHeader(0) = 66) And (FileHeader(1) = 77) Then
       GetImageFileForm = BMP
       Exit Function
     End If
     If (FileHeader(0) = 255) And (FileHeader(1) = 216) Then
       GetImageFileForm = JPEG    
       Exit Function
     End If
     If (FileHeader(0) = 71) And (FileHeader(1) = 73) And (FileHeader(2) = 70) And (FileHeader(4) = 57) Then
       GetImageFileForm = GIF89
       Exit Function
     End If
     If (FileHeader(0) = 71) And (FileHeader(1) = 73) And (FileHeader(2) = 70) And (FileHeader(4) = 55) Then
       GetImageFileForm = GIF87
       Exit Function
     End If
     If (FileHeader(0) = 137) And (FileHeader(1) = 80) Then
       GetImageFileForm = PNG  
       Exit Function
     End If
     If (FileHeader(0) = 73) And (FileHeader(1) = 73) Then
       GetImageFileForm = TIFF  'TIFF 摩托罗拉
       Exit Function
     End If
     If (FileHeader(0) = 77) And (FileHeader(1) = 77) Then
       GetImageFileForm = TIFF  'TIFF Intel
       Exit Function
     End If
     If (FileHeader(2) = 1) And (FileHeader(4) = 1) Then
       GetImageFileForm = ICO
       Exit Function
     End If
     If (FileHeader(2) = 2) And (FileHeader(4) = 1) Then
       GetImageFileForm = CUR
       Exit Function
     End If
     If (FileHeader(0) = 82) And (FileHeader(1) = 73) And (FileHeader(2) = 70) And (FileHeader(3) = 70) Then
       GetImageFileForm = ANI  
       Exit Function
     End If
     If (FileHeader(2) = 2) And (FileHeader(4) = 0) Then
       GetImageFileForm = [TGA Normal]
       Exit Function
     End If
     If (FileHeader(2) = 16) And (FileHeader(4) = 0) Then
       GetImageFileForm = [TGA RLE]
       Exit Function
     End If
     If (FileHeader(0) = 10) Then
       GetImageFileForm = PCX
       Exit Function
     End If
   End If
End Function
 

转自: http://hi.baidu.com/xovqbgpcznbovxq/item/ac7f14ec8b9df4285a7cfb3f